DT PE A410BSIT - Alterar status da situação do Pedido de Venda - EAI

CONTEÚDO

Dados Gerais
Descrição
Sintaxe
Parâmetros
Retorno
Exemplo

01. DADOS GERAIS

Produto:	TOTVS Backoffice
Linha de Produto:	Linha Protheus
Segmento:	Backoffice
Módulo:	SIGAFAT - Faturamento
Função:	MATI410B - Pedido de Venda EAI (DOCUMENTTRACEABILITYORDER)
Abrangencia:	Microsiga Protheus 12
Versões:	Microsiga Protheus 12
Compativeis Paises:	Todos
Sistema Operacionais:	Todos
Compatível com as Bases de Dados:	Todos
Nivel de Acesso:	Nível 1 (Acesso Clientes)
Idiomas	Todos

02. DESCRIÇÃO

O ponto de entrada A410BSIT permite que seja alterado o descritivo da situação do Pedido de Venda, onde deverá ser retornado ou não o novo descritivo.
A rotina retorna com as seguintes situações:

Pedido em Aberto
Pedido Encerrado
Pedido Liberado
Pedido Bloqueado por Regra
Pedido Bloqueado por Verba

Importante

Esse ponto de entrada permite somente ser modificado o descritivo, não tendo ação na liberação ou bloqueio do pedido caso o pedido esteja bloqueado por qualquer motivo e a mensagem seja alterada para pedido liberado no protheus ação de liberação não vai ocorrer. Caso o pedido esteja liberado e a mensagem seja modificada para bloqueado essa ação não vai ocorrer.

Caso seja necessário o bloqueio ou desbloqueio de pedido será necessário a utilização de um outro ponto de entrada, pois esse ponto somente vai tratar a modificação da descrição da situação do pedido.

03. SINTAXE

A410BSIT( { cFilUse, cNumDoc, cSitDoc } ) ---> cRet

04. PARÂMETROS

Nome	Tipo	Descrição
cFilUse	Caractere	Retorna a Filial corrente.
cNumDoc	Caractere	Retorna o numero do pedido que deverá ser enviado para integração EAI.
cSitDoc	Caractere	Retorna a situação atual do pedido.

05. RETORNO

Retorno	Tipo	Descrição	Obrigatório
cRet	Caracter	Descritivo da situação do pedido.	Sim

05. EXEMPLO

Exemplo

#INCLUDE 'TOTVS.CH'    

User Function A410BSIT()

Local cFilUse  := ParamIxb[1]  //filial que esta em uso
Local cNumDoc  := PadR(ParamIxb[2],TamSx3("C5_NUM")[1])   // Numero do pedido
Local cSitDoc  := ParamIxb[3]  // Situação do documento
Local cRet     := ""           // Retorno do ponto de entrada 
Local aArea    := GetArea()
Local aArSC6   := SC6->(GetArea())
Local cChave   := ""
Local nValDoc  := 0

If cFilUse == "D MG 01 "
    If !"Transmitida" $ cSitDoc
        cChave := xFilial("SC5") + cNumDoc
        DbSelectArea("SC6")
        DbSetorder(1) //C6_FILIAL+C6_NUM+C6_ITEM+C6_PRODUTO
        DbSeek(cChave )
       
        While !Eof() .And. cChave == SC6->C6_FILIAL + SC6->C6_NUM 
            
            nValDoc += SC6->C6_VALOR

            SC6->(DbSkip())
        End

        If nValDoc > 1000
            cRet := "Autorização da Gerencia Financeira"
        Else 
            cRet := cSitDoc
        EndIf

    EndIf 

EndIf 

Restarea(aArSC6)
RestArea(aArea)

Return cRet

Árvore de páginas