Linha Microsiga Protheus

Árvore de páginas

Ponto de entrada que acionado ao repassar uma nova tarefa da manutenção padrão para manutenção

Características do Requisito

Linha de Produto:

Microsiga Protheus

Segmento:

Manufatura

Módulo:

SIGAMNT - Manutenção de Ativos / SIGAGFR - Gestão de Frotas

Rotina:

RotinaNome Técnico
MNTA180Manutenção Padrão

Ponto de Entrada

Descrição:

Ponto de entrada que acionado ao repassar uma nova tarefa da manutenção padrão para manutenção.

Parâmetros

TipoDescrição
string

Código do Bem vinculado a manutenção em atualização.

string

Serviço vinculado a manutenção em atualização.

int

RECNO do registro referente a tarefa da manutenção atualizado.

Exemplo do P.E. MNTA1800
#include 'totvs.ch'

User Function MNTA1800()

    Local cAlsSTF := GetNextAlias()
    Local cCodBem := ParamIXB[1]
    Local cCodSer := ParamIXB[2]
    Local nRecST5 := ParamIXB[3]

    dbSelectArea( 'ST5' )
    dbGoTo( nRecST5 )
 
    BeginSQL Alias cAlsSTF

        SELECT
            MAX( ST5.T5_DTULTMA ) AS T5_DTULTMA,
            MAX( ST5.T5_CONMANU ) AS T5_CONMANU
        FROM
            %table:STF% STF
        INNER JOIN
            %table:ST5% ST5 ON
                ST5.T5_FILIAL  = STF.TF_FILIAL        AND
                ST5.T5_CODBEM  = STF.TF_CODBEM        AND
                ST5.T5_SERVICO = STF.TF_SERVICO       AND
                ST5.T5_SEQRELA = STF.TF_SEQRELA       AND
                ST5.T5_TAREFA  = %exp:ST5->T5_TAREFA% AND  
                ST5.%NotDel%
        WHERE
            STF.TF_FILIAL  = %xFilial:STF% AND
            STF.TF_CODBEM  = %exp:cCodBem% AND
            STF.TF_SERVICO = %exp:cCodSer% AND 
            STF.TF_ATIVO   = 'N'           AND
            STF.%NotDel%

    EndSQL

    If (cAlsSTF)->( !EoF() )

        RecLock( 'ST5', .F. )

            ST5->T5_DTULTMA := SToD( (cAlsSTF)->T5_DTULTMA )
            ST5->T5_CONMANU := (cAlsSTF)->T5_CONMANU

        MsUnLock()

    EndIf

    (cAlsSTF)->( dbCloseArea() )

Return