FWMVCRotAuto

Descrição
Realiza a conversão do formato anterior de rotina automática para o formato novo, garantindo os programas legados.

Sintaxe
FWMVCRotAuto( oModel , cAlias , nOpcAuto , aAuto , lSeek , lPosaRot ) -> lRetorno

Parâmetros

Nome	Tipo	Descrição	Obrigatório
oModel	Objeto	Objeto com o modelo do formulário de dados	X
cAlias	Caracter	Alias do Browse principal
nOpcAuto	Numérico	Código de identificação do tipo de processamento da rotina automática [3] Inclusão / [4] Alteração / [5] Exclusão
aAuto	Array	Array com os dados da rotina automática na seguinte estrutura [n][1] Código do formulário do Modelo que terá uma atribuição [n][2] Array padrão dos dados da EnchAuto e GetDAuto, conforme documentação anterior	X
lSeek	Lógico	Indica se o arquivo principal deve ser posicionado com base nos dados fornecidos.
lPosaRot	Lógico	Indica se o nOpc não deve ser calculado com base no aRotina

Retorno

Nome	Tipo	Descrição
lRetorno	Lógico	Valor lógico que indica se o processamento foi realizado com sucesso

Exemplo

User Function MyOMSA010()


Local aCabec := {}
Local aItens := {}
Local aLinha := {}
Local nY := 0
Local lOk := .T.
PRIVATE lMsErroAuto := .F.

//ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
//| Abertura do ambiente |
//ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

ConOut(Repl("-",80))

ConOut(PadC("Teste de Inclusao de 1 tabela de preco",80))

PREPARE ENVIRONMENT EMPRESA "99" FILIAL "01" MODULO "FAT"

//ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
//| Verificacao do ambiente para teste |
//ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

dbSelectArea("SB1")
dbSetOrder(1)
If !SB1->(MsSeek(xFilial("SB1")+"PA001"))
    lOk := .F.
    ConOut("Cadastrar produto: PA001")
EndIf

If !SB1->(MsSeek(xFilial("SB1")+"PA002"))
    lOk := .F.
    ConOut("Cadastrar produto: PA002")
EndIf

If lOk
    ConOut("Inicio: "+Time())
    For nY := 1 To 1
        aCabec := {}
        aItens := {}
        aadd(aCabec,{"DA0_DESCRI" ,"TESTE DE TABELA",Nil})
        //aadd(aCabec,{"DA0_CONDPG" ,"001",Nil})
        aLinha := {}
        aadd(aLinha,{"DA1_ITEM","0001"})
        aadd(aLinha,{"DA1_CODPRO","PA001"})
        aadd(aLinha,{"DA1_PRCVEN",10,Nil})          
        aadd(aItens,aLinha)
        aLinha := {}
        aadd(aLinha,{"DA1_ITEM","0002"})
        aadd(aLinha,{"DA1_CODPRO","PA002"})
        aadd(aLinha,{"DA1_PRCVEN",10,Nil})          
        aadd(aItens,aLinha)

        //ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        //| Teste de Inclusao |
        //ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

        aRotina := MenuDef()

        FWMVCRotAuto(ModelDef(),"DA0",3,{{"OMSA010_DA0",aCabec},{"OMSA010_DA1",aItens}})

        If !lMsErroAuto
            ConOut("Incluido com sucesso! ")
        Else
            ConOut("Erro na inclusao!")
        EndIf
    Next nY
    ConOut("Fim : "+Time())

    //ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
    //| Teste de alteracao |
    //ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

    aCabec := {}
    aItens := {}
    For nY := 1 To 1
        aCabec := {}
        aItens := {}
        aadd(aCabec,{"DA0_CODTAB" ,DA0->DA0_CODTAB,Nil})
        aadd(aCabec,{"DA0_DESCRI" ,"TESTE DE TABELA",Nil})
        //aadd(aCabec,{"DA0_CONDPG" ,"001",Nil})
        aLinha := {}
        aadd(aLinha,{"LINPOS","DA1_ITEM","0001"})
        aadd(aLinha,{"AUTDELETA","N",Nil})
        aadd(aLinha,{"DA1_CODPRO","PA001"})
        aadd(aLinha,{"DA1_PRCVEN",11,Nil})          
        aadd(aItens,aLinha)
        aLinha := {}
        aadd(aLinha,{"LINPOS","DA1_ITEM","0002"})
        aadd(aLinha,{"AUTDELETA","N",Nil})              
        aadd(aLinha,{"DA1_CODPRO","PA002"})
        aadd(aLinha,{"DA1_PRCVEN",11,Nil})          
        aadd(aItens,aLinha)
    Next nY
    ConOut(PadC("Teste de alteracao",80))
    ConOut("Inicio: "+Time())

    //ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
    //| Teste de alteracao |
    //ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

    aRotina := MenuDef()
    FWMVCRotAuto(ModelDef(),"DA0",4,{{"OMSA010_DA0",aCabec},{"OMSA010_DA1",aItens}})
    ConOut("Fim : "+Time())
    ConOut(Repl("-",80))

    //ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
    //| Teste de Exclusao |
    //ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

    ConOut(PadC("Teste de exclusao",80))
    ConOut("Inicio: "+Time())
    aRotina := MenuDef()
    FWMVCRotAuto(ModelDef(),"DA0",5,{{"OMSA010_DA0",aCabec},{"OMSA010_DA1",aItens}})

    If !lMsErroAuto
        ConOut("Exclusao com sucesso! "+DA0->DA0_CODTAB)
    Else
        ConOut("Erro na exclusao!")
    EndIf

    ConOut("Fim : "+Time())
    ConOut(Repl("-",80))    
EndIf

RESET ENVIRONMENT

Return(.T.)

Atalhos

Páginas filhas