Linha Microsiga Protheus

Árvore de páginas


01. DADOS GERAIS

Produto:

TOTVS Backoffice

Linha de Produto:

Linha Protheus

Segmento:

Backoffice

Módulo:

TOTVS Backoffice (Linha Protheus) - Automação e Coleta de Dados (SIGAACD)

Função:ACDV152
País:Brasil
Ticket:
Issue:DMANMAT01-41864


02. DESCRIÇÃO

O ponto de entrada possui dois comportamentos distintos:

  • Caso utilize etiqueta CB0 tipo 01, permite customizar a validação na etiqueta CB0 informada.
  • Caso não utilize etiqueta CB0, permite customizar a validação do produto informado.

03. PARÂMETROS

NomeDescrição

cEtiqueta OU

cProduto

Dependendo da configuração do ambiente, retorna o código da etiqueta CB0 ou o código do produto (B1_COD).

04. RETORNO


NomeDescriçãoConteúdo
lRetRetorno lógico da validaçãoLógico - .T. para validação OK ou .F. para inconsistência.

05. EXEMPLO DE UTILIZAÇÃO

Exemplo AV152VPR com CB0
#INCLUDE "TOTVS.CH"  

/*/{Protheus.doc} AV152VPR
Válida a etiqueta de produto informado no envio para processo
@type       user function
@author    TOTVS 
/*/
User Function AV152VPR()
    Local aAreas   := {CB0->(GetArea()), SB1->(GetArea()), GetArea()}
    Local cCodEti  := ParamIXB
    Local lRet     := .T.

    //Válidação customizada
    CB0->(DbSetOrder(1)) //CB0_FILIAL+CB0_CODETI
    If CB0->(DbSeek(FWXFilial('CB0')+AllTrim(cCodEti)))
        SB1->(DbSetOrder(1)) //B1_FILIAL+B1_COD
        SB1->(DbSeek(FWXFilial('SB1')+CB0->CB0_CODPRO))
        If SB1->B1_TIPO $ 'EM|MO'
            lRet := .F.
            VtAlert('TIPO DO PRODUTO INVALIDO','ERRO' ,.T.,4000,3)
        EndIf
    EndIf
    
    //Restaura as áreas
    AEval(aAreas, {|x| RestArea(x)})
Return lRet


Exemplo AV152VPR sem CB0
#INCLUDE "TOTVS.CH"  

/*/{Protheus.doc} AV152VPR
Válida o código de produto informado no envio para processo
@type       user function
@author    TOTVS 
/*/
User Function AV152VPR()
    Local aAreas   := {SB1->(GetArea()), GetArea()}
    Local cCodProd := ParamIXB
    Local lRet     := .T.

    //Válidação customizada
    SB1->(DbSetOrder(1)) //B1_FILIAL+B1_COD
    SB1->(DbSeek(FWXFilial('SB1')+cCodProd))
    If SB1->B1_TIPO $ 'EM|MO'
        lRet := .F.
        VtAlert('TIPO DO PRODUTO INVALIDO','ERRO' ,.T.,4000,3)
    EndIf
    
    //Restaura as áreas
    AEval(aAreas, {|x| RestArea(x)})
Return lRet


06. ASSUNTOS RELACIONADOS