TOTVSTEC

Árvore de páginas

Tempo aproximado para leitura: 2 minutos

Salva uma mensagem de e-mail em disco.

Sintaxe

Save( < cFilePath > )

Parâmetros

Nome

Tipo

Descrição

Obrigatório

Referência

cFilePath

caractere

Indica o arquivo no disco a partir do RootPath do servidor.

X


Observações

  • Ao criar uma instância da classe TMailMessage, é possível salvar a mensagem carregada ou criada em disco a partir do método Save. Com isso, todos os itens da mensagem são salvos, como Body e Subject.
  • Este método suporta dois padrões de mensagem:
    • eml
    • MIME - Version 1.0

Exemplos

Exemplo 1
user function saveEmail()
  Local oServer
  Local oMessage
  Local nMessages := 0, nI := 0
  Local cFile := ""
  Local xRet
  
  oServer := TMailManager():New()
  writePProString( "Mail", "Protocol", "POP3", getsrvininame() )
  
  oServer:SetUseSSL( .T. )
  xRet := oServer:Init( "mail.totvs.com.br", "", "user", "password", 995, 0 )
  if xRet <> 0
    conout( "Could not initialize mail server: " + oServer:GetErrorString( xRet ) )
    return
  endif
  
  xRet := oServer:POPConnect()
  if xRet <> 0
    conout( "Could not connect on POP3 server: " + oServer:GetErrorString( xRet ) )
    return
  endif
  
  oServer:GetNumMsgs( @nMessages )
  conout( "Number of messages: " + cValToChar( nMessages ) )
  
  oMessage := TMailMessage():New()
  
  for nI := 1 to nMessages
    oMessage:Clear()
    
    conout( "Receiving message " + cValToChar( nI ) )
    xRet := oMessage:Receive( oServer, nI )
    if xRet <> 0
    conout( "Could not get message " + cValToChar( nI ) + ": " + oServer:GetErrorString( xRet ) )
    loop
    endif
    
    cFile := "\emails\email" + cValToChar( nI ) + ".eml"
    conout( "Saving message " + cValToChar( nI ) + " to " + cFile )
    oMessage:Save( cFile )
  next nI
  
  xRet := oServer:POPDisconnect()
  if xRet <> 0
    conout( "Could not disconnect from POP3 server: " + oServer:GetErrorString( xRet ) )
  endif
return
  • Sem rótulos