Linha Microsiga Protheus

Árvore de páginas


CONTEÚDO


01. VISÃO GERAL

A rotina de Entidade(OGA010) foi criado usando a arquitetura Model-View-Controller ou MVC, possibilitando o uso da regra de negócio em aplicações automática.

A finalidade deste documento é exemplificar a inclusão, alteração e exclusão de uma entidade via rotina automática MVC. 

Deve ser adequado conforme a necessidade do cliente.


02. EXEMPLO DE UTILIZAÇÃO


User Function zIncReg()
    Local lRet := .F.
    Local oModel := Nil
     
    oModel	:= FWLoadModel('OGA010')   
    oModel:SetOperation(MODEL_OPERATION_INSERT) //INCLUSÃO
    oModel:Activate()
     
    //### Modelos de dados: NJ0UNICO, NN0UNICO ###
    //Setando valores nos campos
    oModel:GetModel('NJ0UNICO'):SetValue('NJ0_CGC', '71407447000128' ) 
    oModel:GetModel('NJ0UNICO'):SetValue('NJ0_CODENT', '990001') 
    oModel:GetModel('NJ0UNICO'):SetValue('NJ0_LOJENT', '01') 
    oModel:GetModel('NJ0UNICO'):SetValue('NJ0_NOME  ', 'ENTIDADE AGRO ')
    oModel:GetModel('NJ0UNICO'):SetValue('NJ0_NOMLOJ', 'ENTIDADE AGRO')
    oModel:GetModel('NJ0UNICO'):SetValue('NJ0_CLASSE', '3')

	oModel:GetModel('NJ0UNICO'):SetValue('NJ0_CODFOR', '000005')
	oModel:GetModel('NJ0UNICO'):SetValue('NJ0_LOJFOR', '01')

	oModel:GetModel('NJ0UNICO'):SetValue('NJ0_CODCLI', '024024')
	oModel:GetModel('NJ0UNICO'):SetValue('NJ0_LOJCLI', '01')
	
  
    //modelo de dados da Grid "Dados Bancarios"
    oModel:GetModel('NN0UNICO'):GoLine( 1 ) //posicionando na linha
    oModel:GetModel('NN0UNICO'):SetValue('NN0_ITEM', '01')   
    oModel:GetModel('NN0UNICO'):SetValue('NN0_CODBCO', '001')           
    oModel:GetModel('NN0UNICO'):SetValue('NN0_CODAGE', '2370') 
	oModel:GetModel('NN0UNICO'):SetValue('NN0_CODCTA', '1213967') 
 
    If oModel:VldData() //valida os dados
        oModel:CommitData() //realiza a gravação do registro
        MsgInfo("Registro incluído com sucesso")   
        lRet := .T.
    Else   
        VarInfo("",oModel:GetErrorMessage())
        MsgAlert("Erro ao incluir o registro")
    EndIf 
 
return lRet
User Function zAltReg()
    Local lRet := .F.
    Local oModel := Nil
     
    dbSelectArea("NJ0")
    NJ0->(DbSetOrder(1))
    If NJ0->(DbSeek(xFilial("NJ0") + '990001'))
        oModel  := FWLoadModel('OGA010')   
        oModel:SetOperation(MODEL_OPERATION_UPDATE) //ALTERAÇÃO
        oModel:Activate()
        
        //### Modelos de dados: NJ0UNICO, NN0UNICO ###
        //Setando valores nos campos
        oModel:GetModel('NJ0UNICO'):SetValue('NJ0_ATIVO', '2')
    
    
        If oModel:VldData() //valida os dados
            oModel:CommitData() //realiza a gravação do registro
            MsgInfo("Registro alterado com sucesso")   
            lRet := .T.
        Else   
            VarInfo("",oModel:GetErrorMessage())
            MsgInfo("Erro ao alterar o registro")
        EndIf 
    Else
        MsgInfo("Registro não localizado!")
    EndIf
 
return lRet
User Function zDelReg()
    Local lRet := .F.
    Local oModel := Nil
     
    dbSelectArea("NJ0")
    NJ0->(DbSetOrder(1))
    If NJ0->(DbSeek(xFilial("NJ0") + '990001'))
        oModel  := FWLoadModel('OGA010')   
        oModel:SetOperation(MODEL_OPERATION_DELETE) //EXCLUSÃO
        oModel:Activate()
        
        If oModel:VldData() //valida os dados
            oModel:CommitData() //realiza a gravação do registro
            MsgInfo("Registro excluido com sucesso")   
            lRet := .T.
        Else   
            VarInfo("",oModel:GetErrorMessage())
            MsgAlert("Erro ao excluir o registro")
        EndIf 
    Else
        MsgInfo("Registro não localizado!")
    EndIf
 
return lRet

03. ASSUNTOS RELACIONADOS