TOTVSTEC

Árvore de páginas

Sintaxe Mínima

@ <nRow>,<nCol> MSPANEL <oPanel>

Sintaxe Completa

@ <nRow>, <nCol> MSPANEL <oPanel> 
   [ PROMPT | VAR <cPrompt> ] 
   [ OF | WINDOW | DIALOG <oWnd> ]
   [ FONT <oFont> ]
   [ CENTERED | CENTER ]
   [ COLOR <nClrText> ]
   [ SIZE <nWidth,nHeight> ]
   [ LOWERED ]
   [ RAISED ]

Include

#include "totvs.ch"

Parâmetros

CláusulaTipoObrigatóriaDescrição
<nRow>NSParâmetro obrigatório, indica a linha da tela (em pixels ou coordenadas) onde o componente será exibido. Deve ser usada uma expressão numérica, constante ou variável.
<nCol>NSParâmetro obrigatório, indica a coluna da tela (em pixels ou coordenadas) onde o componente será exibido. Deve ser usada uma expressão numérica, constante ou variável.
MSPANEL <oPanel>OSCláusula obrigatória, indica o uso do componente de agrupamento tPanel(). Deve ser sucedido da variável AdvPL a receber o objeto do componente.
PROMPT | VAR <cText>CNPermite especificar uma expressão caractere, constante ou variável, que será usada como título do painel.
OF | WINDOW | DIALOG  <oWnd>ONCláusula opcional, quando informada permite especificar o nome de uma variável AdvPL que contenha o objeto ou componente pai de interface (janela ou diálogo, painel) onde o componente deve ser exibido. Caso seja omitida, o componente será criado na janela ou diálogo ativos no momento. Embora todas as cláusulas sejam suportadas (OF, DIALOG ou WINDOW), por questões de padronização de código, recomendamos o uso da cláusula OF – pois um componente de interface não necessariamente têm seu componente pai definido como uma caixa de diálogo, qualquer outro componente de agrupamento ou container pode ser utilizado – como um tPanel, tFolder, etc.
FONT <oFont>ONPermite especificar uma fonte diferenciada, que será a fonte padrão dos componentes dentro do painel.
CENTERED | CENTER
NIndica que, quando especificado um título do painel através da opção PROMPT ou VAR, este título deve ser exibido centralizado no componente. Por padrão o título é exibido no canto superior esquerdo da área interna do painel.
COLOR | COLORS  <nClrText> ,[,<nClrBack>] NNCláusula opcional, permite alterar a cor do texto da mensagem a ser exibida pelo componente. Deve ser usada uma expressão numérica, constante ou variável. Opcionalmente também especificar a cor de fundo do painel.
SIZE <nWidth>,<nHeight>NNParâmetros opcionais, indicam respectivamente o tamanho horizontal e vertical a ser usado pelo componente. Caso não especificados no construtor, devem ser informados posteriormente para a visualização correta do componente.
LOWERED* 
NIndica que o painel será desenhado com uma borda do lado direito e borda inferior
RAISED
NIndica que o painel será desenhado com uma borda do lado esquerdo e borda superior
  • O componente MSPANEL (tPanel) é um componente de agrupamento ou "container" de componentes. Logo, podemos utilizá-lo como o componente superior ao usarmos outros componentes de interface, como SAY, GET, BUTTON, etc.
  • Este componente pode ser alinhado dinamicamente usando a área do seu componente superior, usando a propriedade ALIGN da classe hierarquicamente superior TCONTROL.. Para maiores detalhes, consulte a propriedade tControl:Align

Classe usada pelo comando

O comando @ .. MSPANEL é traduzido em tempo de compilação para utilizar a classe de interface visual do AdvPL TPANEL() e seu método construtor NEW().

Referências

Construtor TPanel:New

Exemplo


Exemplo do comando @ ... MSPANEL
#include 'totvs.ch'

User function tPanel1()
Local oDlg     
Local oPanel1,oPanel2,oPanel3,oPanel4
	
DEFINE DIALOG oDlg TITLE "Exemplo de TABS" FROM 0,0 TO 300,400 PIXEL

@ 10,15 MSPANEL oPanel1 COLORS CLR_BLACK,CLR_HGRAY SIZE 100, 20 OF oDlg 
@ 7,10 SAY "Texto Exemplo 1" OF oPanel1 PIXEL
       
@ 40,15 MSPANEL oPanel2 COLORS CLR_BLACK,CLR_HGRAY SIZE 100, 20 OF oDlg RAISED
@ 7,10 SAY "Texto Exemplo 2" OF oPanel2 PIXEL

@ 70,15 MSPANEL oPanel3 COLORS CLR_BLACK,CLR_HGRAY SIZE 100, 20 OF oDlg LOWERED
@ 7,10 SAY "Texto Exemplo 3" OF oPanel3 PIXEL

@ 100,15 MSPANEL oPanel4 COLORS CLR_BLACK,CLR_HGRAY PROMPT "Painel 4" SIZE 100, 20 OF oDlg 

ACTIVATE DIALOG oDlg CENTER 

Return

Resultado


  • Sem rótulos