Linha Microsiga Protheus

Árvore de páginas

Carregando...
Tempo aproximado para leitura: 4 minutos

01. DADOS GERAIS

Produto:

TOTVS Manutenção de Ativos

Linha de Produto:

Linha Protheus

Segmento:

Manufatura

Módulo:

TOTVS Manufatura (Linha Protheus) - Manutenção de ativos (SIGAMNT)

Função:MNTA4905()
País:Brasil


02. DESCRIÇÃO

Descrição:

Ponto de Entrada executado ao montar o Browse, permitindo modificar as propriedades relacionadas ao botões disponíveis em tela ou para adicionar um novo botão na rotina.

Localização:

SIGAMNT: Atualizações/Controle de Oficina/Plano Manutenção/Liberação de OS 

Programa Fonte:

MNTA490.prw

Função:

MNTA4905()

Parâmetros:

NomeTipoDescrição
ParamIXB[1]Array
NomeTipoDescrição
Array[1]ObjetoPropriedades referente ao botão visualizar
Array[2]ObjetoPropriedades referente ao botão Cancelar
Array[3]ObjetoPropriedades referente ao botão Custo Previsto
Array[4]ObjetoPropriedades referente ao botão Insumos
Array[5]ObjetoPropriedades referente ao botão Etapas
Array[6]ObjetoPropriedades referente ao botão Mod. Insumos
Array[7]ObjetoPropriedades referente ao botão Mod. Etapas
Array[8]ObjetoPropriedades referente ao botão Altera O.S.
Array[9]ObjetoObjeto onde será adicionado novo botão.
ParamIXB[2]

Caracter

NomeTipoDescrição
cTRBA490CaracterTabela temporária que contém os campos Ordem (TJ_ORDEM) e Plano (TJ_PLANO)

Retorno:

Nil

03. DEMAIS INFORMAÇÕES

Exemplo MNTA4905()
#Include "Protheus.ch"
 
//-------------------------------------------------------------------
/*/{Protheus.doc} MNTA4905
Permite alterar propriedade de botões ou adicionar um novo.
 
@author  NG Informática
@since   29/10/2019
@version P12
/*/
//-------------------------------------------------------------------
User Function MNTA4905()
 
    Local aButtons  := ParamIXB[1]
    Local cPETabela := ParamIXB[2]
    Local oPnlTop   := aButtons[9]
    Local oTesteOs  := Nil
 
    aButtons[5]:lActive  := .F.
    aButtons[2]:lVisible := .F.
    aButtons[1]:cTitle   := "Teste"
 
    @ 01,328 BUTTON oTesteOs PROMPT "Novo Botão" SIZE 38,12 OF oPnlTop PIXEL ACTION U_MNTATOS((cPETabela)->TJ_ORDEM,(cPETabela)->TJ_PLANO)
 
Return
 
//-------------------------------------------------------------------
/*/{Protheus.doc} MNTA4905
Ação do botão adicionado.
 
@param cPEOrdem, Caracter, Ordem de Serviço.
@param cPEPlano, Caracter, Plano.
 
@author  NG Informática
@since   29/10/2019
@version P12
/*/
//-------------------------------------------------------------------
User Function MNTATOS(cPEOrdem,cPEPlano)
 
    //Grava conteúdo em campo de usuário.
    dbSelectArea("STJ")
    dbSetOrder(1)
    If MsgYesno("Deseja alterar a OS"+space(1)+cPEOrdem+space(1)+"?") .And. dbSeek(xFilial("STJ")+cPEOrdem+cPEPlano)
        Reclock("STJ",.F.)
        STJ->TJ_XUSER := "Registro alterado."
        STJ->(MsUnlock())
    EndIf
 
Return


04. ASSUNTOS RELACIONADOS

  • Não se aplica.