TOTVSTEC

Árvore de páginas

Você está vendo a versão antiga da página. Ver a versão atual.

Comparar com o atual Ver Histórico da Página

« Anterior Versão 5 Próxima »

Retorna  o valor de uma determinada chave cKey, do objeto Json, em formato de string

Sintaxe

JsonObject:GetJsonText(cKey)

Parâmetros

NomeTipoDescriçãoObrigatórioReferência
cKeycaractereNome da propriedade do objeto Json cujo conteúdo será retornadoX


Retorno

Nome

Tipo

Descrição

cRet

caractere

String que seja o conteúdo de uma propriedade de um objeto JSON

Observações

  • Caso a propriedade não exista ou contiver o valor null, será retornado uma string vazia.
  • Caso o valor da propriedade informada seja uma string, o conteúdo do retorno será um caractere mas nao conterá aspas, conforme primeiro item do exemplo abaixo.
  • Caso o valor da propriedade informada seja um vetor e em seu conteúdo haja strings, estas serão preenchidas dentro do vetor com aspas, conforme o ultimo exemplo abaixo.


Exemplo

Exemplo 1
#include "protheus.ch"

user function GJTExemplo()
  local oJson
  local ret

  oJson := JsonObject():new()

  ret := oJson:fromJson('{"character":"Joaquim", "json":{"Joao":22, "Joana":33}, "array":[4,12,5], "numeric":23, "logic":false, "nil":null, "CArr":["Joaquim","Ana","joao"]}')

  if ValType(ret) == "U"
    Conout("JsonObject populado com sucesso")
  else
    Conout("Falha ao popular JsonObject. Erro: " + ret)
  endif

  ret := oJson:GetJsonText("character")

  conout (ret)

  /*
  Será impresso:
  Joaquim
  */

  ret := oJson:GetJsonText("json")

  conout (ret)

  /*
  Será impresso:
  {"Joana":33,"Joao":22}
  */

  ret := oJson:GetJsonText("array")

  conout (ret)

  /*
  Será impresso:
  [4,12,5]
  */

  ret := oJson:GetJsonText("numeric")

  conout (ret)

  /*
  Será impresso:
  23
  */

  ret := oJson:GetJsonText("logic")

  conout (ret)

  /*
  Será impresso:
  false
  */

  ret := oJson:GetJsonText("nil")

  conout (ret)

  /*
  Será impresso:
  
  */

  ret := oJson:GetJsonText("CArr")

  conout (ret)

  /*
  Será impresso:
  ["Joaquim","Ana","joao"]
  */

  ret := oJson:GetJsonText("xpto")

  conout (ret)

  /*
  Será impresso:
  
  */
  FreeObj(oJson)
return


Observações:

Disponível em build igual ou superior a 17.2.1.0

  • Sem rótulos