Linha Microsiga Protheus - Espanhol

Atalhos

Árvore de páginas

Punto-de-Entrada: COMCOL2 - PERSONALIZACIÓN PARA PROCESAR SOLAMENTE DOCUMENTOS DEL TIPO TRANSFERENCIA ENTRE SUCURSALES.


Versiones:
Compatible Países:Todos
Sistemas operativos:Todos
Compatible con las bases de datos:Todos
Nivel de acceso:(Acceso Clientes)
Idiomas:Todos


Descripción:
Ubicación: Function COLNFeAut - Función responsable por validar las tablas SE4/SF4 para generación automática de los documentos del TOTVS Colaboración. En que Punto: En la función COLNFeAut antes de entrar en el lazo para cargar los ítems del documento importado, se debe utilizar para verificar si solamente se procesarán los documentos del tipo de transferencia entre sucursales, para permitir el procesamiento automático de los documentos importados, solamente cuando sea transferencia entre sucursales.
Programa fuente:
COMXCOL.PRW
Parámetros:



NombreTipoDescripciónEstándarObligatorioReferencia

PARAMIXB[1]Array of Records Array que contiene el encabezado del documento importado.



PARAMIXB[2]Array of Records Array que contiene los ítems del documento importado.



Retorno:
Lógico
DEVUELVE SI EL DOCUMENTO QUE SE ESTÁ PROCESANDO ES DEL TIPO TRANSFERENCIA ENTRE SUCURSALES.
Programa fuente:
COMXCOL.PRW
Ejemplo:
User Function COMCOL2() 
Local aAreaSM0 := SM0->(GetArea())
Local aAreaSA2 := SA2->(GetArea())
Local aCabec   := PARAMIXB[1]  //Encabezado de los principales campos de la tabla SF1 (Encabezado del documento de entrada)
Local aItens   := PARAMIXB[2]	//Ítems de los principales campos de la tabla SD1 (Ítems del documento de entrada)
Local nPosFor  := aScan(aCabec,{|x| AllTrim(x[1]) == "F1_FORNECE"})
Local nPosLoj  := aScan(aCabec,{|x| AllTrim(x[1]) == "F1_LOJA"})
Local lRet	:= .F.

SA2->(DbSetOrder(1))
SA2->(dbSeek(xFilial("SA2")+aCabec[nPosFor,2]+aCabec[nPosLoj,2]))
If UsaFilTrf()
	lRet := (!Empty(SA2->A2_FILTRF))
Else
	SM0->(DbSetOrder(1))
	SM0->(MsSeek(cEmpAnt))
	Do While !SM0->(Eof()) .And. SM0->M0_CODIGO == cEmpAnt
		If (SM0->M0_CGC == AllTrim(SA2->A2_CGC))
			lRet := .T.
			Exit
		EndIf
		SM0->(DbSkip())
	EndDo
EndIf

RestArea(aAreaSM0)
RestArea(aAreaSA2)
Return lRet