Linha Microsiga Protheus

Árvore de páginas

01. DADOS GERAIS

Produto:

TOTVS Manutenção de Ativos

Linha de Produto:

Linha Protheus

Segmento:

Manufatura

Módulo:

TOTVS Manufatura (Linha Protheus) - Manutenção de ativos (SIGAMNT)

Função:

MNTA265 - Alteração de O.S.

MNTA295 - Distribuição de S.S. e Geração de O.S.

MNTA410 - O.S. Manual

MNTA420 - O.S. Corretiva

MNTA490 - Liberação de O.S.


02. DESCRIÇÃO

Descrição:

Ponto de entrada chamado após a inclusão da O.S. e tem como objetivo realizar a impressão de um relatório qualquer com as informações desta O.S..

Parâmetros:
PosiçãoTipoDescrição
1stringOrdem de serviço
2stringPlano de manutenção
3dateData de manutenção prevista
Retorno:
TipoDescrição

boolean

Retorno lógico indicando se houve algum problema na execução do ponto de entrada.

03. DEMAIS INFORMAÇÕES

Exemplo: P.E. NGIMPOS
#include 'protheus.ch' 
 
User Function NGIMPOS()

    Local aMatOS   := {}
    Local aMATSX1  := {}
    Local aAreaSTJ := STJ->( FWGetArea() )

    Local nTamCCt  := FWTamSX3( 'TJ_CCUSTO' )[1]
    Local nTamPla  := FWTamSX3( 'TJ_PLANO' )[1]
    Local nTamAre  := FWTamSX3( 'TJ_CODAREA' )[1]
    Local nTamCTr  := FWTamSX3( 'TJ_CENTRAB' )[1]
    
    If Type( 'ParamIXB' ) == 'A'

        If MsgYesNo( 'Deseja Imprimir a O.S.?', 'Atenção' )

            aAdd( aMatOS, { ParamIXB[1], ParamIXB[2] } )
            
            aMATSX1 := {    { '01', ParamIXB[1] }              ,;
                            { '02', Replicate( 'Z', nTamPla ) },;
                            { '07', Space( nTamCCt ) }         ,;
                            { '08', Replicate( 'Z', nTamCCt ) },;
                            { '09', Space( nTamCTr ) }         ,;
                            { '10', Replicate( 'Z', nTamCTr ) },;
                            { '11', Space( nTamAre ) }         ,;
                            { '12', Replicate( 'Z', nTamAre ) },;
                            { '13', ParamIXB[2] }              ,;
                            { '14', ParamIXB[2] }              ,;
                            { '15', DToC( ParamIXB[3] ) }      ,;
                            { '16', DToC( ParamIXB[3] ) } }
 
            If ExistBlock( 'MNTIMPOS' )

                ExecBlock( 'MNTIMPOS', .F., .F., ParamIXB )

            Else

                MNTR675(.F., , , aMatOS, , aMATSX1 )

            EndIf
 
        EndIf

    Else

        MsgInfo( 'Não será possível imprimir a ordem de serviço devido a'  + Chr( 13 ) +;
            'problema na passagem de parâmetro para a função de impressão' + Chr( 13 ) +;
            '(Ponto de entrada NGIMPOS)' + Chr( 13 ) + Chr( 13 ) +;
            'Consulte o suporte...', 'NÃO CONFORMIDADE' )

    EndIf

    FWRestArea( aAreaSTJ )

    FWFreeArray( aMatOS )
    FWFreeArray( aMATSX1 )
    FWFreeArray( aAreaSTJ )

Return .T.


04. ASSUNTOS RELACIONADOS

  • Não se aplica