Linha Microsiga Protheus

Árvore de páginas

01. DADOS GERAIS

Linha de Produto:Microsiga Protheus®
Segmento:Serviços
Módulo:Financeiro
Rotina:FINA090 - Baixa a Pagar Automática


02. DESCRIÇÃO

O ponto de entrada FBXL9816 foi disponibilizado para atender a Lei 9.816 de 1999, onde é possível que seja informada a taxa do câmbio a ser utilizada na formação da base de calculo do IRRF, que não é necessariamente a taxa utilizada na baixa do título a pagar. Ele será executado no calculo/geração do IRRF com fago gerador na baixa (A2_CALCIRF=2).

Observações:

  • O ponto de entrada FBXL9816 esta disponível para execução durante a baixa de qualquer título, cabe a quem for implementar criar os critérios e regras para o uso da nova taxa;
  • Para atender as baixas manuais (FINA080), afim de respeitar o legado do sistema, deve ser utilizado o ponto de entrada F80L9816 - que já era utilizado antes da existência desse ponto de entrada;
  • Esse ponto de entrada não contempla a geração de IRRF através:
    • Da inclusão de Pagamento Antecipado (PA);
    • Da Compensação entre Títulos a Pagar (FINA340);
    • Da Compensação entre Carteiras (FINA450);

Importante

Parâmetros:

ParamIXB[1] - Chave do título - SE2→(E2_FILIAL+E2_PREFIXO+E2_NUM+E2_PARCELA+E2_TIPO+E2_FORNECE+E2_LOJA)
ParamIXB[2] - Data do Pagamento
ParamIXB[3] - Data do Débito


Além dos parâmetros informados no ponto de entrada, pode-se utilizar de qualquer informação disponível do Título a Pagar (campos da tabela SE2) e Fornecedor (campos da tabela SA2) que esta sendo processado, pois os registros estarão posicionados.


Retorno:

NomeTipoDescriçãoObrigatório
nTaxaNuméricoTaxa a ser utilizada para compor a base de cálculo do IRRF. No caso de não haver mudança da taxa padrão do sistema, retornar 0 (zero)Sim


03. EXEMPLO DE UTILIZAÇÃO


FBXL9816
#INCLUDE "PROTHEUS.CH"
 
User Function FBXL9816()
 
Local cChave    := ParamIXB[1]
Local dDtBaixa  := ParamIXB[2]
Local dDtDebito := ParamIXB[3]
Local dDtTaxa   := dDataBase
Local cAlias    := ""
Local aArea     := GetArea()
Local nTaxa     := 0   

dDtTaxa:=dDtBaixa-2
 
If SA2->A2_TIPO=='X' .And. SE2->E2_MOEDA > 1
    dbSelectArea('SED')
    aAreaSED := SED->(GetArea())
    SED->(dbSetOrder(1))
    SED->(dbSeek(xFilial('SED')+SE2->E2_NATUREZ))
    If SED->ED_CALCIRF=='S'
        //-- Retorna taxa na data solicitada
        nTaxa:=RecMoeda(dDtTaxa,SE2->E2_MOEDA)
    EndIF
    RestArea(aAreaSED)
EndIF
 
RestArea(aArea)
Return(nTaxa)


04. DEMAIS INFORMAÇÕES

IRRF - Taxa Cambial no cálculo do imposto para fornecedor estrangeiro

05. ASSUNTOS RELACIONADOS

RecMoeda() (SIGAFAT)