Linha Microsiga Protheus

Árvore de páginas

Tempo aproximado para leitura: 3 minutos

01. DADOS GERAIS

Produto:

TOTVS Backoffice

Linha de Produto:

Linha Protheus

Segmento:

Serviços

Módulo:

TOTVS Backoffice (Linha Protheus) - Ativo Fixo (SIGAATF)

Função:ATFA125
País:Brasil
Ticket:Interno
Requisito/Story/IssueDSERCTR1-46748

02. DESCRIÇÃO

O ponto de entrada AF125OKB é utilizado para validar a inclusão e a exclusão de uma solicitação de baixa de um ativo imobilizado. Ele permite ao cliente definir regras específicas de validação para garantir que as operações de inclusão ou exclusão de uma solicitação de baixa sejam realizadas de acordo com as políticas e critérios estabelecidos pela empresa.

Com o AF125OKB, é possível assegurar que todos os registros de baixa sejam manipulados de maneira precisa e conforme os requisitos do negócio, evitando a exclusão indevida ou a inclusão incorreta de solicitações, contribuindo para a integridade dos dados de controle de ativos imobilizados.

03. DEMAIS INFORMAÇÕES


Manipulação de PE no sistema
If ExistBlock( "AF125OKB" ) .And. nOpc > 2 .And. lRet
	lRet := ExecBlock( "AF125OKB", .F., .F., { nOpc, cCBASE, cItem, nQtdBx, cMotbx,;
	cCondPg, nVlVenda, cGeraNF, cCliente,;
	cLoja, cSerie, cTESNFS } )
EndIf
Exemplo de PE
//Ponto de entrada exemplo

User Function AF125OKB()

	//Exemplo de uma validação utilizando algumas das variáveis disponiveis para uso no Ponto de Entrada
	Local nOpc := paramixb[1]
	Local cCbase := paramixb[2]
	Local nQtdBx := paramixb[4]
	Local nVlVenda := paramixb[7]
	Local lRet := .T.

	If nOpc == 3 //Se for inclusão de uma solicitação de baixa 3 - Inclusão / 5 - Exclusão

		If nQtdBx > 5 //Se a quantidade baixada for maior que cinco...
			lRet := .F.//...o sistema não deve prosseguir com a inclusão da solicitação
		EndIf

		If lRet .And. (nVlVenda>1000)//Se o valor de venda for maior do que R$1000

			If Aviso("Atenção!","Deseja confirmar a solicitação de venda do ativo " + Alltrim(cCbase)+ "?", {"SIM", "NÃO"})== 2
				Alert("Solicitação de venda não efetivada!")
				lRet := .F.
			Else
				Alert("Solicitação de venda do bem " + Alltrim(cCbase) + " efetivado com êxito!")
			EndIf

		EndIf

	EndIf

Return lRet

Importante !!

  • Observa-se que a utilização do PE e os impactos dele no sistema são de responsabilidade do cliente.
  • Os exemplos utilizados nessa documentação são apenas para fins de demonstração, cada cliente deve verificar qual comportamento deseja realizar de acordo com o escopo do ponto de entrada.

04. ASSUNTOS RELACIONADOS

  • Não se aplica.