PE JA203CN1 Alterar os vencimentos das parcelas

01. DADOS GERAIS

02. DESCRIÇÃO

03. DEMAIS INFORMAÇÕES

USER Function JA203CN1

Local nA         := 0
Local aArea      := GetArea()
//Local cTipo      := ParamIXB[1]
Local aParcelas  := ParamIXB[2]
Local cFila      := NXA->NXA_CFILA   //Tabela NXA ja posicionada
Local cCliPG     := NXA->NXA_CLIPG
Local cLojaPG    := NXA->NXA_LOJPG  

DbSelectArea("ZXC")
DbSetOrder(1) //ZXC_FILIAL+ZXC_FILA+ZXC_CLIPG+ZXC_LOJAPG+ZXC_PARCEL

Begin Sequence

    If  Empty(cFila) .Or. Empty(cCliPG) .Or. Empty(cLojaPG)
        Aviso("Fila ou Cliente e Loja pagadora em branco! Favor verificar!")
        Break
    EndIf

    If  Empty(aParcelas) .Or. (ValType(aParcelas) != "A")
        Break
    EndIf

    For nA := 1 to Len(aParcelas)
        If  DbSeek(xFilial("ZXC")+cFila+cCliPG+cLojaPG+StrZero(nA,Len(ZXC_PARCEL)))
            If  (nA == 1) .And. NXA->( DbRLock(Recno()) )     //Atualiza o NXA com o primeiro vencimento das parcelas.
                NXA->NXA_DTVENC := ZXC_VECMTO
                NXA->( MsUnLock() )
            EndIf
            aParcelas[nA][1] := ZXC_VECMTO  //Atualiza com o vencimento alterado anteriormente pelo usuario na fila de impressao.
        EndIf
    Next nA

End Sequence

RestArea(aArea)

Return aParcelas

04. ASSUNTOS RELACIONADOS

• Emissão de Faturas - JURA203