FWCalcStruct

FWCalcStruct(<oModelCalc >)-> oStruct

Esta função fornece o objeto de estrutura de dados do tipo calculo pra ser usado na view.
As estruturas são fornecidadas com base nos calcs do Modelo, adicionados atráves do método AddCalc.

 

oStruct Estrutura de dados para o objeto.

Static Function ModelDef()
Local oStruZA1 := FWFormStruct( 1, 'ZA1')
Local oStruZA2 := FWFormStruct( 1, 'ZA2')
Local oModel

oModel := MPFormModel():New( 'COMP022M')

oModel:AddFields( 'ZA1MASTER', NIL, oStruZA1 )
oModel:AddGrid( 'ZA2DETAIL', 'ZA1MASTER', oStruZA2)

oModel:AddCalc( 'COMP022CALC1', 'ZA1MASTER', 'ZA2DETAIL', 'ZA2_AUTOR', 'ZA2__TOT01', 'COUNT', { | oFW | COMP022CAL( oFW, .T. ) },,'Total Pares' )
oModel:AddCalc( 'COMP022CALC1', 'ZA1MASTER', 'ZA2DETAIL', 'ZA2_AUTOR', 'ZA2__TOT02', 'COUNT', { | oFW | COMP022CAL( oFW, .F. ) },,'Total Impares' )

oModel:SetRelation( 'ZA2DETAIL', { { 'ZA2_FILIAL', 'xFilial( "ZA2" ) ' } , { 'ZA2_MUSICA', 'ZA1_MUSICA' } } , ZA2->( IndexKey( 1 ) ) )

Return oModel

Static Function ViewDef()
Local oModel := ModelDef()
Local oView
Local oStr1:= FWFormStruct(2, 'ZA1')
Local oStr2:= FWFormStruct(2, 'ZA2')
Local oStr3:= FWCalcStruct( oModel:GetModel('COMP022CALC1') )

oView := FWFormView():New()
oView:SetModel( oModel )

oView:AddField('ZA1MASTER' , oStr1)
oView:AddGrid('ZA2DETAIL' , oStr2)
oView:AddField('CALC', oStr3,'COMP022CALC1')

oView:CreateHorizontalBox( 'BOX6', 50)
oView:CreateFolder( 'FOLDER7', 'BOX6')

oView:AddSheet('FOLDER7','SHEET9','SHEET9')
oView:CreateHorizontalBox( 'BOXFORM2', 100, , 'FOLDER7', 'SHEET9')

oView:AddSheet('FOLDER7','SHEET8','SHEET8')
oView:CreateHorizontalBox( 'BOXFORM4', 100, , 'FOLDER7', 'SHEET8')
oView:CreateHorizontalBox( 'BOXFORM8', 50)

oView:SetOwnerView('ZA1MASTER','BOXFORM2')
oView:SetOwnerView('ZA2DETAIL','BOXFORM4')
oView:SetOwnerView('CALC','BOXFORM8')

Return oView