Linha Microsiga Protheus

Árvore de páginas

Carregando...
Tempo aproximado para leitura: 4 minutos

01. DADOS GERAIS

Produto:

TOTVS Manutenção de Ativos

Linha de Produto:

Linha Protheus

Segmento:

Manufatura

Módulo:

TOTVS Manufatura (Linha Protheus) - Manutenção de ativos (SIGAMNT)

Função:MNTA400A()
País:Brasil


02. DESCRIÇÃO

Descrição:

Ponto de entrada acionado ao montar a tela de cancelamento, permitindo montar um browse especifico para o processo.

Localização:

SIGAMNT: Atualizações/Controle de Oficina/Retorno de OS/Retorno

Programa Fonte:

MNTA400.prw

Função:

MNTA400A()

Parâmetros:

TipoDescriçãoObrigatório
NuméricoRECNO do registro que será alteradoSim

Retorno:

TipoDescriçãoObrigatório
Lógico

.T. - Para confirmação da tela

.F. - Cancelamento da tela

Sim

03. DEMAIS INFORMAÇÕES

Exemplo MNTA400A()
#INCLUDE "PROTHEUS.CH"
   
User Function MNTA400A()
         
    Local aArea := GetArea()
    Local cObs  := ""
    Local nOpcc := 0
    Local oDlg  := Nil
    Local oObs  := Nil
    Local oMenu := Nil
    Local nRec  := ParamIXB[1]
         
    dbSelectArea("STJ")
    dbGoTo(nRec)
         
    cObs := STJ->TJ_MTCANC
         
    Define Msdialog oDlg Title "Cancelamento da O.S."+STJ->TJ_ORDEM From 18,20 To 35,75 Of oMainWnd
        @ 38,8 Say "Motivo do Cancelamento" Of oDlg Pixel
        @ 45,8 Get oObs Var cObs Of oDlg Multiline Size 200,40 Pixel
                
        If ValType(aSMenu) == "A"
            NGPOPUP(aSMenu,@oMenu)
            oDlg:bRClicked:= { |o,x,y| oMenu:Activate(x,y,oDlg)}
        EndIf
                
    Activate Msdialog oDlg On Init EnchoiceBar(oDlg,{||nOpcc:=1,oDlg:End()},{||oDlg:End()})
         
    If nOpcc == 1
        dbSelectArea("STJ")
        RecLock('STJ',.F.)
        STJ->TJ_MTCANC := cObs
        MsUnLock()
    EndIf
         
    RestArea(aArea)
         
Return (nOpcc == 1)


04. ASSUNTOS RELACIONADOS

  • Não se aplica.