Baixas Automáticas - FINA090 - Financeiro P12

Nota

Essa rotina foi ajustada para atender a Lei Geral de Proteção de Dados (Lei n° 13.70), sendo que alguns campos que apresentam informações consideradas como dados sensíveis e/ou pessoais, serão ofuscados deixando de ser legíveis.

Nota

O processo de seleção de filiais, bem como o de baixa em múltiplas filiais através da rotina de baixas automáticas unificada estará disponível apenas a partir de abril/2022

01. VISÃO GERAL

Esta rotina permite executar a baixa automática de títulos em aberto, baixando vários títulos de uma única vez.
Os títulos são selecionados pelo usuário, mediante uma filtragem de portador, intervalo de vencimentos, motivo de baixa e borderô (caso os títulos estejam relacionados a um borderô), possibilitando a baixa de vários borderôs dentro de um intervalo especificado pelo usuário (de/até). O sistema permite ainda que seja efetuada a baixa de um ou mais títulos com cheque automaticamente.

02. MAPA MENTAL

03. EXECUÇÃO

Manual

Procedimento efetuado de forma manual via rotina Baixas Pagar Automática (FINA090), com exibição das telas envolvidas no processo e necessitando de ações/comandos do usuário

Automática

Procedimento realizado de forma automática na rotina de Baixas Pagar Automática (FINA090), sem exibição de telas ou necessidade de interação do usuário.

Utilizado em customizações onde o processo não necessita de interações do usuário (MSEXECAUTO)

Importante - Contabilização Online

Caso a contabilização seja online a baixa via rotina automática só será processada se a contabilização não estiver configurada para demonstrar a tela em casos de erro no lançamento (falta de conta, débito/crédito não batem, etc).

Somente será processada com a contabilização online se:
MV_PRELAN = S
MV_CT105MS = N
MV_ALTLCTO = N

Caso utilize a configuração para que seja demonstrado a tela de contabilização em caso de erro no lançamento, a rotina de baixa automática via execauto apenas será processada se a contabilização for Off-Line.

Exemplo de rotina automática

#INCLUDE "PROTHEUS.CH"

/*
Baixa Automática

	Baixa Automática
	----------------------
		Estrutura da aRetAuto - baixa automática
		---------------------------------------------------------
		aRetAuto [1] := aRecnos		(array contendo os Recnos dos registros a serem baixados)
		aRetAuto [2] := cBanco 		(Banco da baixa)
		aRetAuto [3] := cAgencia	(Agencia da baixa)
		aRetAuto [4] := cConta		(Conta da baixa)
		aRetAuto [5] := cCheque		(Cheque da Baixa - apenas Contas a Pagar)
		aRetAuto [6] := cLoteFin	(Lote Financeiro da baixa)
		aRetAuto [7] := cNatureza	(Natureza do movimento bancario - apenas Contas a Pagar)
		aRetAuto [8] := dBaixa		(Data da baixa)
		aRetAuto [9] := nTipoBx		(1 = Baixa somente titulos que não estao em bordero ou nTipoBx -> 2 = Baixa somente titulos em bordero)
		aRetAuto [10]:= cBcoDe 		(Portador de)
		aRetAuto [11]:= cBcoAte		(Portador Até)
		aRetAuto [12]:= dVencIni	(Vencimento Inicial)
		aRetAuto [13]:= dVencFim	(Vencimento Final)
		aRetAuto [14]:= cBord090I	(Borderô Inicial)
		aRetAuto [15]:= cBord090F	(Borderô  Final)
		aRetAuto [16]:= cBenef090	(Beneficiário do Cheque)
		aRetAuto [17]:= cHistor		(Historico do Cheque)
		aRetAuto [18]:= lMultNat	(Rateio Multiplas naturezas)
		aRetAuto [19]:= aVendor		(Array para a baixa de vendor)		

		Exemplo: 	MSExecAuto({|x, y| FINA090(x, y)}, 3, aRetAuto)

		Para definir o Motivo de Baixa (caso não informado, o default é NORMAL):
			Private _cAutoMotBx := "DEBITO CC"	

	Cancelamento de baixa:
	----------------------

		Estrutura da aRetAuto - Cancelamento automático de baixas
		---------------------------------------------------------
		nRadio		:= aRetAuto[1] //1 = Cancela Baixa de titulos titulos 	2 = cancela baixa somente titulos em bordero
		cBord1		:= aRetAuto[2] // Borderô De
		cBord2 		:= aRetAuto[3] // Borderô Até
		cDatB1		:= aRetAuto[4] // Dt. Baixa Inicial
		cDatB2		:= aRetAuto[5] // Dt. Baixa Final
		cFor1		:= aRetAuto[6] // Fornecedor De
		cFor2		:= aRetAuto[7] // Fornecedor Até
		aSelFil		:= aRetAuto[8] // Array com as filiais a serem consideradas na seleção dos titulos

*/

/*
------------------------------------------------------------------------------------
	FAut090
	
	Exemplos de processos do FINA090 Automático
------------------------------------------------------------------------------------
*/

User Function FAut090()

	Local nOpca  := 0
	Local nRadio := 1

	While .T.
		DEFINE MSDIALOG oDlg FROM  094,1 TO 230,293 TITLE "Baixa Automatica" PIXEL
			@ 05,07 TO 40, 140 OF oDlg  PIXEL
			@ 10,10 RADIO oRadio VAR nRadio;
			ITEMS "Baixa Automatica","Baixa Automatica - Vendor","Cancelamento Automatico de Baixas";
			3D SIZE 100,10 OF oDlg PIXEL

			DEFINE SBUTTON FROM 45,085 TYPE 1 ENABLE OF oDlg ACTION (nOpca := 1, oDlg:End())
			DEFINE SBUTTON FROM 45,115 TYPE 2 ENABLE OF oDlg ACTION (nOpca := 0, oDlg:End())

		ACTIVATE MSDIALOG oDlg CENTERED
		If nOpca == 1
			If nRadio == 1 		//Baixa Automática
				FBx090Aut()
				Loop
			ElseIf nRadio == 2	//Baixa Automática - Vendor
				FBx090VEN()
				Loop
			Else				//Cancelamento Automático de Baixa
				FBx090Can()
				Loop
			Endif
		Else
			Exit
		Endif
	EndDo		

Return

/*
------------------------------------------------------------------------------------
	FBx090Aut
	
	Função para realizar baixa automática - Multi-Filiais
	
	Ajustar pergunta Seleciona Filiais		- SIM
------------------------------------------------------------------------------------
*/
Static Function FBx090Aut()

	Local aRecnos	:= {}
	Local cPref		:= "091"
	Local cFil1		:= "D MG 01 "
	Local cTitulo1	:= "FIN000001"
	Local cFil2		:= "D MG 02 "
	Local cTitulo2	:= "FIN000002"
	Local cParcel	:= " "
	Local cTipo		:= "NF "
	Local cForne	:= "FIN102"
	Local cLoja		:= "01"
	Local cBanco    := "001"
	Local cAgencia	:= "00001"
	Local cConta	:= "0000000001"
	Local cCheque	:= ""
	Local dBaixa	:= dDataBase
	Local nTipoBx	:= 1
	Local cBcoDe 	:= "   "
	Local cBcoAte 	:= "ZZZ"
	Local dVencIni	:= dDataBase
	Local dVencFim	:= dDataBase
	Local cBordIni	:= "      "
	Local cBordFim	:= "ZZZZZZ"	
	Local cBenef090	:= ""
	Local cHistor	:= ""
	Local lMultNat	:= .F.
	Local cLoteFin	:= ""
	Local cNatureza := PadR("PEQ000",Len( SE2->E2_NATUREZ))
	Local aFilBx	:= {cFil1,cFil2}

	Private _cAutoMotBx := "DEBITO CC"	//Caso não informe esta variável, o motivo de baixa será NORMAL

//-- variaveis utilizadas para o controle de erro da rotina automatica
	Private lMsErroAuto		:= .F.
	Private lAutoErrNoFile	:= .T.

//-- Data base
	dDataBase := CTOD("14/07/2016")
	dBaixa	  := dDataBase
	dVencIni  := dDataBase
	dVencFim  := dDataBase

//-- Array com as informações para selecionar os títulos
	aAdd(aRecnos,PesqSE2(cFil1,cPref, cTitulo1, cParcel, cTipo, cForne, cLoja))
	aAdd(aRecnos,PesqSE2(cFil2,cPref, cTitulo2, cParcel, cTipo, cForne, cLoja))	

	aRetAuto := {}

	aAdd(aRetAuto,aRecnos	)		//(array contendo os Recnos dos registros a serem baixados)
	aAdd(aRetAuto,cBanco	)		//(Banco da baixa)
	aAdd(aRetAuto,cAgencia	)		//(Agencia da baixa)
	aAdd(aRetAuto,cConta	)		//(Conta da baixa)
	aAdd(aRetAuto,cCheque	)		//(Cheque da Baixa - apenas Contas a Pagar)
	aAdd(aRetAuto,cLoteFin	)		//(Lote Financeiro da baixa)
	aAdd(aRetAuto,cNatureza	)		//(Natureza do movimento bancario - apenas Contas a Pagar)
	aAdd(aRetAuto,dBaixa	)		//(Data da baixa)
	aAdd(aRetAuto,nTipoBx	)		//(1 = Baixa somente titulos que não estao em bordero ou nTipoBx -> 2 = Baixa somente titulos em bordero)
	aAdd(aRetAuto,cBcoDe	)		//(Portador de)
	aAdd(aRetAuto,cBcoAte	)		//(Portador Até)
	aAdd(aRetAuto,dVencIni	)		//(Vencimento Inicial)
	aAdd(aRetAuto,dVencFim	)		//(Vencimento Final)
	aAdd(aRetAuto,cBordIni	)		//(Borderô Inicial)
	aAdd(aRetAuto,cBordFim	)		//(Borderô  Final)
	aAdd(aRetAuto,cBenef090	)		//(Beneficiário do Cheque)
	aAdd(aRetAuto,cHistor	)		//(Historico do Cheque)
	aAdd(aRetAuto,lMultNat	)		//(Rateio Multiplas naturezas)
	aAdd(aRetAuto,aFilBx	)		//(Filiais para seleção dos títulos paraa baixa - apenas se Seleciona Filiais = Sim)

//-- Realiza baixa
	//3 = inclusao
	MSExecAuto({|x, y| FINA090(x, y)}, 3, aRetAuto)

	If lMsErroAuto
		MOSTRAERRO() 
	Endif
Return


/*
------------------------------------------------------------------------------------
	FBx090VEN
	
	Função para realizar baixa automática pelo motivo Vendor
------------------------------------------------------------------------------------
*/

Static Function FBx090VEN()

	Local aRetAuto  := {}
	Local aRecnos   := {}
	Local cPref		:= "PEQ"
	Local cTitulo	:= "CT090A090"
	Local cTituloV	:= "CT090V090"
	Local cParcel	:= PadR(" ",Len( SE2->E2_PARCELA ))
	Local cTipo		:= "DP "
	Local cNatureza := "PEQ000    "
	Local cForne	:= "PEQ000"
	Local cLoja		:= "00"
	Local cCheque   := ""
	Local cLoteFin	:= ""
	Local cBanco    := "001"
	Local cAgencia	:= "00001"
	Local cConta	:= "0000000001"
	Local dBaixa	:= dDatabase
	Local cFil		:= "D MG 01 "
	Local nTipoBx	:= 1
	Local cBcoDe 	:= "   "
	Local cBcoAte 	:= "ZZZ"
	Local dVencIni	:= dDatabase
	Local dVencFim	:= dDatabase
	Local cBordIni	:= "      "
	Local cBordFim	:= "ZZZZZZ"	
	Local cBenef090	:= ""
	Local cHistor	:= "BAIXA POR VENDOR"
	Local lMultNat	:= .F.
	Local cContrato := "FINA090_CT090"
	Local dDtVencV  := CTOD("20/12/2021")
	Local nTxAcresV := 5
	Local nValorV	:= 1000
	Local cNatV		:= "VENDOR    " 
	Local aFilBx	:= {}
	Local aVendor	:= {cContrato, cBanco, cAgencia, cPref, cTituloV, cParcel, cTipo, dDtVencV, nTxAcresV, cNatV, nValorV}

	Private _cAutoMotBx := "VENDOR"

//-- variaveis utilizadas para o controle de erro da rotina automatica
	Private lMsErroAuto		:= .F.
	Private lAutoErrNoFile	:= .T.

	//-- Data base
	dDataBase 	:= CTOD("14/12/2021")
	dBaixa 		:= dDataBase
	dVencIni	:= dDataBase
	dVencFim	:= dDataBase

	aAdd(aRecnos,PesqSE2(cFil,cPref, cTitulo,cParcel, cTipo, cForne, cLoja))

	aAdd(aRetAuto,aRecnos	)		//(array contendo os Recnos dos registros a serem baixados)
	aAdd(aRetAuto,cBanco	)		//(Banco da baixa)
	aAdd(aRetAuto,cAgencia	)		//(Agencia da baixa)
	aAdd(aRetAuto,cConta	)		//(Conta da baixa)
	aAdd(aRetAuto,cCheque	)		//(Cheque da Baixa - apenas Contas a Pagar)
	aAdd(aRetAuto,cLoteFin	)		//(Lote Financeiro da baixa)
	aAdd(aRetAuto,cNatureza	)		//(Natureza do movimento bancario - apenas Contas a Pagar)
	aAdd(aRetAuto,dBaixa	)		//(Data da baixa)
	aAdd(aRetAuto,nTipoBx	)		//(1 = Baixa somente titulos que não estao em bordero ou nTipoBx -> 2 = Baixa somente titulos em bordero)
	aAdd(aRetAuto,cBcoDe	)		//(Portador de)
	aAdd(aRetAuto,cBcoAte	)		//(Portador Até)
	aAdd(aRetAuto,dVencIni	)		//(Vencimento Inicial)
	aAdd(aRetAuto,dVencFim	)		//(Vencimento Final)
	aAdd(aRetAuto,cBordIni	)		//(Borderô Inicial)
	aAdd(aRetAuto,cBordFim	)		//(Borderô  Final)
	aAdd(aRetAuto,cBenef090	)		//(Beneficiário do Cheque)
	aAdd(aRetAuto,cHistor	)		//(Historico do Cheque)
	aAdd(aRetAuto,lMultNat	)		//(Rateio Multiplas naturezas)
	aAdd(aRetAuto,aFilBx	)		//(Filiais para seleção dos títulos paraa baixa - apenas se Seleciona Filiais = Sim)
	aAdd(aRetAuto,aVendor	)		//(Array com dados do Vendor)

//-- Realiza baixa
	//3 = inclusao
	MSExecAuto({|x, y| FINA090(x, y)}, 3, aRetAuto)

	If lMsErroAuto
		MOSTRAERRO() 
	Endif
Return


/*
------------------------------------------------------------------------------------
	FBx090Can
	
	Função para realizar cancelamento automático de baixas
------------------------------------------------------------------------------------
*/
Static Function FBx090Can()

	Local cFil1		:= "M PR 01 "
	Local cFil2		:= "M PR 02 "
	Local cForne	:= "FICN13"
	Local cForne2	:= "FICN14"
	Local aFiliais	:= {cFil1,cFil2}

//-- variaveis utilizadas para o controle de erro da rotina automatica
	Private lMsErroAuto		:= .F.
	Private lAutoErrNoFile	:= .T.

	//Data base
	dDataBase := CTOD("09/08/2019")
	dBaixa 	  := dDataBase

	aRetAuto := {}
		
	aAdd(aRetAuto,1			) //1 = Baixa somente titulos que não estao em bordero ou nTipoBx -> 2 = Baixa somente titulos em bordero
	aAdd(aRetAuto,"   "		) // Bordero De
	aAdd(aRetAuto,"ZZZZZ"	) // Bordero Até
	aAdd(aRetAuto,dDataBase	) // Dt. Baixa Inicial
	aAdd(aRetAuto,dDataBase	) // Dt. Baixa Final
	aAdd(aRetAuto,cForne	) // Fornecedor De
	aAdd(aRetAuto,cForne2	) // Fornecedor Ate
	aAdd(aRetAuto,aFiliais	) //Títulos Baixados	 

//-- Realiza Cancelamento da baixa
	//4 = Cancelamento
	MSExecAuto({|x, y| FINA090(x, y)}, 4, aRetAuto)

	If lMsErroAuto
		MOSTRAERRO() 
	Endif

Return



/*
------------------------------------------------------------------------------------
	PesqSE2
	
	Função para retornar o Recno do título a ser baixado
	
	@param cFilOri	 , Character, Filial de origem do título (E2_FILORIG)
	@param cPrefOri	 , Character, Prefixo do titulo (E2_PREFIXO)
	@param cNumOri 	 , Character, Número do titulo (E2_NUM)
	@param cParcOri  , Character, Parcela do titulo (E2_PARCELA)
	@param cTipoOri  , Character, Tipo do titulo (E2_TIPO)
	@param cCfOri    , Character, Fornecedor do titulo (E2_FORNECE)
	@param cLojaOri  , Character, Loja do titulo (E2_LOJA)

	@retorno nRec, Numeric, Recno do registro a ser baixado

------------------------------------------------------------------------------------
*/
Static Function PesqSE2(cFilOri, cPref, cTitulo, cParcel, cTipo, cForne, cLoja )

	Local aAreaSE2  := SE2->(GetArea())
	Local nRec 		:= 0

	DEFAULT cFilOri := cFilAnt

	SE2->(DbSetOrder(1))
	If DbSeek (xFilial("SE2", cFilOri) + cPref + cTitulo + cParcel + cTipo + cForne + cLoja)
		nRec := SE2-> (RECNO())
	Endif

	RestArea(aAreaSE2)

Return nRec

04. OPERAÇÕES

Procedimento para baixa de títulos a pagar de quaisquer naturezas do módulo Financeiro.

Ao acionar esta opção, verifique o preenchimento dos principais campos e confirme o procedimento.

Exemplo:

Baixar: selecione a opção desejada entre Títulos ou borderôs.

Títulos: Exibe apenas títulos que não estão em borderô

Borderôs: Carrega apenas títulos em borderô

Portador: define um intervalo de portadores para que seja realizado o filtro dos títulos que serão baixados.
Vencimento: define um intervalo de vencimentos dos títulos que serão baixados. Dessa forma, o sistema considera apenas os títulos referentes ao portador informado.
Borderô: define o intervalo de borderôs a serem considerados no processo. Este campo somente estará habilitado caso a escolha de Baixar seja Borderô.
Mot. Baixa : define o motivo de baixa a ser aplicado ao processo.
Banco: define o código do banco para a geração dos movimentos bancários referentes a baixa. Este campo somente estará habilitado caso o Mot. Baixa permita a geração do movimento bancário.
Agência: define o código da agência do banco para a geração dos movimentos bancários referentes a baixa. Este campo somente estará habilitado caso o Mot. Baixa permita a geração do movimento bancário.
Conta: define o código da conta corrente do banco para a geração dos movimentos bancários referentes a baixa. Este campo somente estará habilitado caso o Mot. Baixa permita a geração do movimento bancário.
Cheque: define o código do cheque a ser gerado no processo de baixas. Este campo somente estará habilitado caso o Mot. Baixa permita a geração de cheque e a pergunta Gera cheque Autom. = Sim
Beneficiário: define o beneficiário do cheque gerado para o processo de baixas.
Natureza Movto.: define a natureza financeira que irá classificar o movimento bancário. Não afeta de qualquer maneira eventuais retenções de impostos.
Lote: define o lote que agrupa o processo de baixas. Este campo somente estará habilitado caso se opte pelo movimento totalizador (vide parâmetro MV_BXCNAB) ou ponto de entrada F090NATLOT tenha retorno .T.
Histórico do Cheque: define o histórico do cheque. Este campo somente estará habilitado caso o Mot. Baixa permita a geração de cheque e a pergunta Gera cheque Autom. = Sim
Dt Baixa: define a data a ser registrar como data de baixa do processo.
Rateio Multi Naturezas: define se a baixa replicará o rateio múltiplas naturezas informado na emissão do título. Este campo somente estará habilitado caso o parâmetro MV_MULNATP esteja habilitado.

Clique em OK.

Caso a pergunta Seleciona Filiais = Sim, será apresentada tela para a seleção de filiais a serem consideradas para a seleção dos títulos a serem baixados.

Selecione as filiais desejadas.

Caso a pergunta Seleciona Filiais = Não, a filial logada será considerada como única filial para a seleção dos títulos a serem baixados.

Em seguida será apresentada a tela da seleção dos títulos a serem baixados no processo.

Selecione os títulos desejados e clique em Salvar.

O processo será realizado e os títulos baixados de acordo com a parametrização efetuada.

Importante

Sobre a baixa de títulos do tipo PA - (Pagamento Antecipado).
Quando realizamos uma baixa de um PA que já sofreu movimentação bancária esta baixa é considerada a devolução daquele valor, ou seja, é gerado um movimento bancário a receber.

Atualmente a rotina Baixa Automática a Pagar (FINA090) não possui tratamentos para cheques recebidos,

No processo padrão serão gerados cheques, referentes aos pagamentos de títulos, apenas aqueles que irão gerar movimentos bancários a pagar.

Títulos em moeda estrangeira

Baixa de títulos de múltiplas moedas utilizando banco em moeda corrente (01), todos os títulos serão baixados no processo. Para bancos em moeda estrangeira, permite a baixa apenas dos títulos que estão na mesma moeda do banco.

Permite a pesquisa de informações para o título selecionado com a utilização de filtros que as ordenam de acordo com a característica desejada.

O índice escolhido na pesquisa será usado para ordenar a tela de seleção de títulos, permitindo que o usuário escolha qual a ordenação da tela de seleção.

Exemplo:

filial+ordem pagto.

Procedimento para permitir que um processo de baixa seja cancelado de forma automática, dentro de determinadas condições.

Acesse Outras Ações → Cancelamento Automático de Baixas

Exemplo:

Cancelar Baixas: selecione a opção desejada entre Títulos ou borderôs.

Títulos: Exibe apenas títulos que não estão em borderô

Borderôs: Carrega apenas títulos em borderô

Borderô De/ Borderô Até: define um intervalo de borderôs a serem considerados no processo. Este campo somente estará habilitado caso a escolha de Baixar seja Borderô.
Dt. Baixa De/ Dt. Baixa Até: define um intervalo datas a serem considerados no processo.
Fornecedor De/ Fornecedor Até: define o intervalo de códigos de fornecedores a serem considerados no processo.
Seleciona Filiais : define se será permitido o cancelamento de baixas de múltiplas filiais.
Quando marcado, permite a apresentação de tela para escolha das filiais a serem consideradas no processo.
Caso contrário, apenas títulos da filial corrente serão considerados para o processo.

Clique em OK para prosseguir.

Será apresentada a tela para a seleção dos títulos a terem suas baixas canceladas.

Selecione os título e clique no botão Confirmar, para que o processo de cancelamento seja realizado.

Nesta opção é possível localizar e exibir os lançamentos contábeis a partir do documento que os originou.

Apresenta consulta com o rateio de múltiplas naturezas do título posicionado no browse.
Esta apresentação depende da ativação do processo de rateios de múltiplas naturezas para contas a pagar (parâmetro MV_MULNATP)

Apresenta consulta das retenções de impostos ocorridas com configurações do Configurador de Tributos - Regras Financeiras.

Apresenta quadro das legendas e seus significados referenciados a situação do título de contas a pagar.

A legenda pode ser visualizada na primeira coluna do browse.

05. PARÂMETROS APLICADOS

Lista de parâmetros aplicados ao FINA090 e seu processamento

Pergunta	Descrição
Mostra Lanc. Contábil ?	Informe a opção "SIM" para que os lançamentos contábeis gerados através da compensação sejam exibidos em tela, ou "NAO", caso contrario
Aglutina Lançamentos ?	Informe a opção "SIM" para que os lançamentos contábeis gerados através da compensação sejam aglutinados em um único lançamento.
Contabiliza On Line ?	Informe se "SIM" para que a contabilização dos lançamentos referentes a baixa de contas a pagar sejam realizados online, ou "NAO", caso contrario.
Gera cheque Autom. ?	Informe a opção “Sim” para que as baixas a pagar automáticas gerem os cheques para o pagamento dos respectivos títulos, o “Não”, caso contrário. Nota Por meio da rotina de Liberação de Cheques o sistema permite que os cheques gerados possam ser liberados on-line, de acordo com o preenchimento do parâmetro MV_LIBCHEQ. Quando o conteúdo é S, os cheques são liberados automaticamente e quando é N devem, obrigatoriamente, passar por esta opção. A movimentação bancária referente aos cheques ocorre quando houver liberação on-line ou após o procedimento de liberação de cheques.
Contabiliza Borderô ?	Indica se a contabilização do LP 532, baseada na variável VALOR, será feita desmembrada Borderô a Borderô ou a contabilização de todos os borderôs em somente um total.
Tipo de Desconto ?	Informe o tipo de desconto concebido ao(s) título(s), caso houver. Esta informação será utilizada no Fiscal, bloco F100 do SPED. ATENÇÃO - Esta pergunta se aplica somente a localização BRA (Brasil)
Seleciona Filiais ?	Selecione SIM para que seja possível selecionar as filiais a serem consideradas para o processo. Caso selecione NÃO, apenas a filial atual será considerada para o processo. Nota O processo de seleção de filiais, bem como o de baixa em múltiplas filiais estará disponível apenas em abril/2022
Contabiliza na Filial Logada ?	Selecione 1-SIM para contabilizar na filial logada ou 2-NÃO para contabilizar na filial de origem do título. Nota Este parâmetro só é válido para situações que a contabilização é feita título a título. Disponível após aplicação da expedição contínua de dicionário de Outubro/2022.
Considera BCO/AG/CTA Borderô ?	SIM - As movimentações de baixa deve considerar o banco que foi utilizado quando o borderô foi criado. NÃO - Informar na tela de baixa qual banco deve ser feito as movimentações de baixa (DEFAULT). IMPORTANTE Independente da escolha da pergunta SIM ou NÃO, se o parâmetro MV_BXCNAB = S e ao realizar a baixa com mais de 1 borderô, será gerado apenas 1 único totalizador com o banco escolhido em tela. Caso a escolha da pergunta seja SIM e MV_BXCNAB = S, deve-se realizar a baixa individual de cada borderô para que a movimentação da baixa receba o banco, agência e conta gravado no borderô. Nota Disponível após aplicação da expedição contínua de dicionário de Dezembro/2022.

Parâmetro	Descrição	Default
MV_AG10925	Indica se os impostos do PCC serão aglutinados em um titulo apenas quando ocorrerem os três impostos no mesmo titulo.	2
MV_ALTLCTO	Permite alterar lançamento contábil de integração?(S)Sim ou (N)Nao.	S
MV_ATUFORN	Indica se atualização de saldos do fornecedor deverá ser executada on-line, nas baixas automáticas a pagar.	.T.
MV_ATUSLBC	Indica se atualização de saldos bancários devera ser executada on-line, nas baixas automáticas a pagar.	.T.
MV_BX10925	Define momento do tratamento da retenção dos impostos Pis Cofins e Csll 1 = Na Baixa ou 2 = Na Emissão	1
MV_BXAUTVE	Ativa a Baixa Automática de títulos com motivo VENDOR	.F.
MV_BXCNAB	Define se as baixas dos títulos no retorno do CNAB devem ser aglutinadas. (S)im ou (N)ão.	N
MV_BXDTFIN	Não permite data de baixa menor que o a data contida no parâmetro MV_DATAFIM (1=Permite, 2=Não Permite)	2
MV_BXTXA	Tratamento para controle da baixa de títulos TXA na baixa automática. 1 = Permite Baixar 2 = Não zera o saldo.	1
MV_CALCCM	Indica se o calculo de correção monetária será ou não efetuado. Validos: "S" - calcula ou "N" - não calcula.	S
MV_CARTEIR	Codigos dos bancos que operam em carteira.
MV_CHQBOR	Indica se sera permitido informar numero cheque quando titulo estiver em borderô.	S
MV_COFINS	Natureza para títulos referentes ao COFINS	COFINS
MV_CSLL	Natureza para títulos referentes ao CSLL	CSLL
MV_CTBAIXA	Define se a taxa informada na compensação será utilizada em todo o processo. T = Tx no Processo, F = Tx Individual	.F.
MV_CTBFLAG	Indica se a marcação dos flags de contabilização das rotinas off-line será feita na transação do lançamento contábil - SIGACTB.	.F.
MV_CTLIPAG	Controla as baixas a pagar através da data de liberação preenchida, caso .T. o sistema verifica se o campo E2_DATALIB preenchido, caso contrario não controla	.F.
MV_CTMOVPA	Indica se a Contabilização Off do LP513 ocorrerá pelo Título(SE2) ou Mov. Bancário(SE5) do Pagamento Antecipado. 1="SE2" / 2="SE5"	1
MV_CXFIN	Caixa Geral Financeiro	CX1/00001/0000000001
MV_DTCNBXP	Data para contabilização Online baixas pagar: 1- Data Digitação; 2- Data Disponibilidade; 3- Data Pagamento	3
MV_EASYFIN	Define se a Easy Import Control e integrado com o Financeiro	N
MV_ESTADO	Sigla do estado da empresa usuária do Sistema.	SP
MV_FATOUT	Time out para seleção do registro pelo usuário (em segundos) Caso o usuário demore mais tempo a tela é fechada.	900
MV_FINVDOC	Ativa o controle de documentos obrigatórios nas rotinas de liberação para baixa / movimentação dos títulos a pagar? ("1" = Sim / "2" = Não)	2
MV_IRF	Natureza para títulos referentes ao IRF	IRF
MV_ISS	Natureza para títulos referentes ao ISS	ISS
MV_JFILBCO	Indica se deve filtrar as contas correntes vinculadas ao escritório logado. (.T.=Sim ou .F.=Não)	.F.
MV_JURXFIN	Habilita a integração entre os módulos SIGAFIN - Financeiro e SIGAPFS - Jurídico Padrão desabilitado.
MV_LIBCHEQ	Opção para liberação de saldo bancário quando da geração de cheques antes da baixa.	S
MV_MCUSTO	Moeda utilizada para verificação do limite de credito que foi informado no cadastro de clientes.	2
MV_MRETISS	Modo de retenção do ISS nas aquisições de serviços 1 = na emissão do título principal; 2 = na baixa do título principal	1
MV_MSGTIME	Informe (em segundos) o tempo em que o sistema exibirá a mensagem ao usuário, avisando o que está acabando o tempo de utilização da tela.	120
MV_MULNATP	Utilizado para identificar se o título utiliza múltiplas naturezas no contas a pagar
MV_MUNIC	Utilizado para identificar o código dado a secretaria das finanças do município para recolher o ISS.	MUNIC
MV_NGMNTFI	Integração Manutenção (MNT) com Financeiro (FIN) Informar S=Sim, P=Pedido ou N=Não	N
MV_PCOINTE	Indica se a integração dos processos do Planejamento e Controle Orçamentário com os processos de Lançamentos / Bloqueios esta ativa (1=Sim/ 2=Não).	2
MV_PISNAT	Natureza para títulos referentes ao PIS	PIS
MV_PRELAN	Indica se o Lançamento Contábil será automaticamente lançado ou passara por Pré-lançamento. S=Sempre, N=Nunca, D=Doc. Inconsistente	N
MV_RT10925	Modo padrão de operação do sistema quanto a retenção de PIS/COFINS/CSLL. (1=Calculado p/sistema, 2=Efetua retenção sempre, 3=Não efetua retenção)	1
MV_SOLNCP	Define se deve ser usada a rotina de solicitação de Nota de credito	.F.
MV_UNIAO	Utilizado para identificar o código dado a secretaria da Receita Federal para pagamento do Imposto de Renda.	UNIAO
MV_VL10925	Valor máximo de pagamentos no período para dispensa da retenção de PIS/COFINS/CSLL (aplicável apenas a empresa pública ou cálculos anteriores a 22/06/2015.)	5000
MV_VLMINPG	Valor mínimo para executar a baixa do título, mesmo que o campo E2_DATALIB não esteja preenchido e o parâmetro MV_CTLIPAG seja .T.	0
MV_VLMPUB	Valor mínimo a ser considerado na soma do PCC e IRRF para dispensa de retenção para Empresas Públicas.	10
MV_VLTITAD	Verificar no momento de baixas a pagar, se o fornecedor possui títulos de adiantamento para compensação. T = Ativa verificação ou F = Não ativa.	F

06. CONTABILIDADE

A contabilização dos processos aplicados a uma compensação contas a pagar via módulo Financeiro é feita pelos lançamentos padrões abaixo:

LP	Fato Gerador	ON	OFF
530	Na baixa de títulos a pagar	X	X
532	Na baixa de títulos a pagar em Borderô	X	X
513	Na inclusão de movimento bancário de adiantamento Vide parâmetro MV_CTMOVPA	X	X

Borderô

Borderôs: Para títulos normais o lançamento padrão será o 532, já para títulos de adiantamento o lançamento padrão é o 513

Os impostos com fato gerador "Caixa" (na baixa) gerados pelo borderô, deverão ser contabilizados pelo LP 530.
Observação: Caso o parâmetro "Contabiliza por?" esteja configurado como "Borderô/borderô" o LP 513 não será contabilizado.

Histórico.

Caso necessário resgatar o número do borderô e informar no histórico no momento da contabilização, deverá ser utilizado o campo SEA→EA_NUMBOR.
Observação: Essa opção irá retornar o valor do Borderô correto somente quando o parâmetro "Contabiliza por?" esteja configurado como "Borderô/borderô".

Nota

Contabilização por tipo de baixa:

Títulos: Para títulos normais o lançamento padrão será o 530, já para títulos de adiantamento o lançamento padrão é o 513.

07. TABELAS RELACIONADAS

SE2 - Cadastro do contas a pagar
SE5 - Cadastro de cheques
SED - Cadastro de Naturezas.
SA2 - Cadastro de Fornecedores.
FK2 - Baixas a Pagar.
FK3 - Impostos Calculados.
FK4 - Impostos Retidos.
FK5 - Movimentos Bancários.
FK6 - Valores acessórios.
FK7 - Tabela Auxiliar
FKA - Rastreio de movimento.

08. PONTOS DE ENTRADA

Pontos de Entrada - FINA090

Ponto de entrada	Observação	Link
F090ADBTN	Permite incluir botões na tela (enchoicebar), em que são selecionados os títulos a serem baixados de forma automática.	F090AdBtn - Inclui botões na tela
F090ADDB	Ponto de entrada para adicionar rotinas e botões na aRotina.	F090ADDB - Permite a inclusão de rotinas e botões no menu da rotina FINA090
F090ADFR	Ponto de entrada para manipulação do filtro que seleciona os registros pendentes de adiantamentos (PA) e/ou notas de débito (NDF/DIC) do fornecedor do título a ser baixado	F090ADFR - Manipulação do filtro que seleciona os registros de adiantamentos e/ou notas de débito do fornecedor.
F090BROW	Executado antes da chamada da mBrowse.	F090BROW - Baixa automática
F090CHOK	Permite validar a utilização ou não das baixas automáticas.	F090CHOK - Valida baixas automáticas
F090CPOS	Trata os campos que serão apresentados na tela de seleção dos títulos que serão baixados pela rotina de baixa automática	F090CPOS - Tratamento de campos
F090DESC	Permite informar os descontos para cada título liberado para baixa que foi pago antecipadamente.	F090DESC - Concede desconto para cada título liberado para baixa que foi pago antecipadamente.
F090FIL	Permite a alteração do filtro padrão do processo de baixa automático	F090FIL - Filtro de dados
F090FILB	Adiciona filtros específicos (de usuário) no browse inicial (específico para Brasil).	F090FILB - Definir filtro em SQL
F090FILEMI	Tem como finalidade permitir ao cliente customizar qual campo de data de emissão será considerado no filtro dos títulos trazidos para a baixa automática.	F090FILEMI - Customização do cliente
F090FLBR	Adiciona filtros específicos (de usuário) no browse inicial (específico para mercado internacional).	F090FLBR - Ponto de entrada para filtrar os registros da browse na Baixa Pagar Automática, exceto localização Brasil.
F090GAVE	Manipula os dados de filtro para montagem da tela inicial de baixa automática.	F090GAVE - Manipula filtro para montagem de baixa automática
	Utilizado para gravação do log.	F090LOG - Gravação de log
F090MNAT	Habilita ou desabilita a opção de múltiplas naturezas.	F090MNAT - Opção de múltiplas Naturezas
F090MTBX	Permite criar como padrão, um outro motivo de baixa, ao acessar a tela da rotina Baixa Automática, a fim de facilitar a operação.	F090MTBX - Altera motivo de baixa autom.
F090NATLOT	Permite a liberação dos campos Natureza Financeira e Lote da Baixa para digitação mesmo quando o parâmetro MV_BXCNAB estando como não.	F090NATLOT - Liberação de campos na baixa automática
F090NLOTE	Permite manipular a variável cLoteFin.	F090NLOTE - Manipula variável cLoteFin
F090PABX	Utilizado para verificação da existência de títulos do tipo PA (Pagamento antecipado) de um determinado fornecedor, no momento da baixa de um título.	F090PABX - Verificação de PAs de Fornecedor na Baixa de Título
F090POSTIT	Posiciona o título desejado no momento da seleção de títulos na baixa automática a Pagar.	F090POSTIT - Baixa automática posicionamento de Títulos CP
F090QFIL	A finalidade do ponto de entrada F090QFIL é permitir complementar o filtro padrão dos registros da Baixa Pagar Automática (FINA090).	F090QFIL - Ponto de entrada para filtrar os registros da Baixa Pagar Automática
F090REST	Executado após o destravar os registros de todas as tabelas envolvidas na gravação da Baixa Automática, é utilizado para realizar alguma operação após a gravação da Baixa Automática.	F090REST - Gravação e restauração dos índices
F090SE5	manipula movimentos bancários processados tendo como parâmetro o Recno dos registros SE5 que foram utilizados na baixa automática.	F090SE5 - Manipula movimentos bancários processados na baixa automática
F090TIPO	Este ponto de entrada permitirá selecionar quais tipos de títulos serão desconsiderados na baixa a pagar automática.	F090TIPO - Seleciona Tipos de Título
F090TIT	Utilizado na marcação dos títulos que serão baixados.	F090TIT - Marca título na baixa
F090TOK	Utilizado para validar informações adicionais na função Valida dados para baixa automática	F090TOK - Validações adicionais dos dados
F090VLEX	Tratamentos específicos para informações da tabela temporária.	F090VLEX – Tratamentos específicos para informações da tabela temporária.
F091FBX	Controle das Filiais da Baixa de Títulos para as Multi-Filiais	F091FBX - Controle das Filiais da Baixa de Títulos para as Multi-Filiais
	Tratamento da natureza de um título baixado que não possui campo natureza preenchido	F091Natur - Tratamento da natureza de um título baixado que não possui campo natureza preenchido
F90SE5GRV	Gravações complementares na SE5 após a baixa	F90SE5GRV - Gravações complementares na SE5 após a baixa
F90TOTGRV	Gravações complementares no registro totalizador da baixa	F90TOTGRV - Gravações complementares no registro totalizador da baixa
FA080SEF	Após a gravação do cheque quando na baixa se informa o cheque.	FA080SEF - Grava cheque
FA090BCO	Será executado após digitar o código do banco na baixa a pagar automática.	FA090BCO - Valida código do banco
	Será executado após confirmar a baixa automática e será utilizado para calcular o valor da correção monetária para cada um dos títulos	FA090COR- Calcula valor da correção monetária
FA090DES	Será executado após confirmação da baixa automática e será utilizado para calcular o valor de desconto para cada um dos títulos	FA090DES - Calcula valor de desconto
FA090JUR	Será executado após confirmar a baixa automática e será utilizado para calcular o valor dos juros para cada um dos títulos	FA090JUR - Calcula valor dos juros
FA090MUL	Será executado após confirmar a baixa automática e será utilizado para calcular o valor da multa para cada um dos títulos	FA090MUL - Calcula valor da multa
FA090POS	Permite tratamento das variáveis (CBCO090, CAGE090, CTA090, CCHEQ090).	FA090POS - Ponto de entrada para tratamento de variáveis da rotina FINA090
FA090TIT	Utilizado na confirmação da baixa dos títulos.	FA090TIT - Confirma a Baixa do título
FA090TX	Será executado após a baixa do titulo no SE2.	FA090TX - Baixa título

09. CONTEÚDOS RELACIONADOS

Árvore de páginas

Baixas Automáticas - FINA090 - Financeiro P12

01. VISÃO GERAL

02. MAPA MENTAL

03. EXECUÇÃO

04. OPERAÇÕES

05. PARÂMETROS APLICADOS

06. CONTABILIDADE

07. TABELAS RELACIONADAS

08. PONTOS DE ENTRADA

09. CONTEÚDOS RELACIONADOS