TOTVSTEC

Árvore de páginas

Tempo aproximado para leitura: 2 minutos

Retorna se a tabela está em modo de inserção de registros ou não.

Sintaxe

DBInInsert()

Retorno

Nome

Tipo

Descrição

lRet

lógico

Retorna .T. se estiver inserindo registros; caso contrário, .F..

Observações

  • Caso não haja tabela aberta, a função retornará .F..

Exemplos

O exemplo abaixo utiliza a RDD "TOPCONN", mas a função pode ser utilizada com qualquer uma das RDDs válidas.

user function test1()
  Local nHandle1 := TCLink( "MSSQL/DSN1", "127.0.0.1", 7890 )
  Local cTable1 := "MYTABLE1"
  Local cRDD := "TOPCONN"
  
  // Cria a tabela
  DBCreate( cTable1, { { "CPOC", "C", 10, 0 }, ;
                       { "CPON", "N",  3, 0 }, }, cRDD )
  
  conout( DBInInsert() ) // Exibe: .F.
  
  // Abre a tabela 1 em modo exclusivo criando uma área de trabalho
  DBUseArea( .T., cRDD, cTable1, (cTable1), .F., .F. )
  
  conout( DBInInsert() ) // Exibe: .F.
  
  DBAppend( .F. )
  
  conout( DBInInsert() ) // Exibe: .T.
  
  (cTable1)->CPOC := "ABC"
  (cTable1)->CPON := 99
  
  DBCommit()
  
  conout( DBInInsert() ) // Exibe: .F.
  
  // Fecha a área de trabalho
  DBCloseArea()
  
  // Abre a tabela 1 em modo exclusivo criando uma área de trabalho
  DBUseArea( .T., cRDD, cTable1, (cTable1), .F., .F. )
  
  conout( DBInInsert() ) // Exibe: .F.
  
  (cTable1)->CPOC := "DEF"
  (cTable1)->CPON := 88
  
  conout( DBInInsert() ) // Exibe: .F.
  
  // Fecha a área de trabalho
  DBCloseArea()
  
  // Apaga a tabela
  TCDelFile( cTable1 )
  
  // Desconecta
  TCUnlink( nHandle1 )
return

Veja também

  • Sem rótulos