Linha Microsiga Protheus

Árvore de páginas

Novo Modelo de Ponto de entrada.

Existe um novo modelo de desenvolvimento de ponto de entrada, por favor realizar a alteração, conforme o exemplo a seguir: Clique aqui.

Ponto de entrada para validar a geração do Check List.

Características do Requisito

Linha de Produto:

Microsiga Protheus

Segmento:

Manufatura

Módulo:

SIGAMNT - Manutenção de Ativos e Gestão de Frotas

Rotina:

Rotina

Nome Técnico

MNTA735 

Retorno Check List

País(es):

Todos

Banco(s) de Dados:

Todos

Tabelas Utilizadas:

TTF - Check List

TTG - Detalhes do Check List

Sistema(s) Operacional(is):

Windows e Linux

Ponto de Entrada

Descrição:

Ponto de entrada com o objetivo de validar os valores informados na tabela TTF -Check List e TTG -Detalhes do Check List

Localização:

Atualizações > Controle de Oficina > Check List > Retorno Check List.

Eventos:

Retorno Check List (MNTA735.prw)

Programa Fonte:

MNTA735.prw

Função:

MNTA7356()

Retorno:

Nome

Tipo

Descrição

Obrigatório

 lRet

Lógico

Retorna .T. quando verificar estiver correta e .F. quando não estiver correta e ocorrerá a parada do processo.

Sim

 

Exemplo Ponto de Entrada
#Include 'Protheus.ch'


User Function MNTA7356()

    Local oModel   := PARAMIXB[1] //Retorna a Modelo que contêm os valores da TTF.
    Local oGrid    := oModel:GetModel('TTGDETAIL') // Posiciona no Model da Grid
    Local lRet     := .T.
    Local nLenGrid := oGrid:Length() // Pega tamanho total da grid.
    Local nInd     := 0
    Local cEtapa   := ""

    If Empty(oModel:GetValue('TTFMASTER','TTF_RAMAL')) //Verifica se o campo Ramal foi preenchido.
        Help(Nil, Nil, "Atenção", Nil, "O campo de Ramal não foi preenchido. Favor realizar o seu preenchimento.", 1, 0)
        lRet := .F.
    EndIf

    If lRet
        For nInd := 1 To nLenGrid

            oGrid:GoLine(nInd) // Posiciona na linha desejada.
            If !oGrid:IsDeleted() // Veririfica se o registro não está delatado

                cEtapa := AllTrim(oGrid:GetValue("TTG_ETAPA"))
                If cEtapa == "0001"
                    Help(Nil, Nil, "Atenção", Nil, "Essa etapa não pode ser utilizada", 1, 0)
                    lRet := .F.
                EndIf

            EndIf
        Next nInd
    EndIf

Return lRet