Linha Microsiga Protheus

Árvore de páginas

Novo padrão para chamadas dos pontos de entrada MNTA7652 e MNTA7661

Características do Requisito

Linha de Produto:

Microsiga Protheus

Segmento:

Manufatura

Módulo:

SIGAMNT - Manutenção de Ativos e Gestão de Frotas. 

Rotina:

Rotina

Nome Técnico

MNTA765

Multas

MNTA845Inconsistências

Cadastros Iniciais:

MNTA084 - Veículos. 

País(es):

Todos

Banco(s) de Dados:

Todos

Tabelas Utilizadas:

ST9 - Bens 

Sistema(s) Operacional(is):

Windows e Linux

Ponto de Entrada:

MNTA7652 - Validação na confirmação da Multa.

MNTA7661 - Possibilita alteração de campos apos inclusão de uma notificação.

Descrição

Realizado conversão das rotinas MNTA765 - Multas e MNTA845 - Inconsistências para o modelo padrão de desenvolvimento MVC, por este motivo a chamada e utilização de pontos de entrada MNTA7652 e MNTA7661 precisam ser alteradas para continuarem sendo executados corretamente. 

Verifique no exemplo abaixo e realize as atualizações. 

Procedimento para Utilização

  1.  Entrar no modulo de Manutenção de Ativos e Gestão de Frotas(SIGAMNT).
  2. Em Atualizações > Gestão de Riscos > Multas > Multas.
  3. Em Atualizações > Gestão de Riscos > Multas > Inconsistências. 


Ponto de Entrada

Descrição:

Ponto de entrada no padrão MVC. 

Localização:

Em Atualizações > Gestão de Riscos > Multas > Multas.

Em Atualizações > Gestão de Riscos > Multas > Inconsistências. 

Eventos:

Multas (MNTA765).

Inconsistências (MNTA845).

Programa Fonte:

MNTA765.prx

MNTA845.prx

Função:

MNTA765()

MNTA845()

Retorno:

Nome

Tipo

Descrição

Obrigatório

 xRet

Indefinido

Determina o retorno o parâmetro

Sim. 

 

Exemplo Ponto de Entrada Padrão MVC
#INCLUDE "PROTHEUS.CH"
#INCLUDE "FWMVCDEF.CH"


User Function MNTA765()

	Local aArea      := GetArea()
	Local aParam     := PARAMIXB
	Local xRet       := .T.
	Local oObj       := ''
	Local cIdPonto   := ''
	Local cIdModel   := ''
	Local nOperacao  := 0

	If aParam <> NIL

    	oObj       := aParam[1] //Modelo de dados.
    	cIdPonto   := aParam[2] //Identificador do ponto de chamada.
    	cIdModel   := aParam[3] //Idificador do Modelo de dados.

		// Substituição do ponto de entrada MNTA7652.
    	If cIdPonto == 'MODELPOS' //Chamada após a Confirmação da rotina.

    	    nOperacao := oObj:GetOperation() //Busca a opção selecionada (3=Inclusão, 4= Alteração ou 5=Exclusão)

    	    If nOperacao == 3 //OPÇÃO DE INCLUSÃO.
        	
				dbSelectArea("TRX")
        		dbSetOrder(1)
       			If !Empty( dbSeek( xFilial("TRX") + oObj:GetValue('MULTAS','TRX_MULTA') ) )
            		If AllTrim(oObj:GetValue('MULTAS','TRX_TPMULTA')) $ "TRANSITO/PRODUTO PERIGOSO"
                		MsgInfo("Já existe uma multa cadastrada com esse número! ", "Atenção")
                		xRet := .F.
            		EndIf
        		EndIf

       		EndIf
		
		// Substituição do ponto de entrada MNTA7661
		ElseIf cIdPonto == 'MODELCOMMITNTTS' //  Chamado após a gravação da tabela.

			If IsInCallStack("MNTA766")

				nOperacao := oObj:GetOperation() //Busca a opção selecionada (3=Inclusão, 4= Alteração ou 5=Exclusão)

 				If nOperacao == 3 //OPÇÃO DE INCLUSÃO.
        	
					dbSelectArea("TRX")
        			RecLock("TRX", .F.)
       				TRX->TRX_CIDINF := "JOINVILLE"
        			TRX->( MsUnlock() )
    		
				EndIf

			EndIf
    	
		EndIf

	EndIf

	RestArea(aArea)

Return xRet