Linha Microsiga Protheus

Árvore de páginas


01. DADOS GERAIS

Produto:

TOTVS Gestão Jurídica - Linha SISJURI

Linha de Produto:

Linha Protheus

Segmento:

Jurídico

Módulo:

TOTVS Gestão Jurídica - Linha SISJURI - Pré Faturamento de Serviços (SIGAPFS)

Função:Cadastro de Casos - JURA070
País:Brasil


02. DESCRIÇÃO

Esse ponto de entrada deve ser usado na inclusão do caso para que a sequência de numeração de caso considere apenas o Cliente, não Cliente e a Loja.

Localização

Atualização >> Cadastro >> Caso

Parâmetro

PARAMIXB[1] - Próximo numero de Caso / Validação se o Caso já existe para o Cliente

PARAMIXB[2] - Código do Cliente

PARAMIXB[3] - Número do Caso

PARAMIXB[4] - Parãmetro (MV_JCASO1) - Sequência da numeração do caso (1 - Por cliente / 2 - Independente)

PARAMIXB[5] - Parâmetro (MV_JCASO2) - Reaproveita lacunas existentes na numeração? .T. - Reaproveita; .F. - Não reaproveita.

Retorno

Query que a rotina irá executar para verificar a próxima numeração do caso.


03. DEMAIS INFORMAÇÕES

User Function J070NUM

Local cQuery     := ''
Local cTipo      := PARAMIXB[1] 
Local cCliente   := PARAMIXB[2]
Local cCaso      := PARAMIXB[3]
Local cNumClien  := PARAMIXB[4] 
Local lUsaLacuna := PARAMIXB[5] 

If cTipo == '1'
    If cNumClien == '1'
        If lUsaLacuna
            cQuery := " SELECT NVE_NUMCAS "
        Else
            cQuery := " SELECT MAX(NVE_NUMCAS) NVE_NUMCAS "
        EndIf
        cQuery += "   FROM "+ RetSqlName( "NVE" ) +" NVE "
        cQuery += "  WHERE NVE.D_E_L_E_T_ = ' ' "
        cQuery += "    AND NVE.NVE_FILIAL = '" + xFilial("NVE") +"' "
        cQuery += "    AND NVE_CCLIEN = '" + cCliente +"' "
        cQuery += "  ORDER BY NVE_NUMCAS"
    Else
        If lUsaLacuna
            cQuery := " SELECT DISTINCT NVE_NUMCAS "
        Else
            cQuery := " SELECT MAX(NVE_NUMCAS) NVE_NUMCAS "
        EndIF
        cQuery += "   FROM "+ RetSqlName( "NVE" ) +" NVE "
        cQuery += "  WHERE NVE.D_E_L_E_T_ = ' ' "
        cQuery += "    AND NVE.NVE_FILIAL = '" + xFilial("NVE") +"' "
        cQuery += "  ORDER BY NVE_NUMCAS "
    EndIf
ElseIf cTipo == '2'

    cQuery := " SELECT NVE.NVE_CCLIEN, NVE_LCLIEN, NVE_NUMCAS "
    cQuery += "   FROM "+ RetSqlName( "NVE" )   +" NVE "
    cQuery += "  WHERE NVE.D_E_L_E_T_ = ' ' "
    cQuery += "    AND NVE.NVE_FILIAL = '" + xFilial( "NVE" ) +"' "
    cQuery += "    AND NVE_SITUAC = '1' "
    cQuery += "    AND NVE_NUMCAS = '" + cCaso +"' "

    If (cNumClien == '1')
        cQuery += "    AND NVE_CCLIEN = '" + cCliente +"' "
    EndIf
EndIf

Return cQuery


04. ASSUNTOS RELACIONADOS