TQueueSvc:DelMsg

#include 'protheus.ch'

// Setup Redis
Static cRedisHost := "tec-clima"
Static nRedisPort := 6379

User Function FilDel()
  Local nRet       := 0
  // ID da mensagem
  Local cMsgId1    := ""
  // Mensagem a receber
  Local cMsg       := ""
  // Nome da Fila
  Local cQueueName := "Fila_TQLS"
  // Objeto de Fila
  Local oTQLS := Nil
  Local nNO_MSGS := 0
  // Cria um novo objeto de Fila
  oTQLS := TQueueSvc():New(cQueueName)
  If(oTQLS == Nil)
    ConOut("### ERRO ### " + "Erro na criacao da Fila - " + cQueueName)
    Return .F.
  Else
    ConOut("Criacao da Fila  OK - " + oTQLS:cName)
  EndIf
  // Configurando a Fila
  nRet := oTQLS:Setup(cRedisHost, nRedisPort)
  If nRet != 0
    ConOut("### ERRO ### " + "Erro ao fazer o Setup" + " Erro: " + AllTrim(Str(nRet)))
    Return .F.
  Else
    ConOut("Setup de Fila    OK - " + oTQLS:cName + " nMsgRetPer: " + AllTrim(Str(oTQLS:nMsgRetPer)) + " nVisTimeOut: " + AllTrim(Str(oTQLS:nVisTimeOut)))
  EndIf
  // Obtendo valor de indicacao de que nao tem mais mensagens
  nNO_MSGS := oTQLS:eNO_MSGS
  // Obtem a mensagem
  nRet := oTQLS:WaitMsg( @cMsgId1, @cMsg, , 3 )
  If nRet != 0
    If(nRet == nNO_MSGS)
      ConOut("Nao existem mensagens na Fila. (Execute U_FilPut)")
    Else
      ConOut("### ERRO ### " + "Erro ao receber mensagem" + " Erro: " + AllTrim(Str(nRet)))
    EndIf
    Return .F.
  Else
    ConOut("Recebeu msg Fila OK - " + oTQLS:cName + " com ID: " + cMsgId1 + " Tamanho: " + AllTrim(Str(Len(cMsg))))
  EndIf
  // Removendo a mensagem
  nRet := oTQLS:DelMsg( cMsgId1 )
  If nRet != 0
    ConOut("### ERRO ### " + "Erro ao remover mensagem" + " Erro: " + AllTrim(Str(nRet)))
    Return .F.
  Else
    ConOut("Removeu msg Fila OK - " + oTQLS:cName + " com ID: " + cMsgId1)
  EndIf
Return .T.