Linha Microsiga Protheus

Árvore de páginas

Ponto de entrada que permite alterar o tipo de montagem do browse na rotina de Retorno (MNTA400)

Características do Requisito

Linha de Produto:

Microsiga Protheus

Segmento:

Manufatura

Módulo:

SIGAMNT - Manutenção de Ativos e Gestão de Frotas

Rotina:

Rotina

Nome Técnico

MNTA400

Retorno

Rotina(s) envolvida(s)

Nome Técnico

MNTA400H

Ponto de entrada

País(es):

Todos

Banco(s) de Dados:

Todos

Sistema(s) Operacional(is):

Todos




Ponto de Entrada

Descrição:

Ponto de entrada executado na rotina de Retorno (MNTA400) que permite alterar o tipo de criação do browse

Localização:

SIGAMNT: Atualizações/Controle de Oficina/Retorno de OS/Retorno 

Programa Fonte:

MNTA400.prx

Função:

MNTA400H()

Retorno:


.T.


 

Exemplo do Ponto de Entrada MNTA400H()
#INCLUDE "FWBROWSE.CH"

User Function MNTA400H()	

	SetVisual() 	
	oBrowse := FwMBrowse():New()	
	oBrowse:SetAlias( "STJ" )	
	oBrowse:SetDescription(cCADASTRO)	
	
	If lNovoBrw		
		oBrowse:setfilterdefault("TJ_FILIAL = '"+ xFilial("STJ")+"'"+" .And. TJ_LUBRIFI <> 'S' .And. TJ_TERMINO = 'N' ;
									.And. TJ_SITUACA = 'L' .And. TJ_ORDEPAI = '" + ;
									Space(Len(STJ->TJ_ORDEPAI)) + "'")	
	EndIf	
	
	oBrowse:AddLegend( "NGSEMAFARO('!Empty(STJ->TJ_TIPORET) .And. STJ->TJ_DTMPFIM >= dDataBase')", ;
						'BR_VERDE',	OemToAnsi( "Com Insumo" ) )	
	oBrowse:AddLegend( "NGSEMAFARO('Empty(STJ->TJ_TIPORET) .And. STJ->TJ_DTMPFIM >= dDataBase' )", 'BR_VERMELHO', ;
						OemToAnsi( "Sem Insumo" ) )	
	oBrowse:AddLegend( "NGSEMAFARO('Empty(STJ->TJ_TIPORET) .And. STJ->TJ_DTMPFIM < dDataBase'  )", 'BR_AMARELO', ;
						OemToAnsi( "Atrasada Sem Insumo" ) )	
	oBrowse:AddLegend( "NGSEMAFARO('!Empty(STJ->TJ_TIPORET) .And. STJ->TJ_DTMPFIM < dDataBase' )", 'BR_AZUL', ;
						OemToAnsi( "Atrasada Com Insumo" ) )		
						
	ADD STATUSCOLUMN oColumn DATA { || If(AllTrim(TJ_PRIORID) $ "1",'BR_VERMELHO', If(AllTrim(TJ_PRIORID) $ ;
	"2",'BR_AMARELO','BR_VERDE') ) } DOUBLECLICK { |oBrowse| U_CBT400LEG() } OF oBrowse		
	
	oBrowse:Activate()
	
Return .T.
	
/*/{Protheus.doc} CBT400LEG 
Definição das cores da legenda                              
@type function

@author Rafael Reinert         
@since 31/01/2012 
@return .T.                                                  
/*/
	
User Function CBT400LEG()
	
	Local aLegenda := {}
	
	aAdd(aLegenda,{"BR_VERMELHO","Alta"})
	aAdd(aLegenda,{"BR_AMARELO","Média"})
	aAdd(aLegenda,{"BR_VERDE","Baixa"})
	BrwLegenda(cCadastro,"Legenda - Prioridade",aLegenda)
	
Return .T.