DT PE Punto Entrada FA855CPOS Inclusión de pre orden de pago ARG

01. DATOS GENERALES

Producto

TOTVS Backoffice

Línea de producto:

Línea Protheus

Segmento:

Backoffice

Módulo:

SIGAFIN - Financiero.

Función:

Rutina	Nombre Técnico
CONSCCARG.PRW	Consulta de Cuenta corriente en la AFIP Orden de pago.
FECREDAMB.PRW	Parametriza el TOTVS Services para el webservice WSFECRED.
FINA847.PRW	Browser Orden de pago Mod. II.
FINA850.PRW	Orden de pago Mod. II.
FINA850A.PRW	Complemento Orden de pago Mod. II.
FINA850I.PRW	Complemento Orden de pago Mod. II.
FINA855.PRW	Nueva orden previa de pago.
FINRETARG.PRW	Cálculo de retenciones Mod. II - Estructura.
FINRETGAN.PRW	Cálculo de retención de ganancias.
FINRETIBB.PRW	Cálculo de retención de IIBB.
FINRETIVA.PRW	Cálculo de retención de IVA.
FINRETMUN.PRW	Cálculo de retención de Municipalidades.
FINRETSLI.PRW	Cálculo de retención SLI.
FINRETSUS.PRW	Cálculo de retención de SUSS.
TRFFECRED.PRW	Función que realiza la transferencia de la aceptación en la rutina de Orden previa de pago AFIP.
TRFOPARG.PRW	Transferencia de aceptación en la rutina Orden de pago.
TRFOPCRED.PRW	Transferencia de aceptación en la rutina Orden de pago.

País:

Argentina.

Ticket:

17959588.

Requisito/Story/Issue (informe el requisito vinculado):

DMICNS-18275.

02. SITUACIÓN/REQUISITO

Se solicita implementar que el dato tome del grabado en tabla SE2, pudiendo agregar los campos personalizados a la query y a la grabación de la tabla temporal F855TMP, para que sea implementado este tratamiento en generación del Archivo temporal en la función A855SE2() del FINA855.

03. SOLUCIÓN

Se implementa el tratamiento para traer la información del campo indicado en el Punto de entrada de forma automática, el campo puede ser variable a la personalización deseada, sin embargo, el campo debe de estar creado en la base de datos en la tabla correspondiente para poder cumplir con su función.

Por medio del módulo de Configurador(SIGACFG) realizar la siguiente configuración:
1. En la tabla deseada debe de existir el campo que desea agregar por medio del punto de Entrada, para este escenario, se agrega en las tablas Cuentas por pagar(SE2) e Ítem Preorden de pago (FJL) los campo Descripción modalidad (E2_XDESNAT/FJL_XDESNA).
En la rutina de Productos(MATA010) que se encuentra en el menú perteneciente al módulo Compras-SIGACOM (Actualizaciones | Archivos) registre un producto.
En la rutina de Proveedores(MATA020) que se encuentra en el menú perteneciente al módulo Compras-SIGACOM (Actualizaciones | Archivos) incluir un proveedor configurado para el cálculo de la retención de ingresos brutos.
En la rutina de Impuestos Variables(MATA995) que se encuentra en el menú perteneciente al módulo de Libros Fiscales-SIGAFIS (Actualizaciones | Archivos) configurar los impuestos deseados.
En la rutina de Tipos de Entrada Y Salida(MATA080) que se encuentra en el menú perteneciente al módulo Compras-SIGACOM (Actualizaciones | Archivos) incluir una TES de Entrada/Salida.
En la rutina de Fiscal Vs Imp.(MATA998) que se encuentra en el menú perteneciente al módulo Libros Fiscales-SIGAFIS (Actualizaciones | Archivos) deberá incluir un registro dependiendo de tipo de comprobante, impuesto y tipo de agente fiscal.
En la rutina de Factura de Entrada (MATA101N) que se encuentra en el menú perteneciente al módulo Compras-SIGACOM(Actualizaciones | Movimientos) registre una factura de entrada para el proveedor.

A través de la rutina de Preorden Pago Mod. II(FINA850) que se encuentra en el menú perteneciente al módulo Financiero - SIGAFIN (Actualizaciones | Proceso Modelo II) genere la Preorden de pago utilizando el titulo generado previamente.
1. De clic al botón Incluir, después, informe los parámetros que mejor se adapten a sus necesidades.
2. Seleccione el título generado previamente.
3. Verifique que exista información en el campo utilizado en el punto de entrada, para este escenario el campo es Descripción modalidad (E2_XDESNAT).
4. El sistema mostrará la información en automático en el campo indicado por medio del punto de entrada.

04. INFORMACIÓN ADICIONAL

Punto de Entrada

Descripción:

FA855CPOS()

Ubicación:

Financiero

Eventos:

-

Programa Fuente:

FINA855.PRW

Función:

FINA855()

Respuesta:

Nombre

Tipo

Descripción

Obligatorio

aRet

Array

Campos a incluir en grid de pestaña de Orden Previa.

El arreglo (aRet) en el cual se agregan los campos es a dos posiciones:

En la primera posición se incluye un arreglo con el campo y las propiedades que va a tener en el grid de la pestaña de “Orden Previa”.

Importante: Para que el campo sea grabado, en la posición 6 del arreglo (X3_VALID) adicional a las validaciones de usuario, se debe grabar en el contenido del nuevo campo en la tabla temporal (FA855SE2), como se muestra en el ejemplo UpdCampo(cCampo), en caso de no grabarlo, no será actualizado en la FJL.
En la segunda posición se informa el nombre del campo de la tabla FJL en el cual será grabado el valor.

Sí

Ejemplo:

#Include 'Protheus.ch'

/*/{Protheus.doc} FA855CPOS
Carga campos que seran incluidos en la solapa.

@Type User Function
@Author Microsiga Protheus
@Since 18/10/2023
@Version P12.1.2310
@Param
@Return aRet: Campos que serán agregados en la solapa.
/*/

User Function FA855CPOS
Local _aArea := GetArea()
Local aRet := {}

// X3_TITULO, X3_CAMPO, X3_PICTURE, X3_TAMANHO, X3_DECIMAL, X3_VALID, "", X3_TIPO, "", "Campo en FJL"})
Aadd(aRet,{{RetTitle("E2_XDESNAT"), "E2_XDESNAT", PesqPict("SE2","E2_XDESNAT"), TamSX3("E2_XDESNAT")[1], TamSX3("E2_XDESNAT")[2],'u_UpdCampo("E2_XDESNAT")', "", "C", "", ""}, {"FJL_XDESNA"}})

RestArea( _aArea )
Return(aRet)

Es importante que el campo que sea utilizado para el punto de entrada exista creado en la base de datos en las dos tablas informadas en el arreglo aRet, para el ejemplo de arriba es necesario contar con el campo E2_XDESNAT creado en la tabla SE2 y el campo FJL_XDESNA creado en la tabla FJL.

Al momento de incluir la Preorden de pago la información será cargada inicialmente del campo del primer bloque del arreglo, para el ejemplo de arriba es el campo E2_XDESNAT , después, al realizar las acciones de modificar, visualizar, borrar, esta información será consultada del campo FJL_XDESNA.

/*/{Protheus.doc} UpdDesNat
Actualiza valor en tabla tamporal FA855SE2.

@Type User Function
@Author Microsiga Protheus
@Since 18/10/2023
@Version P12.1.2310
@Param cCampo: Nombre del campo.
@Return lRet: (.T.) Indica que se actualizó el valor y que la validación fue correcta.
/*/

User Function UpdDesNat(cCampo)
Local lRet := .F.
Local cDesNat := ""

If FA855SE2->(DbSeek(xFilial("SE2")+cFornece+cLoja+GdFieldGet("E2_PREFIXO")+GdFieldGet("E2_NUM")+GdFieldGet("E2_PARCELA")+GdFieldGet("E2_TIPO")))
cDesNat := Posicione("SED",1,xFilial("SE1")+FA855SE2->E2_NATUREZ,"ED_DESCRIC")
RecLock("FA855SE2",.F.)
FA855SE2->E2_XDESNAT := cDesNat//GdFieldGet(cCampo)
FA855SE2->(MsUnlock())
lRet := .T.
EndIf

oBrwTit:Refresh()

Return lRet

/*/{Protheus.doc} UpdCampo
Actualiza valor en tabla tamporal FA855SE2.

@Type User Function
@Author Microsiga Protheus
@Since 18/10/2023
@Version P12.1.2310
@Param cCampo: Nombre del campo.
@Return lRet: (.T.) Indica que se actualizó el valor y que la validación fue correcta.
/*/

User Function UpdCampo(cCampo)
Local lRet := .F.
GdFieldPut(cCampo, M->&(cCampo))

//Validación de usuario para el campo FJL_TESTE
If FA855SE2->(DbSeek(xFilial("SE2")+cFornece+cLoja+GdFieldGet("E2_PREFIXO")+GdFieldGet("E2_NUM")+GdFieldGet("E2_PARCELA")+GdFieldGet("E2_TIPO")))
RecLock("FA855SE2",.F.)
FA855SE2->&(cCampo) := GdFieldGet(cCampo)
FA855SE2->(MsUnlock())
lRet := .T.
EndIf
oBrwTit:Refresh()

Return lRet

05. ASUNTOS RELACIONADOS

3320927_DMICNS-3677_DT_Punto_de_Entrada_FA855CPOS_PreOrden_ARG

Árvore de páginas