Linha Microsiga Protheus

Árvore de páginas

Ponto de entrada FT600TOK

Características do Requisito

Linha de Produto:

Microsiga Protheus®

Segmento:

Serviços

Módulo:

CRM - SIGACRM
Faturamento - SIGAFAT

Rotina:

Rotina

Nome Técnico

Proposta comercial

FATV600

Proposta comercialFATV600A

Tickets relacionados

790786

Requisito/Story/Issue:

DSERFAT-2025

País(es):

Todos os países.

Banco(s) de Dados:

Todos os bancos de dados homologados.

Sistema(s) Operacional(is):

Todos os sistemas operacionais homologados.

Versão:A partir da versão 12.1.17.

Descrição

Permite realizar validações extras antes da gravação da Proposta Comercial.

Importante

Este ponto de entrada estará disponível somente se os programas fonte FATV600.PRW e FATV600A.PRW possuírem data posterior à 06 de novembro de 2017 (versão 12.1.17) em seu repositório (arquivo ".RPO" do seu ambiente). Portanto, caso deseje utilizar este ponto de entrada, certifique-se desta premissa.

Ponto de Entrada

Descrição:

A finalidade do ponto de entrada FT600TOK é possibilitar validações específicas antes da gravação da Proposta Comercial.

Localização:

SIGACRM → Atualizações → Vendas → Vendas → Oportunidades → Ações Relacionadas → Proposta Comercial
SIGAFAT → Atualizações → CRM-Administração de vendas → Oportunidades → Ações Relacionadas → Proposta Comercial

Programa Fonte:

FATV600.PRW / FATV600A.PRW

Parâmetros:

<oModel>

Onde:

NomeTipoDescriçãoObrigatório
<oModel>ObjetoModelo ativoSim

Retorno:

NomeTipoDescriçãoObrigatório
lRet
Lógico

Indica se a validação específica foi bem sucedida ou não.

Onde:

RetornoExecução
.T.Validação bem sucedida.
.F.Validação não foi bem sucedida.
Sim

Exemplo:

#Include 'Protheus.ch'
#Include "FwMVCDef.ch"
*==========================
User Function FT600TOK()
*==========================
Local oModel := ParamIXB
Local cFolder := ""
Local cAba := ""
Local nAba := 0
Local nX := 0
Local lRet := .T.

For nAba := 1 to 2
      If nAba == 1
            cFolder := "ADZPRODUTO" // Valida a pasta produtos.
            cAba := "Produtos"
      Else
            cFolder := "ADZACESSOR" // Valida a pasta acessórios.
            cAba := "Acessórios"
      EndIf
      If !( oModel:GetModel(cFolder):IsEmpty() )
            For nX := 1 To oModel:GetModel(cFolder):Length()
                  oModel:GetModel(cFolder):GoLine(nX)
                  If (oModel:GetModel(cFolder):IsUpdated() .Or. oModel:GetModel(cFolder):IsInserted()) .AND. !Empty(oModel:GetModel(cFolder):GetValue("ADZ_PRODUT"))
                        If oModel:GetModel(cFolder):GetValue("ADZ_PRCVEN") < oModel:GetModel(cFolder):GetValue("ADZ_XLMINF")
                              Help( "", 1, "U_FT600TOK", ,"O preço de venda não pode ser inferior ao valor limite inferior de venda. Aba: " + cAba + " Item: " + AllTrim(Str(nX)),2,,,,,,,{"Informe um preço de venda válido para o item."} )
                              lRet := .F.
                              EXIT
                        EndIf
                  EndIf
            Next nX
            If ! lRet
                  EXIT
            EndIf
      EndIf
Next nAba

Return lRet

Imagem da aplicação do ponto de entrada

Não disponível.