TOTVSTEC

Árvore de páginas

Esta annotation deve ser utilizada quando for necessário desenvolver uma aplicação que responderá pelo método/verbo GET. Este método/verbo solicita uma representação do recurso especificado na Uri. Abaixo veremos exemplos de sua utilização:


Exemplo utilizando função e recebendo parâmetro via path param

#include "tlpp-core.th"
#include "tlpp-rest.th"
​
/* --------------------------------------- */
@Get("examples/function/get/path/user/:user")
User Function examplesFunctionGetPath()
    Local cJson := ""
    Local jPath
​
    jPath := JsonObject():New()
    jPath := oRest:getPathParamsRequest()
​
    If (jPath <> Nil)
        cJson := '[ { "description": "functionExamplesGetPath successfully executed, parameter received: ' + jPath['user'] +'"} ]'
    Endif
Return oRest:setResponse(cJson)

Exemplo utilizando função e recebendo parâmetro via query string

#include "tlpp-core.th"
#include "tlpp-rest.th"
​
/* --------------------------------------- */
@Get("examples/function/get/query/user")
User Function examplesFunctionGetQuery()
    Local cJson := ""
    Local jQuery
​
    jQuery := JsonObject():New()
    jQuery := oRest:getQueryRequest()
​
    If (jQuery <> Nil)
        cJson := '[ {"description": "examplesFunctionGetQuery successfully executed, parameter received: ' + jQuery['user'] + '"} ]'
    Endif
Return oRest:setResponse(cJson)


Exemplo utilizando classe com métodos recebendo parâmetro via path param e query string.

#include "tlpp-core.th"
#include "tlpp-rest.th"
​
Class classGetExamples
​
    Public Method New()

    @Get("examples/class/get/path/user/:user")
    Public Method metodExamplesGetPath()

    @Get("examples/class/get/query/user")
    Public Method metodExamplesGetQuery()
​
EndClass
​
Method New() class classGetExamples
​
Return self
​
/* --------------------------------------- */
Method methodExamplesGetPath() class classGetExamples
​
    Local cJson := ""
    Local jPath
​
    jPath := JsonObject():New()
    jPath := oRest:getPathParamsRequest()
​
    If (jPath <> Nil)
        cJson := '[ {"description": "methodExamplesGetPath successfully executed, parameter received: ' + jPath['user'] + '"} ]'
    Endif
Return oRest:setResponse(cJson)
​
/* --------------------------------------- */
Method methodExamplesGetQuery() class classGetExamples
    Local cJson := ""
    Local jQuery
​
    jQuery := JsonObject():New()
    jQuery := oRest:getQueryRequest()
​
    If (jQuery <> Nil)
        cJson := '[ {"description": "methodExamplesGetQuery successfully executed, parameter received: ' + jQuery['user'] + '"} ]'
    Endif
Return oRest:setResponse(cJson)

Atenção:

Os objetos JSON retornados por métodos de oRest, como por exemplo oRest:getQueryRequest(), são referências ao objeto existente no REST e não uma cópia.

Existem alguns motivos para ser uma referência, são eles:

  • Melhorar performance do serviço;
  • Economia de memória;
  • Evitar que seja necessário limpar o objeto na saída da implementação do serviço REST.

Portanto, é imprescindível que não se manipule diretamente o Objeto, pois isso irá refletir nas próximas requisições, causando problemas difíceis de serem detectados.

Métodos:

oRest:getPathParamsRequest()
oRest:getQueryRequest()
oRest:getHeaderRequest()
oRest:getThreadPoolTlppData()
oRest:getServerTlppData()
oRest:getThreadPoolUserData()
oRest:getThreadPoolServerUserData()
oRest:getHeaderResponse()

  • Sem rótulos