PONTO DE ENTRADA CADASTRO DE VEÍCULOS (MNTA084)

Características do Requisito

Linha de Produto:

Microsiga Protheus

Segmento:

Manufatura

Módulo:

SIGAMNT - Manutenção de Ativos e Gestão de Frotas

Rotina:

Rotina	Nome Técnico
MNTA084	Cadastro de Veiculos

Rotina(s) envolvida(s)	Nome Técnico
MNTA084	Ponto de Entrada

País(es):

Todos

Banco(s) de Dados:

Todos

Sistema(s) Operacional(is):

Todos

Ponto de Entrada

Descrição:

Ponto de Entrada padrões.

Localização:

SIGAMNT: Atualizações/Controle de Oficina/Bens/Veículos.

Programa Fonte:

MNTA084.prw

Função:

MNTA084()

Variáveis:

Nome	Tipo	Pode Alterar	Descrição
oObj	Objeto	Não	Recebe o objeto modelo, que contêm todos os valores informados.
cIdPonto	Caracter	Não	Identificador do ponto de chamada.
cIdModel	Caracter	Não	Identificado do modelo.

Retorno:

Nome	Tipo	Descrição	Obrigatório
xRet	Lógico	Retorna o conteúdo da verificação.	Sim

Exemplo 1

#Include "Protheus.ch"
#Include "Fwmvcdef.CH"

//---------------------------------------------------------------------
/*/{Protheus.doc} MNTA084
Ponto de entrada MNTA084
/*/
//---------------------------------------------------------------------
User Function MNTA084() //Função responsável pela chamda dos pontos de entrada da rotina MNTA084 - Veículos.

Local aParam   := PARAMIXB // Parâmetros passados pelo ponto de entrada.
Local xRet     := .T.// Retorno da função.
Local oObj     := '' // Objeto que receberá o modelo.
Local cIdPonto := '' // Identificador da chamada do ponto de entrada.
Local cIdModel := '' // Identificador do modelo utilizado.
Local cModel   := '' // Identifica o modelo utilizado e receberá o seu identificador.

If aParam <> NIL // Identifica que foram enviado os parâmetros.
    oObj     := aParam[1] // Modelo ativado.
    cIdPonto := aParam[2] // Determina o ponto de chamada.
    cIdModel := aParam[3] // Identificador do modelo.

    If cIdPonto == 'MODELPOS' //Novo modelo para chamada do ponto de entrada MNTA0841

        oST9 := MntPneu():New // Inicializa classe
        oST9:ModelToClass( oObj ) // Carrega a classe com modelo de dados
        xRet := oST9:Valid() // Executa validação final
        oST9:ShowHelp() // Se houver, apresenta erro

    ElseIf cIdPonto == 'MODELCOMMITTTS' //Novo modelo para chamada do ponto de entrada MNTA0842.

        If !Empty(oObj:GetValue('T9_CODBEM'))
            MsgInfo("Ponto de entrada 'MNTA084' executado com sucesso! Codigo do bem: " + oObj:GetValue('T9_CODBEM'))
            xRet := .T.
        EndIf

    EndIf
EndIf

Return xRet //Retorno do ponto de entrada.

Exemplo 2

#Include "Protheus.ch"
#Include "Fwmvcdef.CH"

//---------------------------------------------------------------------
/*/{Protheus.doc} MNTA084
Ponto de entrada MNTA084
/*/
//---------------------------------------------------------------------
User Function MNTA084() //Função responsável pela chamda dos pontos de entrada da rotina MNTA084 - Veículos.

    Local aParam   := PARAMIXB // Parâmetros passados pelo ponto de entrada.
    Local xRet     := .T.// Retorno da função.
    Local oObj     := "" // Objeto que receberá o modelo.
    Local cIdPonto := "" // Identificador da chamada do ponto de entrada.
    Local cIdModel := "" // Identificador do modelo utilizado.
    Local cPlaca   := ""

    If aParam <> NIL // Identifica que foram enviado os parâmetros.
        oObj     := aParam[1] // Modelo ativado.
        cIdPonto := aParam[2] // Determina o ponto de chamada.
        cIdModel := aParam[3] // Identificador do modelo.

        If cIdPonto == 'MODELPOS' //Novo modelo para chamada do ponto de entrada MNTA0841

            oModel := oObj:GetModel('MNTA084_ST9') // Posiciona no Model
            If oModel:GetOperation() != MODEL_OPERATION_DELETE // Valida apenas se não for deleção

                cPlaca := oModel:GetValue('T9_PLACA')
                If Empty(cPlaca)
                    Help(NIL, NIL, "Atenção", NIL, "O campo Placa não foi preenchido", 1, 0, NIL, NIL, NIL, NIL, NIL, {"Favor preencher o campo Placa"})
                    xRet := .F.
                EndIf

            EndIf

        EndIf
    EndIf

Return xRet //Retorno do ponto de entrada.

Árvore de páginas

DT PE MNTA084 Ponto de entrada

PONTO DE ENTRADA CADASTRO DE VEÍCULOS (MNTA084)

Características do Requisito

Ponto de Entrada