FA070TIT - Confirma as baixas a receber.

#INCLUDE 'PROTHEUS.CH'

USER FUNCTION FA070TIT() AS LOGICAL
    LOCAL lRet AS LOGICAL
    LOCAL cMensagem AS CHARACTER

    IF (TYPE("lF070Auto") == "L" .AND. lF070Auto) .OR. ISBLIND()
        /***
            Regras de verificação e validação
            ...
            ...
        ***/

        //-- Simulando uma invalidação
            lRet := .F.
            cMensagem := "PE: FA070TIT - Mensagem motivo invalidação baixa a Receber"
            AutoGrLog(cMensagem)
    ELSE
        lRet := MsgYesNo("Deseja baixar os títulos do cliente " + SE1->E1_CLIENTE + "?", "Atenção")
    ENDIF

RETURN lRet

//---------------------------------------------------------------------------------------------------
// Baixa do titulo a receber
//---------------------------------------------------------------------------------------------------
User Function BAIXA070()
  
    Local aBaixa AS ARRAY
    
    Private lMsErroAuto		AS LOGICAL  //-- utilizadas para o controle de erro da rotina automática
    Private lAutoErrNoFile	AS LOGICAL  //-- utilizadas para o controle de erro da rotina automática

    lMsErroAuto		:= .F.
    lAutoErrNoFile	:= .F.  

    aBaixa := { {"E1_PREFIXO"  ,"GRV"                ,Nil    },;
                {"E1_NUM"      ,"TVA000001"            ,Nil    },;
                {"E1_PARCELA"  ," "                    ,Nil    },;
                {"E1_TIPO"     ,"DP "                  ,Nil    },;
                {"AUTMOTBX"    ,"NOR"                  ,Nil    },;
                {"AUTBANCO"    ,"RIC"                  ,Nil    },;
                {"AUTAGENCIA"  ,"M2   "                ,Nil    },;
                {"AUTCONTA"    ,"0         "           ,Nil    },;
                {"AUTDTBAIXA"  ,dDataBase              ,Nil    },;
                {"AUTDTCREDITO",dDataBase              ,Nil    },;
                {"AUTHIST"     ,"BAIXA TESTE"          ,Nil    },;
                {"AUTJUROS"    ,0                      ,Nil,.T.},;
                {"AUTVALREC"   ,800                    ,Nil    }}
  
    MSExecAuto({|x,y| Fina070(x,y)},aBaixa,3)
  
  	IF lMsErroAuto
		MostraErro()
    ENDIF

RETURN