M632ADDFLD - Adiciona campos personalizados no cabeçalho dos programas "MATA632 - Operações" e "PCPA124 - Processos Produtivos"

Ponto de Entrada

Exemplo:

#Include 'Protheus.ch'

User Function M632ADDFLD()
Local cAddFields := "G2_ATIVO|G2_OBSERVA"

/*
   cAddFields contém uma string, com os campos customizados que serão adicionados no cabeçalho
   do programa MATA632. Os campos devem ser concatenados utilizando o separador '|', e o nome dos campos
   deve estar sem espaços em branco.
*/
Return cAddFields

Para a correta gravação dos campos personalizados no banco de dados, é necessário também codificar um ponto de entrada para atribuir os valores dos campos personalizados para todas as operações cadastradas na tabela SG2. Pode ser utilizado o ponto de entrada padrão do MVC para fazer esta atribuição. Documentação sobre o ponto de entrada padrão do MVC: Ponto de Entrada Padrão do MVC

Exemplo deste ponto de entrada:

#Include 'Protheus.ch'

User Function MATA632()
Local aParam := PARAMIXB
Local xRet := .T.
Local oModel := Nil
Local nI := 0

If aParam <> NIL
   If aParam[2] == "MODELPOS" .And. aParam[3] == "MATA632" //Validação do modelo do MATA632.
      oModel := aParam[1] //Recupera o Modelo do programa.
      If oModel:GetOperation() != 5 //Operação de exclusão não é necessário atualizar os valores.
         For nI := 1 To oModel:GetModel("MATA632_SG2"):GetQtdLine() //Percorre as linhas da grid da SG2.
            oModel:GetModel("MATA632_SG2"):GoLine(nI) //Posiciona na linha.

            //Atribui o valor dos campos personalizados, que foram adicionados no cabeçalho do programa.
            oModel:GetModel("MATA632_SG2"):SetValue("G2_ATIVO",oModel:GetValue("MATA632_CAB","G2_ATIVO"))
            oModel:GetModel("MATA632_SG2"):SetValue("G2_OBSERVA",oModel:GetValue("MATA632_CAB","G2_OBSERVA"))
         Next nI
      EndIf
   EndIf
EndIf

Return xRet