TOTVSTEC

Árvore de páginas

Carregando...
Tempo aproximado para leitura: 2 minutos

Envia um e-mail, de acordo com os dados passados pelo objeto da classe TMailMng por parâmetro, para o método.

Sintaxe

Send2( < oServer > )

Parâmetros

Nome

Tipo

Descrição

Obrigatório

Referência

oServer

objeto

Indica o objeto do servidor de e-mail, criado através da classe TMailMng.

X


Retorno

Nome

Tipo

Descrição

nRet

numérico

Retorna 0 (zero) quando o e-mail for enviado com sucesso; caso contrário, retorna outro valor.

Observações

Para utilizar o método corretamente, é necessário antes popular algumas das propriedades da classe TMailMessage básicas para o envio, tais como:

cFrom

E-mail de quem está enviando.

cTo

E-mail(s) para o qual se deseja enviar a mensagem.

cCc

E-mail(s) para o qual se deseja enviar a mensagem na seção "com cópia".

cBcc

E-mail(s) para o qual se deseja enviar a mensagem na seção "com cópia oculta".

cSubject

Assunto da mensagem que será enviada.

cBody

Conteúdo da mensagem.

Exemplos

Exemplo 1
user function SendEmail()
  Local oServer, oMessage
  Local xRet
  
  oServer := TMailMng():New( 1, .T., .T. )
  
  oServer:cUser := "username" //define the e-mail account username
  oServer:cPass := "password" //define the e-mail account password
  oServer:cSMTPAddr := "mail.totvs.com.br" // define the send server
  
  // estabilish the connection with the SMTP server
  xRet := oServer:SMTPConnect()
  if xRet <> 0
    conout( "Could not connect on SMTP server: " + oServer:GetErrorString( xRet ) )
    return
  endif
  
  // authenticate on the SMTP server (if needed)
  xRet := oServer:SMTPAuth( oServer:cUser, oServer:cPass )
  if xRet <> 0
    conout( "Could not authenticate on SMTP server: " + oServer:GetErrorString( xRet ) )
    oServer:SMTPDisconnect()
    return
  endif
  
  oMessage := TMailMessage():New()
  oMessage:Clear()
  
  oMessage:cDate := cValToChar( Date() )
  oMessage:cFrom := "myemail@totvs.com.br"
  oMessage:cTo := "otheremail@totvs.com.br"
  oMessage:cSubject := "Test"
  oMessage:cBody := "Email Test"
  
  xRet := oMessage:Send2( oServer )
  if xRet <> 0
    conout( "Could not send message: " + oServer:GetErrorString( xRet ) )
  endif
  
  xRet := oServer:SMTPDisconnect()
  if xRet <> 0
    conout( "Could not disconnect from SMTP server: " + oServer:GetErrorString( xRet ) )
  endif
return

Abrangência

Disponível em build superior a 7.00.131227A


  • Sem rótulos