Linha Microsiga Protheus

Árvore de páginas

Carregando...
Tempo aproximado para leitura: 3 minutos

01. DADOS GERAIS

Linha de Produto:Microsiga Protheus®
Segmento:Backoffice
Módulo:Financeiro
IdiomasPortuguês
Função:

FINC021 - Fluxo de Caixa


02. DESCRIÇÃO


O ponto de entrada FC21CTRFLX possibilita a manipulação dos dados exibidos no browse da consulta de Fluxo de Caixa.

Obs.: a estrutura do array retornado na função deve continuar sendo uma matriz (possuindo de 1 a N linhas) e contendo 10 posições (colunas), não podendo ser modificada.

03. PARÂMETROS

  

Nome

Tipo

Descrição

Conteúdo

paramIXB[1]

Array

Array (matriz) de informações que serão exibidas no Fluxo de Caixa.

Posição do arrayTipoDescrição
paramIXB[X][01]

Caractere

Obs.: Data no formato "dd/mm/aaaa". Exemplo: "19/02/2022"

Data do Fluxo
paramIXB[X][02]NuméricoCrédito (Entradas)
paramIXB[X][03]NuméricoDébito (Saídas)
paramIXB[X][04]NuméricoSaldo do Dia
paramIXB[X][05]NuméricoVariação do Dia (percentual)
paramIXB[X][06]NuméricoCrédito (Entradas) Acumulado
paramIXB[X][07]NuméricoDébito (Saídas) Acumulado
paramIXB[X][08]NuméricoSaldo Acumulado
paramIXB[X][09]NuméricoVariação Acumulada (percentual)
paramIXB[X][10]NuméricoNão utilizado


04. RETORNO

        aFluxo (Array)

        Array (matriz) de informações que serão exibidas no Fluxo de Caixa.

05. EXEMPLO DE UTILIZAÇÃO

FC21CTRFLX
#Include "PROTHEUS.CH"

#Define DATAFLUXO               1
#Define ENTRADAS                2
#Define SAIDAS                  3
#Define SALDODIA                4
#Define VARIACAODIA             5
#Define ENTRADASACUMULADAS      6
#Define SAIDASACUMULADAS        7
#Define SALDOACUMULADO          8
#Define VARIACAOACUMULADA       9

/*/{Protheus.doc} FC21CTRFLX
Possibilita a manipulação dos dados exibidos no browse da consulta de Fluxo de Caixa.

@type   Function
@author TOTVS
@since  21/02/2022
@return array, dados que serão exibidos no Fluxo de Caixa
/*/
User Function FC21CTRFLX()

    Local aFluxoPE      As Array
    Local nLinhaFlux    As Numeric

    aFluxoPE := paramIXB[1]

    //Sua lógica para alteração dos valores abaixo
    For nLinhaFlux := 1 To Len(aFluxoPE)
        //aFluxoPE[nLinhaFlux][DATAFLUXO]           - Data não deve ser alterada
        aFluxoPE[nLinhaFlux][ENTRADAS]              += 20
        aFluxoPE[nLinhaFlux][SAIDAS]                += 50
        aFluxoPE[nLinhaFlux][SALDODIA]              := aFluxoPE[nLinhaFlux][ENTRADAS] - aFluxoPE[nLinhaFlux][SAIDAS]
        aFluxoPE[nLinhaFlux][VARIACAODIA]           := (aFluxoPE[nLinhaFlux][SAIDAS] / aFluxoPE[nLinhaFlux][ENTRADAS]) * 100
        aFluxoPE[nLinhaFlux][ENTRADASACUMULADAS]    += 20
        aFluxoPE[nLinhaFlux][SAIDASACUMULADAS]      += 50
        aFluxoPE[nLinhaFlux][SALDOACUMULADO]        := (aFluxoPE[nLinhaFlux][ENTRADAS] - aFluxoPE[nLinhaFlux][SAIDAS])
        aFluxoPE[nLinhaFlux][VARIACAOACUMULADA]     := (aFluxoPE[nLinhaFlux][SAIDASACUMULADAS] / aFluxoPE[nLinhaFlux][ENTRADASACUMULADAS]) * 100
    Next nLinhaFlux

Return aFluxoPE