Linha Microsiga Protheus

Árvore de páginas

Ponto de entrada que retorna os dados do contador Posterior ao abastecimento realizado

Características do Requisito

Linha de Produto:

Microsiga Protheus

Segmento:

Manufatura

Módulo:

SIGAMNT - Manutenção de Ativos e Gestão de Frotas

Rotina:

Rotina

Nome Técnico

MNTUTIL_CONTADOR

Funções de Contador

Rotina(s) envolvida(s)

Nome Técnico

NGUTIL4F

Ponto de Entrada

País(es):

Todos

Banco(s) de Dados:

Todos

Sistema(s) Operacional(is):

Todos


Ponto de Entrada

Descrição:

Ponto de entrada executado no programa de Funções de Contador (MNTUTIL_CONTADOR) que retorna os dados do contador posterior ao abastecimento que está sendo feito, para que considere apenas os registros de abastecimento. Dessa forma não irá retornar os dados de contador de o próximo registro for de lançamento de contador (abertura de OS, por exemplo).

Programa Fonte:

MNTUTIL_CONTADOR.prw

Função:

NGUTILF()
Retorno:

Nome

Tipo

Descrição

Obrigação

aRetPEArrayContém os dados do abastecimento posteriorX
Exemplo do Ponto de Entrada NGUTILF()
#Include 'Protheus.ch'

User Function NGUTILF()

	Local _cGetDB := TcGetDb()
	Local cBemPE := ParamIXB[1]
	Local dDatPE := ParamIXB[2]
	Local cHorPE := ParamIXB[3]
	
	aRetPE := {}
	
	If FunName() != "MNTA655" .AND. FunName() != "MNTA656"	
		Return aRetPE
	EndIf
	
	cAliasQry := GetNextAlias()
	cQuery := " SELECT STP.TP_DTLEITU, STP.TP_HORA, STP.TP_POSCONT "
	cQuery += " FROM " + RetSqlName("STP")+" STP "
	cQuery += " WHERE STP.TP_CODBEM  = '"+cBemPE+"'"
	If Upper(_cGetDB) == "ORACLE" .Or. "DB2" $ Upper(_cGetDB)	
		cQuery += " AND STP.TP_DTLEITU || STP.TP_HORA > '"+DTOS(dDatPE)+cHorPE+"'"
	Else	
		cQuery += " AND STP.TP_DTLEITU + STP.TP_HORA > '"+DTOS(dDatPE)+cHorPE+"'"
	Endif
	cQuery += " AND   STP.TP_TIPOLAN = 'A' "
	cQuery += " AND   STP.D_E_L_E_T_ <> '*' "
	cQuery += " ORDER BY STP.TP_DTLEITU, STP.TP_HORA "
	cQuery := ChangeQuery(cQuery)
	dbUseArea( .T., "TOPCONN", TCGENQRY(,,cQuery),cAliasQry, .F., .T.)
	dbGotop()
	If !Eof()	
		AADD(aRetPE,{(cAliasQry)->TP_POSCONT,"A",STOD((cAliasQry)->TP_DTLEITU),(cAliasQry)->TP_HORA})
	Else	
		AADD(aRetPE,{0,' ',CTOD('  /  /  '),'  :  '})
	Endif(cAliasQry)->(dbCloseArea())
	
Return aRetPE