F030TITABER - Alterações nos campos da lista de títulos -- 11577

Permite a inclusão/Alteração/Exclusão dos campos na lista de títulos em aberto da consulta de posição de fornecedores.

Ponto de Entrada possui 3 etapas, estas, apontadas na primeira ocorrencia ao qual se passa na chamada do ponto de entrada que, deve ser tratada exatamente como no exemplo abaixo:

(1) - Etapa de adicionar os campos no array que compunham o aquivo de dados:
Nessa etapa, a segunda ocorrencia trazida pelo paramixb é a array original dos campos que deve ser usada para ser retornado como resultado do processamento para a etapa 1.

(2) - Etapa de Abastecimento dos campos adicionados na etapa 1.

(3) - Etapa de Tratamento do ListBox:
Nessa etapa, a segunda ocorrencia trazida pelo paramixb é o tamanho da janela que deve ser usada conforme o exemplo, e as proximas ocorrencias (paramixb[3]...paramixb[19]) são os labels de cada campo, esses, na ordem ao qual o exemplo mostra e que deve ser utilizado.


Exemplo:


User Function F030TITABER()	
Local aCamposPe := {}
If Paramixb[1] == 1 // Somente incluir os campos	
    //Processo de Inclusão do campo na array de criação do arquivo da aba titulos em aberto    
    aCamposPe := Paramixb[2]
    aAdd(aCamposPe,{"TESTE","C", 20, 0, "Campo de Teste"}) 
    aAdd(aCamposPe,{"TESTEN","N", 5, 0, "Teste Numerico"})           
    
    Return aCamposPe
    
ElseIf Paramixb[1] == 2 // Somente abastacer os campos já inclusos anteriormente
	// Processo de Abastecimento dos campos adicionados no arquivo da aba titulos em aberto	
	Replace TESTE  With  "TESTE EVIDENCIADO OK"	
	Replace TESTEN With 12345		
	
ElseIf Paramixb[1] == 3
	// Processo de Adicionar os campos tratados no ponto de entrada no objeto LISTBOX da aba titulos em aberto		
	aPosObj := Paramixb[2]		
	@ aPosObj[2,1]-48,aPosObj[2,2]-2 LISTBOX oLbx FIELDS cArq1->PREFIXO,cArq1->NUMERO,cArq1->PARCELA,cArq1->TIPO,cArq1->EMISSAO,cArq1->DATAVENC,cArq1->NATUREZA, ;
	Transform(cArq1->SALDOPAGAR,PesqPict("SE2","E2_SALDO")),Transform(cArq1->ATRASO,"999999"),Transform(cArq1->VALORJUROS,PesqPict("SE2","E2_SALDO")),Transform(cArq1->VLR_IR,PesqPict("SE2","E2_SALDO")),;
	Transform(cArq1->VLR_ISS,PesqPict("SE2","E2_SALDO")),Transform(cArq1->VLR_INSS,PesqPict("SE2","E2_SALDO")),cArq1->NUMBCO,cArq1->HISTORICO,;
	Transform(cArq1->ACRESCIMO,PesqPict("SE2","E2_ACRESC")),Transform(cArq1->DECRESCIMO,PesqPict("SE2","E2_DECRESC")),cArq1->TESTE,Transform(cArq1->TESTEN,"@E 99999");
	HEADER Paramixb[3],Paramixb[4],Paramixb[5],Paramixb[6],Paramixb[7],Paramixb[8],Paramixb[9],Paramixb[10],Paramixb[11],Paramixb[12],Paramixb[13],Paramixb[14],Paramixb[15],Paramixb[16],Paramixb[17],Paramixb[18],Paramixb[19], "CAMPO ALFA","CAMPO NUMERICO" SIZE aPosObj[2,4]-9,aPosObj[2,3]-82 OF oFolder030:aDialogs[2] PIXEL 	
				
Endif	
Return


Obs: Note que as labels "CAMPO ALFA","CAMPO NUMERICO" que estão sendo informadas logo após o Header e os campos cArq1->TESTE,Transform(cArq1->TESTEN,"@E 99999") logo após o Fields são os dados customizados.  Tirando esses dados, resta o padrão do protheus, então, caso o restante seja alterado, o padrão protheus será alterado.

FINC030.PRW

F030TITABER - Alterações nos campos da lista de títulos ( < depende da etapa> ) --> depende da etapa

depende da etapa(nulo)
• vide descrição