DT PE EECDU400 Declaração Unica de Exportação (DUE )

CONTEÚDO

Visão Geral
Exemplo de utilização
Parâmetros
Variáveis
Tabelas utilizadas

01. VISÃO GERAL

Este Ponto de Entrada pertence à rotina de Declaração Única de Exportação (DUE) (EECDU400). Ele deve ser utilizado para customizar a rotina de DUE.

Programa Fonte: EECDU400.PRW

Retorno: Verdadeiro (.T.) ou Falso (.F.).

02. EXEMPLO DE UTILIZAÇÃO

User Function EECDU400()
Local cParam:= ""

Local cMemo

IF Type("ParamIXB") == "C"
cParam:= PARAMIXB
ELSE
cParam:= PARAMIXB[1]
ENDIF

IF cParam == "GERAARQINI"
Msginfo("Entrou no ponto de entrada 'GERAARQINI'")
ENDIF

Do Case

Case cParam == "INICIO"

MsgInfo("Entrou no ponto de entrada EECDU400 com o parâmetro 'INICIO'")

Case cParam == "FIM"

MsgInfo("Entrou no ponto de entrada EECDU400 com o parâmetro 'FIM'")

Case cParam == "APURA_VALORES_ITEM"

MsgInfo("Entrou no ponto de entrada EECDU400 com o parâmetro 'APURA_VALORES_ITEM' (a tabela EE9 está posicionada no item em questão)")

/* Exemplo de alteração do peso bruto total do item do embarque
nPesoKG:= 200.20 */

/* Exemplo de alteração da quantidade na unidade de medida estatística do item do embarque
nQtdNCM:= 500 */

Case cParam == "DESC_PRODUTO"

//permite informar outra descrição para o produto (cadastro) na geração da DU-e

cDescPrd:= "ABCDEF"

Case cParam == "DESC_ITEM"

//permite informar outra descrição para o produto (do embarque) na geração da DU-e

cDescItem:= "ABCDEF"

Case cParam == "CANCELAR_DUE"
cMemo := MSMM(EEC->EEC_INFGER,200,,,3)
cMemo += CHR(13) + CHR(10) + "DUE Cancelada em: " + DToC(Date())
cMemo += CHR(13) + CHR(10) + "Nro DUE : " + cNroDUE
cMemo += CHR(13) + CHR(10) + "Nro RUC : " + cNroRUC
cMemo += CHR(13) + CHR(10) + "Dt DUE : " + DToC(dDtDUE)
cMemo += CHR(13) + CHR(10) + "Chave DUE : " + cChvDUE
MSMM(,200,,cMemo,1,,,"EEC","EEC_INFGER")

EndCase

Return Nil

//Quando o ponto de entrada retornar dados no array aNFs, será gerada a tag <ReferencedInvoiceLine> no XML da DUE. Se retornar aNFs vazio, a tag nao é geradano XML.

User Function DU400NFREM()

Local cNFOri, cSerOri, cImport, cImpLoja, cFatSeq
Local aNFs := {}

cNFOri := ParamIXB[1]
cSerOri := ParamIXB[2]
cImport := ParamIXB[3]
cImpLoja := ParamIXB[4]
cFatSeq := ParamIXB[5]

aAdd(aNfs, {"0001", "01", 2.0})

// aNfs[1] - Caracter - Codigo chave NFE

// aNfs[2] - Caracter - Sequencial do item

// aNfs[3] - Numérico - Quantidade do item

Return aNFs

03. PARÂMETROS

Nome	Tipo	Descrição
GERAARQINI	Caracter	Parâmetro para identificar o momento da chamada do ponto de entrada.
INICIO	Caracter	Ponto de entrada no inicio da rotina, antes de iniciar as validações.
FIM	Caracter	Ponto de entrada no fim da rotina, antes de finalizar o processo.
APURA_VALORES_ITEM	Caracter	Indica que o ponto de entrada foi executado na apuração das informações dos itens (no looping dos itens). Estarão disponíveis as variáveis: nPesoKG, nQtdNCM, nQtdEmb, nVlrTot, nVlrPri e nVlsCob
DESC_PRODUTO	Caracter	Indica que o ponto de entrada foi executado no preenchimento da descrição do item do processo a partir do cadastro do produto, possibilitando a manipulação da informação que será considerada na geração dos dados para a integração. Neste momento estará disponível a variável cDescPrd.
DESC_ITEM	Caracter	Indica que o ponto de entrada foi executado no preenchimento da descrição do item do processo a partir da descrição que está no embarque, possibilitando a manipulação da informação que será considerada na geração dos dados para a integração. Neste momento estará disponível a variável cDescItem.
CANCELAR_DUE	Caracter	Ponto de Entrada executado ao final do processamento do botão "Cancelar DUE" no Embarque de Exportação. Executado durante a gravação dos campos da tabela EEC, limpando os dados da DUE.

04. VARIÁVEIS

Parâmetro	Nome	Tipo	Permite alterar	Descrição
GERAARQINI	cIni	Caracter	Sim	Variável com dados gravados no arquivo .INI a ser transmitido para o Siscomex.
GERAARQINI	cTimeOutIni	Caracter	Sim	Variável com o valor limite para o timeout.
APURA_VALORES_ITEM	nPesoKG	Numérico	Sim	Peso líquito total do item, em kg
APURA_VALORES_ITEM	nQtdNCM	Numérico	Sim	Quantidade do item na unidade estatística
APURA_VALORES_ITEM	nQtdEmb	Numérico	Sim	Quantidade do item na unidade negociada
APURA_VALORES_ITEM	nVlrTot	Numérico	Sim	Preço total do item
APURA_VALORES_ITEM	nVlrPri	Numérico	Sim	Preço fob do item
APURA_VALORES_ITEM	nVlsCob	Numérico	Sim	Valor sem cobertura cambial do item
DESC_PRODUTO	cDescPrd	Caracter	Sim	Possibilita a redefinição da descrição do produto que será considerada na geração dos dados para a integração da DU-e.
DESC_ITEM	cDescItem	Caracter	Sim	Possibilita a redefinição da descrição do item do processo de embarque que será considerada na geração dos dados para a integração da DU-e.
	cNFOri	Caracter	Não	Nota fiscal de origem
	cImport	Caracter	Não	Importador
	cImpLoj	Caracter	Não	Loja do Importador
	cFatSeq	Caracter	Não	Numero de sequencia do item faturado
CANCELAR_DUE	cNroDUE	Caracter	Não	Número da DUE que será apagado após efetivar o cancelamenrto da DUE.
CANCELAR_DUE	cNroRUC	Caracter	Não	Número RUC que será apagado após efetivar o cancelamenrto da DUE.
CANCELAR_DUE	dDtDUE	Data	Não	Data da DUE que será apagado após efetivar o cancelamenrto da DUE.
CANCELAR_DUE	cChvDUE	Caracter	Não	Chave da DUE que será apagado após efetivar o cancelamenrto da DUE.

05. TABELAS UTILIZADAS

Não há.

Árvore de páginas