PE J203EMISS Tela de parâmetros customizada para emissão de faturas

01. DADOS GERAIS

02. DESCRIÇÃO

03. DEMAIS INFORMAÇÕES

#INCLUDE "FWMVCDEF.CH"
#INCLUDE "FWMBROWSE.CH"
#INCLUDE "PROTHEUS.CH"

User Function J203EMISS()

Local lRet       := .F.
Local lCkNomeRes := .F.
Local lChkAssEle := .T.
Local lCkAdicDep := .T. //Atribuido o Valor para que o campo inicie flegado.
Local lCkUnific  := .T.
Local cSigla     := "" //Criavar( 'RD0_SIGLA', .F. )
Local cNome      := "" //Criavar( 'RD0_NOME' , .F. )
Local cMen       := ""

Local aCbResult  := { "Impressora", "Tela", "Word", "Nenhum" }
Local cCbResult  := Space( 25 )
Local cOptions   := ''
Local cCommand   := Space( 100 )
Local aParams    := Array( 23 )
Local nValid     := 1
Local aCbMarca   := {"CÓPIA","COPY","PRÉ-FATURA","DRAFT INVOICE","PRÓ-FORMA","FATURA INTERNA DA PRÓ-FORMA","FATURA INTERNA PRÊMIO","FATURA POSTADA ELETRONICAMENTE (NÃO ENVIAR CL.)","PRÓ-FORMA POSTADA ELETRONICAMENTE (NÃO ENVIAR CL.)","PRÓ-FORMA SUPORTE E FECHAMENTO DE CÂMBIO","FATURA QUITADA","PAID","FREE TRANSLATION","CONFIDENCIAL","CONFIDENTIAL"," "}
Local cCbMarca1  := Space( 2 )
Local cCbMarca2  := Space( 100 )
Local aRelat     := Array( 1 )
//Local lCkRedacao, lCkContApr, lCkLogo, lCkAdicDep, lCkNoDesps
Local aCb
Local lCkBoleto
Local lCkContApr
Local lCkConvDesTab
Local lCkEncaminhamento
Local lCkLogo
Local lCkMarca
Local lCkMinuta
Local lCkNoDesps
Local lCkRecibo
Local lCkRedacao
Local lCkResult
Local lGetCEP
Local lGetCGC
Local lGetEnd
Local lGetEst
Local lGetPai
Local oCkAdicDep
Local oCkAssinat
Local oCkBoleto
Local oCkContApr
Local oCkConvDesTab
Local oCkEncaminhamento
Local oCkLogo
Local oCkMinuta
Local oCkNoDesps
Local oCkNomeRes
Local oCkRecibo
Local oCkRedacao
Local oCkResult
Local oCkUnific
Local oDlg
Local oGetMarca
Local oGetNome
Local oGetResp
Local oGetResult
Local nI := 0

For nI := 1 to Len(aCbMarca)
    aCbMarca[ nI ]   :=  Capital(aCbMarca[ nI ]   )
Next

//Limpa o cache com o codigo de cancelamento da fatura
J204SetMot()

/* *********************** ============================================================ *******************************
Recriando e Passando os Parametros de criacao de Tela  ATENCAO: PARA ESTE PE A TELA SEMPRE DEVE SER CRIADO POR COMPLETO
DE ACORDO COM O FONTE PADRAO ! - Karlla Honorio
************************** ============================================================ ****************************** */

DEFINE MSDIALOG oDlg TITLE Iif(!IsInCallStack('JURA202'), "Confirmar emissão das faturas", "Confirmar emissão das minutas") FROM 0,0 TO 260,440 PIXEL // Confirmar emissão das faturas / Confirmar emissão das minutas

@ 007, 005 CheckBox oCkMinuta Var lCkMinuta Prompt "Visualizar" Size 100, 008 Pixel Of oDlg // "Visualizar"
If IsInCallStack( 'JURA202' )
    oCkMinuta:cCaption := "Minuta" //"Minuta"
    lCkMinuta := .T.
    oCkMinuta:Disable()
EndIf

@ 017,005 CheckBox oCkRedacao Var lCkRedacao Prompt "Utilizar Redação" Size 100, 008 Pixel Of oDlg // "Utilizar Redação"
@ 027,005 CheckBox oCkContApr Var lCkContApr Prompt "Contra apresentação" Size 100, 008 Pixel Of oDlg // "Contra Apresentação"

@ 037,005 CheckBox oCkConvDesTab Var lCkConvDesTab Prompt "Conv.Des.Tab" Size 100,008 Pixel Of oDlg
@ 047,005 CheckBox oCkEncaminhamento Var lCkEncaminhamento Prompt "Utilizar Encaminhamento" Size 100,008 Pixel Of oDlg

@ 007,110 CheckBox oCkLogo Var lCkLogo Prompt "Exibir Logotipo" Size 100, 008 Pixel Of oDlg // "Exibir Logotipo"
lCkLogo := .T.
@ 017,110 CheckBox oCkAdicDep Var lCkAdicDep Prompt "Adicionar Depósito" Size 100, 008 Pixel Of oDlg // "Adicionar Depósito"
lCkAdicDep := .T.
@ 027,110 CheckBox oCkNoDesps Var lCkNoDesps Prompt "Ocultar despesas no Relatório" Size 100, 008 Pixel Of oDlg // "Ocultar despesas no Relatório"
@ 037,110 CheckBox oCkAssinat Var lChkAssEle Prompt "Exibir Assinatura Eletronica" Size 100, 008 Pixel Of oDlg // "Exibir Assinatura Eletronica"

@ 047,110 CheckBox oCkRecibo  Var lCkRecibo  Prompt "Recibo" Size 100, 008 Pixel Of oDlg // "Recibo"

@ 057,005 CheckBox oCkUnific  Var lCkUnific  Prompt "Unificar Documentos" Size 100, 008 Pixel Of oDlg // "Unificar Documentos"

@ 071,005 Say "Resultado:" Size 030,008 PIXEL OF oDlg //"Resultado:"
@ 069,035 ComboBox cCbResult Items aCbResult Size 100, 019 Pixel Of oDlg
 
@ 085,005 Say "Carimbo:" Size 030,008 PIXEL OF oDlg
@ 083,035 MSCOMBOBOX oCbMarca VAR cCbMarca1 ITEMS aCbMarca SIZE 176, 009 OF oDlg PIXEL OF oDlg

@ 099,005 MSGET ocMarca     VAR cCbMarca2   SIZE 205,009 PIXEL OF oDlg

@ 115,130 Button "Emitir" Size 037,012 PIXEL OF oDlg Action (lRet := .T. , oDlg:End() ) //"Emitir"
@ 115,173 Button "Cancelar" Size 037,012 PIXEL OF oDlg Action (lRet := .F. , oDlg:End() ) //"Cancelar"

ACTIVATE MSDIALOG oDlg CENTERED

If Len(cCbResult) > 1
    cCbResult := AllTrim( Str( aScan( aCbResult, cCbResult ) ) )
EndIf

aRelat[1] := lCkRecibo

Do Case
    Case cCbResult == '1' //Impressora
        cOptions := '2'
   
    Case cCbResult == '3' //Word
        cOptions := '8'
   
    Otherwise //Tela//
        cOptions := '1'
EndCase


cOptions := cOptions + ';0;1;' // "Relatorio de Faturamento"

aParams[ 1] := cOptions

aParams[ 2] := __CUSERID//vpiCodUser
aParams[ 3] := ' '//vpiNumFatura
aParams[ 4] := ' '//vpiOrganizacao
aParams[ 5] := IIf( lCkNomeRes , 'S', 'N' ) //vpcNoSocioFatura
aParams[ 6] := ' '//vpiCliente
aParams[ 7] := IIf( lCkMinuta , 'S', 'N' ) //vpcPreFaturaMinuta
aParams[ 8] := IIf( lCkLogo , 'S', 'N' ) //vpcExibirLogo
aParams[ 9] := IIf( lCkAdicDep , 'S', 'N' ) //vpcDadosDeposito
aParams[10] := IIf( lCkContApr , 'S', 'N' ) //vpcContraApresentacao
aParams[11] := ' '//cContApr
aParams[12] := ' '//cRelatorio
aParams[13] := IIf( lCkRecibo , 'S', 'N' )//Recibo
aParams[14] := ' '
aParams[15] := IIf( lCkRedacao, 'S', 'N' )
aParams[16] := IIf( lCkNoDesps, 'S', 'N' )
aParams[17] := IIf( lChkAssEle, 'S', 'N' )
aParams[18] := JurGetDados("RD0",1,xFilial("RD0")+JurUsuario(__CUSERID),"RD0_NOME")
aParams[19] := IIf( lCkUnific .And. cCbResult == "2", "4", cCbResult ) //Resultado do relatório: '1' - Impressora / '3' - Word / outros - Tela
aParams[20] := IIf( lCkConvDesTab,'S','N' )+";"+ IIf( lCkEncaminhamento, 'S', 'N' )+";"+(cCbMarca1 + " " + Alltrim(cCbMarca2)+";C;")
aParams[21] := IIf( lCkConvDesTab,'S','N' )+";"+IIf( lCkEncaminhamento, 'S','N' )+";"+(cCbMarca1 + " " + Alltrim(cCbMarca2)+";")
aParams[22] := IIf( lCkUnific, 'S', 'N' )
aParams[23] := cCbResult

Return {lRet, aParams}

04. ASSUNTOS RELACIONADOS

• Emissão de Faturas - JURA203