TOTVSTEC

Árvore de páginas

Você está vendo a versão antiga da página. Ver a versão atual.

Comparar com o atual Ver Histórico da Página

« Anterior Versão 12 Próxima »

Cria um objeto do tipo grade.

Hierarquia

Construtores

Métodos

Observações

Em builds superiores à 120420A foi implementado o evento de wheel (roda do mouse), permitindo movimentar os itens do componente à partir deste dispositivo. h2. Propriedades

Propriedade

Descrição

Tipo

aArray

Indica o array que contém as informações apresentadas no browse.

Vetor

aColBmps

Indica um array com campos lógicos para determinar se a coluna é ou não uma imagem.

Vetor

aColSizes

Indica a largura das colunas.

Vetor

aColumns

Indica um array com objetos da classe TCColumn (Caso tenha utilizado este componente para inserir colunas).

Vetor

aHeaders

Indica o título dos campos no cabeçalho.

Vetor

bBmpName

Indica o bloco de código que será executado, internamente pelo browse, quando trocar a imagem de uma célula. Exemplo:
 
Nesta propriedade, é possível implementar novos eventos no bloco de código, porém seu valor original deve ser mantido para não resultar em erros na aplicação.
 
O valor de "X", no bloco de código, é um objeto que contém o nome da imagem definida para a célula.
 
Exemplo 1:
  X:cName = 'br_vermelho'
 
Exemplo 2:
// Bloco de código original
oBrowse:bBMPName := { |X| IF( VALTYPE( X )=='U','',IF( VALTYPE(X)=='C',X, X:CNAME) ) }
// Bloco de código com implementações
oBrowse:bBMPName := { |X| ShowColor(X), IF( VALTYPE( X )=='U','',IF( VALTYPE(X)=='C',X, X:CNAME) ) }
 
// Função implementada no bloco de código
Static Function ShowColor(objColor)
// Exibe no console do Servidor a imagem alterada pelo bloco de código
Conout(objColor:cName)
Return

Bloco de código

bDelOk

Indica o bloco de código que será executado quando excluir uma linha do browse.

Bloco de código

bDrawSelect

Indica o bloco de código que será executado ao utilizar o teclado para mudar de linha.

Bloco de código

bGoBottom

Indica o bloco de código que será executado quando o método GoBottom() for chamado.

Bloco de código

bGoTop

Indica o bloco de código que será executado quando o método GoTop() é chamado.

Bloco de código

bHeaderClick

Indica o bloco de código que será executado quando clicar, com o botão esquerdo do mouse, no cabeçalho do browse.

Bloco de código

bInRange

Indica o bloco de código que será executado para avaliar filtro no registro corrente.

Bloco de código

bLDblClick

Indica o bloco de código que será executado quando clicar duas vezes, com o botão esquerdo do mouse, sobre o objeto.

Bloco de código

bLine

Indica o bloco de código que será executado para montar a linha do browse.

Bloco de código

bLogicLen

Indica o bloco de código que será executado para contar as linhas do browse.

Bloco de código

bSeekChange

Indica o bloco de código que será executado quando mudar de linha.

Bloco de código

bSkip

Indica o bloco de código que será executado quando mudar de linha.

Bloco de código

bSuperDel

Indica o bloco de código que será executado quando excluir uma linha do browse.

Bloco de código

bValid

Indica o bloco de código de validação que será executado quando o conteúdo do objeto for modificado. Retorna verdadeiro (.T.), se o conteúdo é válido; caso contrário, falso (.F.).

Bloco de código

cAlias

Indica se o objeto é utilizado com array ou tabela.

Caracter

cField

Indica as propriedades relacionadas com o filtro.

Caracter

cOrderType

Indica o tipo de ordenação corrente. Exemplo: "D" é igual a ordenação por campo data.

Caracter

cSeek

Indica a chave de pesquisa incremental.

Caracter

lAdjustColSize

Indica se, verdadeiro (.T.), permite ajustar a largura da célula. Padrão - verdadeiro (.T.).

Lógico

lAutoEdit

Compatibilidade. Propriedade implementada somente na classe MsBrGetDBase.

Lógico

lDisablePaint

Indica se, verdadeiro (.T.), desabilita a atualização do browse.

Lógico

lHitBottom

Indica o tipo de ponteiro do mouse que está na última linha do browse.

Lógico

lHitTop

Indica o tipo de ponteiro do mouse que está na primeira linha do browse.

Lógico

lHScroll

Indica se, verdadeiro (.T.), habilita a barra de rolagem horizontal; caso contrário, falso (.F.).

Lógico

lJustific

Indica se, verdadeiro (.T.), centraliza o texto ou, falso (.F.), alinha o texto à esquerda.

Lógico

lUseDefaultColors

Indica se, verdadeiro (.T.), utiliza as cores padrão do browse.

Lógico

lVScroll

Indica se, verdadeiro (.T.), habilita a barra de rolagem vertical.

Lógico

nAt

Retorna a linha selecionada.

Numérico

nColOrder

Indexa os dados exibidos no browse quando utilizado um alias (tabela no banco de dados).

Numérico

nColPos

Indica o posicionamento da coluna no browse.

Numérico

nFreeze

Indica a coluna que será congelada à esquerda. Só é permitido o congelamento de uma coluna, qualquer valor maior que 1 será convertido para 1.

Observação

Essa funcionalidade não está homologada para utilização de CCS (Aplicação de estilo em componentes.). Neste caso é indicado o Componente TGrid.

Numérico

nLen

Indica o número total de linhas.

Numérico

nLinhas

Indica o número de linhas por célula na vertical.

Numérico

nRowPos

Indica o posicionamento da linha no browse

Numérico

nScrollType

Indica o tipo da barra de rolagem que será utilizada, sendo: 0=Scroll padrão e 1= Scroll VCR. Para mais informações, consulte a àrea "Observações".

Numérico

Exemplos

Exemplo 1
#include "TOTVS.CH" 

USER FUNCTION TCBrowse() 
Local oOK := LoadBitmap(GetResources(),'br_verde') 
Local oNO := LoadBitmap(GetResources(),'br_vermelho') 
Local aList := {} 

	DEFINE DIALOG oDlg TITLE "Exemplo TCBrowse" FROM 180,180 TO 550,700 PIXEL 
	
		// Vetor com elementos do Browse 
		aBrowse := { {.T.,'CLIENTE 001','RUA CLIENTE 001',111.11},;
		{.F.,'CLIENTE 002','RUA CLIENTE 002',222.22},;
		{.T.,'CLIENTE 003','RUA CLIENTE 003',333.33} } 
		 
		// Cria Browse 
		oBrowse := TCBrowse():New( 01 , 01, 260, 156,,; 
			{'','Codigo','Nome','Valor'},{20,50,50,50},; 
			oDlg,,,,,{||},,,,,,,.F.,,.T.,,.F.,,, ) 
		
		// Seta vetor para a browse 
		oBrowse:SetArray(aBrowse) 
		
		// Monta a linha a ser exibina no Browse 
		oBrowse:bLine := {||{ If(aBrowse[oBrowse:nAt,01],oOK,oNO),; 
			aBrowse[oBrowse:nAt,02],; 
			aBrowse[oBrowse:nAt,03],; 
			Transform(aBrowse[oBrowse:nAT,04],'@E 99,999,999,999.99') } } 
		
		// Evento de clique no cabeçalho da browse 
		oBrowse:bHeaderClick := {|o, nCol| alert('bHeaderClick') } 
		
		// Evento de duplo click na celula 
		oBrowse:bLDblClick := {|| alert('bLDblClick') } 
		
		// Cria Botoes com metodos básicos 
		TButton():New( 160, 002, "GoUp()", oDlg,{|| oBrowse:GoUp(), oBrowse:setFocus() },40,010,,,.F.,.T.,.F.,,.F.,,,.F. ) 
		TButton():New( 160, 052, "GoDown()" , oDlg,{|| oBrowse:GoDown(), oBrowse:setFocus() },40,010,,,.F.,.T.,.F.,,.F.,,,.F. ) 
		TButton():New( 160, 102, "GoTop()" , oDlg,{|| oBrowse:GoTop(),oBrowse:setFocus()}, 40, 010,,,.F.,.T.,.F.,,.F.,,,.F.) 
		TButton():New( 160, 152, "GoBottom()", oDlg,{|| oBrowse:GoBottom(),oBrowse:setFocus() },40,010,,,.F.,.T.,.F.,,.F.,,,.F.) 
		TButton():New( 172, 002, "Linha atual", oDlg,{|| alert(oBrowse:nAt) },40,010,,,.F.,.T.,.F.,,.F.,,,.F. ) 
		TButton():New( 172, 052, "Nr Linhas", oDlg,{|| alert(oBrowse:nLen) },40,010,,,.F.,.T.,.F.,,.F.,,,.F. ) 
		TButton():New( 172, 102, "Linhas visiveis", oDlg,{|| alert(oBrowse:nRowCount()) },40,010,,,.F.,.T.,.F.,,.F.,,,.F.) 
		TButton():New( 172, 152, "Alias", oDlg,{|| alert(oBrowse:cAlias) },40,010,,,.F.,.T.,.F.,,.F.,,,.F.) 
	
	ACTIVATE DIALOG oDlg CENTERED 
RETURN

Resultado do Exemplo

Abrangência

Microsiga Protheus 8.11 , Microsiga Protheus 11 , Protheus 10 , TOTVS Application Server 10 , ByYou Application Server

  • Sem rótulos