Linha Microsiga Protheus

Árvore de páginas

Ponto de entrada que habilita tela para informação do novo código de estoque na rotina de Análise Técnica (MNTA600)

Características do Requisito

Linha de Produto:

Microsiga Protheus

Segmento:

Manufatura

Módulo:

SIGAMNT - Manutenção de Ativos e Gestão de Frotas

Rotina:

Rotina

Nome Técnico

MNTA600

Análise Técnica


Rotina(s) envolvida(s)

Nome Técnico

MNTA6001

Ponto de Entrada

País(es):

Todos

Banco(s) de Dados:

Todos

Sistema(s) Operacional(is):

Todos


Ponto de Entrada

Descrição:

Ponto de entrada executado na rotina de Análise Técnica (MNTA600) que habilita a tela para informação do novo código do estoque para os motivos não informados no parâmetro MV_NG1ANAT.

Programa Fonte:

MNTA600.prx
Localização:SIGAMNT: Atualizações/Controle de Pneus/Análise Técnica/Análise Técnica 

Função:

MNTA6001()

Retorno:

.T.
Exemplo do Ponto de Entrada MNTA6001()
#Include 'Protheus.ch'

User Function MNTA6001()

	Local oFontB, oFontN, oDlgP
	Local nOpca := 0
	Local lFim  := PARAMIXB[1]
	
	If lFim	
		MsgStop("Será necessário informar o novo código do produto para o 'Destino' selecionado!","ATENÇÃO")
	EndIf
	
	dbSelectArea("ST9")
	dbSetOrder(01)
	If dbSeek(xFilial("ST9")+M->TR4_CODBEM)	
		If !Empty(ST9->T9_CODESTO) .AND. cUsaIntEs == 'S'		
			Define Font oFontB Name "Arial" Size 07,17 Bold		
			Define Font oFontN Name "Arial" Size 07,17		
			Define msDialog oDlgP Title "Informe o novo código de produto" From 000,000 To 150,650 Pixel		
			oPnlPai := TPanel():New(00,00,,oDlgP,,,,,,465,195,.F.,.F.)				
			oPnlPai:Align := CONTROL_ALIGN_ALLCLIENT		
			@ 7,008 Say OemToAnsi("Informe o novo código de produto para o pneu ") Font oFontN Size 400,10 Of oPnlPai Pixel		
			@ 7,141 Say OemToAnsi(AllTrim(M->TR4_CODBEM)+", ") Font oFontB Size 400,10 Of oPnlPai Pixel		
			@ 7,141+(4.5*(Len(AllTrim(M->TR4_CODBEM)))) Say OemToAnsi("cujo status foi alterado para ") Font oFontN Size 400,10 Of oPnlPai Pixel		
			@ 18,008 Say OemToAnsi(NGRETSX3BOX("TR4_DESTIN",M->TR4_DESTIN)+".") Font oFontB Size 400,10 Of oPnlPai Pixel									  		
			@ 35,008 Say OemToAnsi("Produto") Size 47,07 Of oPnlPai Pixel		
			@ 33,045 MsGet cCodProd OF oPnlPai Pixel Picture "@!" F3 "SB1" Valid MNT600PROD(cCodProd) HASBUTTON		
			@ 33,140 MsGet cNomCodP OF oPnlPai Pixel Picture '@!' When .f.		
			@ 50,008 Say OemToAnsi("Almoxarifado") Size 47,07 Of oPnlPai Pixel		
			@ 48,045 MsGet cCodAlmo OF oPnlPai Pixel Picture "@!" Valid NaoVazio()		
			Activate MsDialog oDlgP On Init EnchoiceBar(oDlgP,{|| (nOpca:=1,oDlgP:End())},{||oDlgP:End()}) Center		
			
			If nOpca == 1			
				cCodST9Est := cCodProd			
				cCodST9Alm := cCodAlmo		
			Else			
				cCodST9Est := ' '			
				cCodST9Alm := ' '		
			EndIf	
		EndIf
	EndIf
	
Return .T.