Linha Microsiga Protheus

Árvore de páginas

Carregando...
Tempo aproximado para leitura: 4 minutos

01. DADOS GERAIS

Produto:

TOTVS Manutenção de Ativos

Linha de Produto:

Linha Protheus

Segmento:

Manufatura

Módulo:

TOTVS Manufatura (Linha Protheus) - Manutenção de ativos (SIGAMNT)

Função:MNTA410D()
País:Brasil


02. DESCRIÇÃO

Descrição:

Ponto de entrada acionado na consistência de insumos da O.S. manual. durante os processos de inclusão e alteração. Permitindo assim a inclusão de novas validações neste processo.

Localização:

SIGAMNT: Em Atualizações > Controle de Oficina > Ordens de Serviço > Manual.

Programa Fonte:

MNTA410.prw

Função:

MNTA410D()

Parâmetros:

NomeTipoDescriçãoObrigatório
ParamIXB[1]ArrayLista de insumos reportados na O.S.Sim
ParamIXB[2]NúmericoLinha posicionada que encontra-se em validaçãoSim
ParamIXB[3]ArrayLista de campos contidos na listagem de insumo.Sim

Retorno:

TipoDescriçãoObrigatório

Lógico

Indica se as validações foram realizadas com êxito.

Sim

03. DEMAIS INFORMAÇÕES

Exemplo MNTA410D()
#Include 'Totvs.ch'
  
User Function MNTA410D()
 
    Local aColsUse := ParamIXB[1]
    Local nPos     := ParamIXB[2]
    Local aHeadUse := ParamIXB[3]
    Local lRet     := .T.
    Local nPosAlmx := aScan( aHeadUse, { |x| Trim( Upper( x[2] ) ) == 'TL_LOCAL'   } )
    Local nPosProd := aScan( aHeadUse, { |x| Trim( Upper( x[2] ) ) == 'TL_CODIGO'  } )
    Local nPosTpRg := aScan( aHeadUse, { |x| Trim( Upper( x[2] ) ) == 'TL_TIPOREG' } )
 
    If nPosAlmx > 0 .And. nPosProd > 0 .And. nPosTpRg > 0 .And. nPos > 0
 
        If aColsUse[nPos,nPosTpRg] == 'P'
 
            If aColsUse[nPos,nPosAlmx] == '01' .And. Trim( aColsUse[nPos,nPosProd] ) == 'PRD01'
 
                lRet := .F.
                MsgAlert( 'Local de estoque não deve ser utilizado para o produto: ' + Trim( aColsUse[nPos,nPosProd] )  )
 
            EndIf
 
        EndIf
 
    EndIf
 
Return lRet


04. ASSUNTOS RELACIONADOS

  • Não se aplica.