TOTVSTEC

Árvore de páginas

Você está vendo a versão antiga da página. Ver a versão atual.

Comparar com o atual Ver Histórico da Página

« Anterior Versão 17 Próxima »

Retorna um array com o conteúdo de um diretório.

Consulte a função ADir para outras funcionalidades.

Atenção!

Esta função não opera no SmartClient HTML, pois quando executado via navegador o sistema não tem acesso aos arquivos da estação de trabalho.

Sintaxe

Directory( < cDirEsp >, [ cAtributos ], [ uParam1 ], [ lCaseSensitive ], [ nTypeOrder ] )

Parâmetros

Nome

Tipo

Descrição

Obrigatório

Referência

cDirEsp

caractere

Indica o diretório para pesquisa.
São permitidos caracteres do tipo curinga ( *.* )

  • Caso especificado um path sem a unidade de disco, serão considerados arquivos e diretórios contidos no AppServer, exemplos:

    // Retorna arquivos da raiz do System do AppServer
    aFiles := aFiles := Directory("/*.*", "D")

    // Retorna arquivos do diretorio de Spool do AppServer
    aFiles := aFiles := Directory("/spool/*.*", "D")

  • Caso esterificado um path com unidade de disco, serão considerados arquivos e diretórios contidos na estação de trabalho em que o SmartClient está sendo executado, exemplo:

    // Exemplo para Windows
    aFiles := Directory(    "c:\tmp\*.*")

    // Exemplo para Linux (obrigatório uso do l:)
    aFiles := Directory(    "l:/tmp/*.*")

X


cAtributos

caractere

Indica quais tipos de arquivos/diretórios devem ser incluídos no array.
É permitido concatenar atributos.

No exemplo abaixo retornamos Diretórios + Arquivos de Sistema + Arquivos entre as posições 10.000 e 20.000:

  cAtributos := "D" // Inclui diretorios
  cAtributos += "S" // Inclui arquivos do sistema
  cAtributos += ":10000" // Lista arquivos/diretorios a partir do arquivo de nr 10.000
  aFiles := Directory("c:\tmp\10kk\*.*", cAtributos)

Para mais detalhes, consulte a Tabela A abaixo:

Tabela A

Atribuito

Significado

H

Incluir arquivos ocultos

S

Incluir arquivos de sistema

D

Incluir diretórios

V

Procura pelo volume DOS e exclui outros arquivos
Dada exclusão dos demais tipos de arquivos o parâmetro V deve ser usado com cautela. 

:N

(erro) A partir da build 7.00.131227A-20160630, visando economia de recursos, a função Directory esta limitada ao retorno de 10.000 itens.

Caso necessário visualizar itens que tenham uma "contagem" superior à 10.000 é possível utilizar o Atributo : (dois pontos), ele trará itens de uma determinada posição até o limite de +10.000, veja o exemplo:

// Lista arquivos a partir da posição 10.000 (limitado a +10.000)
cAtributos := ":10000" 
aFiles := Directory("c:\tmp\10kk\*.*", cAtributos)
...
// Lista arquivos a partir da posição 20.000 (limitado a +10.000)
cAtributos := ":20000" 
aFiles := Directory("c:\tmp\10kk\*.*", cAtributos)
...



uParam1

numérico

Parâmetro de compatibilidade, não deve ser preenchido.



lCaseSensitive

lógico

Se verdadeiro (.T.), o nome do arquivo será transformado para letra maiúscula;
Se falso (.F.), o nome do arquivo será retornado conforme escrito no disco rígido.



nTypeOrder

numérico

Indica o tipo de ordenação do resultado da função.
*Apenas em build AppServer superiores a 7.00.131227A.

Para mais detalhes, consulte a Tabela B abaixo:

Tabela B

Parâmetro

Tipo de ordenação

1

Ordenar por nome do arquivo

2

Ordenar por data do arquivo

3

Ordenar por tamanho do arquivo



Retorno

Nome

Tipo

Descrição

aRet

vetor

Retorna um array que contém informações sobre cada arquivo / diretório que atenda aos requisitos
descritos no parâmetro cAtributos, passado na chamada da função. 

A Tabela C (abaixo), descreve a estrutura do array de retorno:

Tabela C

Posição

Conteúdo

1

Nome do arquivo

2

Tamanho

3

Data

4

Hora

5

Atributos, exemplo A=Arquivo, D=Diretório

Exemplos

Exemplo 1
User Function Exemplo1()
  Local aFiles := {}
  Local nX
  local nCount
  aFiles := Directory("c:\garbage\*.*", "D")
  nCount := Len( aFiles )
  For nX := 1 to nCount 
      ConOut('Arquivo: ' + aFiles[nX,1] + ' - Size: ' + AllTrim(Str(aFiles[nX,2])) )
  Next nX
Return

User Function Exemplo2()
  local F_NAME
  aDirectory := DIRECTORY("*.*", "D")
  F_NAME := Len(aDirectory)
  AEVAL(aDirectory, {|aFile| CONOUT(aFile[1])} )
Return

User Function Exemplo3()
  Local aFiles := {}
  local nCount
  Local nX
  local flagparameters := "D:10000" //lista os arquivos entre 10.000 e 20.000, inclusive diretórios
  aFiles := Directory("c:\tmp\10kk\*.*", flagparameters, 1)
  nCount := Len( aFiles )
  For nX := 1 to nCount
      ConOut('Arquivo: ' + aFiles[nX,1] + ' - Size: ' + AllTrim(Str(aFiles[nX,2])) )
  Next nX
Return 


Veja também

  • Sem rótulos