CTB940AC - Habilita o uso de ações customizadas para as tabelas de origem e destino nas regras bancárias do Conciliador BackOffice.

01. DADOS GERAIS

Linha de Produto:	Microsiga Protheus®
Segmento:	BackOffice
Módulo:	Financeiro
Idiomas	Português (Brasil)
Função:	CONCILIADOR (CTBA940) - CR

02. DESCRIÇÃO

O ponto de entrada CTB940AC habilita o uso de ações customizadas para as tabelas de origem e destino nas regras bancárias do Conciliador BackOffice.

Importante

A regra de Conciliação Bancária Manual (0024), possui apenas a tabela de destino apresentada em tela, portanto, está regra aceitará somente ações implementadas para tabela de destino (FK5 – Movimentos Bancários).
Para que a ação seja disparada será necessário marcar ao menos um item da tabela.

03. PARÂMETROS

Parâmetros disponibilizados no ponto de entrada:

PARAMIXB	Tipo	Descrição
1º Posição	Caractere	Contém o código da configuração.

04. RETORNO

Retorno do ponto de entrada:

O ponto de entrada deve retornar um objeto Json contendo duas listas: uma para ações que serão exibidas na tabela de origem(SIG - Itens do extrato bancário) e outra para as ações que serão exibidas na tabela de destino(FK5 – Movimentos Bancários).

Os itens da lista devem possuir a seguinte estrutura:

Chave	Tipo	Obrigatoriedade	Descrição
label	Caractere	Obrigatório	Rotulo da ação. Nome da ação que será apresentado na rotina.
description	Caractere	Obrigatório	Breve descrição da ação.
action	Caractere	Obrigatório	Função de usuário que será executada quando a ação for acionada. (Limite de 8 caracteres)

Importante

Se for necessário recarregar os dados da tabela, o usuário deve acessar os filtros e confirmá-los novamente. Isso atualizará a tabela, pois, nesse momento, os dados estão sendo trabalhados em uma tabela temporária, exigindo que ela seja limpa e os registros sejam reinseridos.

Parâmetros disponibilizados para a função acionada pela ação customizada:

PARAMIXB	Tipo	Descrição
1º Posição	Array	Lista contendo o ID (MSUIDT) dos registros selecionados.

06. EXEMPLO DE UTILIZAÇÃO

CTB940AC Expandir origem

#Include 'Protheus.ch'

//-----------------------------------------------------------------------------------
/*/{Protheus.doc} CTB940AC
    Ponto de entrada para adição de ações no conciliador backoffice.
	
	@see https://tdn.totvs.com/pages/viewpage.action?pageId=912629703     
	@return jAcoes, Json, Objeto contendo as ações dispostas da seguinte forma:
    {
        'origem': [
            {
                'label': '',
                'description': '',
                'action': '
            }
            ...
        ],
        'destino': [
            {
                'label': '',
                'description': '',
                'action': '
            }
            ...
        ]
    }
/*/
//-----------------------------------------------------------------------------------
User Function CTB940AC() as json
    Local cCodCfg   as Character
    Local jAcoes    as json
    local jAcao     as json
    
    cCodCfg := Paramixb[1]  // Codigo da regra de conciliação
    jAcoes  := JsonObject():New()
    jAcao   := JsonObject():New()

    // Propriedades esperadas no retorno do PE para adição das ações (É possível informar somente origem ou destino).
    jAcoes['origem']    := {}
    jAcoes['destino']   := {}

    Do Case
        Case cCodCfg == '0023' // Regra de conciliação bancária automática
            jAcao["label"]  := "R023 Dest"
            jAcao["description"] := "Exibe alerta em tela"
            jAcao["action"] := "CTB23Des"
            Aadd(jAcoes['destino'], jAcao)

            jAcao   := JsonObject():New()

            jAcao["label"]  := "R023 Orig"
            jAcao["description"] := "Exibe alerta em tela"
            jAcao["action"] := "CTB23Ori"
            Aadd(jAcoes['origem'], jAcao)

        Case cCodCfg == '0024' // Regra de conciliação bancária manual
			/*
				Adicionar ações na conciliação  bancária manual, seguir exemplo do json acima
			*/
    EndCase

Return jAcoes

User Function CTB23Ori()
    Local aListItems := {} as Array

    aListItems := Paramixb[1]  // Lista contendo o codigo (MSUIDT) dos registros selecionados na tabela de origem (SIG).

    If Len(aListItems) > 0
        MsgAlert("Chamada REGRA 0023 ORIGEM! " + CRLF + aListItems[1])
    EndIf
Return

User Function CTB23Des()
    Local aListItems := {} as Array

    aListItems := Paramixb[1]  // Lista contendo o codigo (MSUIDT) dos registros selecionados na tabela de destino (FK5).

    If Len(aListItems) > 0
        MsgAlert("Chamada REGRA 0023 DESTINO! " + CRLF + aListItems[1])
    EndIf
Return

Árvore de páginas