Frameworksp

Páginas filhas
  • Função callSchedule
Pré-requisitos
  • Obrigatória ativação da Porta Multiprotocolo e Interface Protheus com PO UI (vide Nova interface do Protheus com PO UI);
  • Disponível a partir do release 2410, para LIB 20240520 ou superior.

callSchedule()

Retorna um valor lógico onde .T. indica que chamou a interface e .F. houve falha.

Parâmetros:

NomeTipoObrigatórioDefaultDescrição
cRoutineCaractereX
Rotina do agendamento 

Exemplo de uso:

callSchedule("MATR110")

Sintaxe: callSchdule(<cRoutine>) → logical

Caso a rotina seja inválida ou o ambiente não esteja preparado para abrir o aplicativo PO-UI, será emitido um alerta para o usuário informando o problema.

Processos Disponíveis

O menu de Monitoramento mostra uma listagem das execuções dos agendamentos referente à rotina que foi definida via parâmetro, sendo que são apresentadas apenas as execuções referentes ao usuário logado. A listagem contém as seguintes informações:

  • Status
  • Agendamento
  • Código da Execução
  • Ambiente
  • Empresa
  • Filial
  • Usuário
  • Dia
  • Hora
  • Rotina
  • Módulo
  • Server
  • Versão do Schedule


Exemplo de utilização:

Nela, também é possível realizar uma Busca Rápida ou uma Busca Avançada. Similar a busca realizada pela listagem de agendamentos, no entanto a busca rápida se dá para os campos de Código da Execução ou Server. 

No caso da busca avançada, o filtro pode ser realizado por todos os campos, menos por Server, Rotina e Usuário.


No menu de agendamentos, é possível gerenciar e visualizar todos os agendamentos disponíveis da rotina que foi definida por parâmetro e que pertence ao usuário logado.


Exemplo de utilização:

Para mais informações sobre a adição de um novo agendamento, olhar a documentação completa: Schedule

Exemplo completo:

Exemplo chamando o monitor de execuções do Schedule 
#include "protheus.ch"
#include "fwmvcdef.ch"

//-------------------------------------------------------------------
/*/{Protheus.doc} poc_mvc
Exemplo de um modelo e view baseado em uma unica tabela com chamada
de um relatório no treports pela função totvs.framework.treports.callTReports

@author  Vanessa Ruama
@since   01/12/2022
@version 1.0
/*/
//-------------------------------------------------------------------
User Function poc_mvc()
    Local oBrowse As Object
	
	oBrowse := FWMBrowse():New()
	oBrowse:SetAlias('SC7')
	oBrowse:SetDescription('Pedido de Compras')
	oBrowse:Activate()
		
Return

//-------------------------------------------------------------------
/*/{Protheus.doc} MenuDef
Função para carregamento do menu.

@return aRotina, array, array com as opções de menu.

@author  Vanessa Ruama
@since   01/12/2022
@version 1.0
/*/
//-------------------------------------------------------------------
Static Function MenuDef()
    Local aRotina As Array
    Local aMedicao As Array

    aRotina := {}
    aMedicao := {}

    ADD OPTION aRotina TITLE 'Visualizar'           ACTION 'VIEWDEF.poc_mvc' OPERATION 2 ACCESS 0
    ADD OPTION aRotina TITLE 'Incluir'              ACTION 'VIEWDEF.poc_mvc' OPERATION 3 ACCESS 0
    ADD OPTION aRotina TITLE 'Alterar'              ACTION 'VIEWDEF.poc_mvc' OPERATION 4 ACCESS 0
    ADD OPTION aRotina TITLE 'Excluir'              ACTION 'VIEWDEF.poc_mvc' OPERATION 5 ACCESS 0
    ADD OPTION aRotina TITLE 'Monitor do Schedule'  ACTION 'callRoutine'     OPERATION 8 ACCESS 0
Return aRotina

//-------------------------------------------------------------------
/*/{Protheus.doc} ModelDef
Definição do model referente aos pedidos

@return oModel, objeto, objeto do modelo

@author  Vanessa Ruama
@since   01/12/2022
@version 1.0
/*/
//-------------------------------------------------------------------
Static Function ModelDef()
    Local oModel As Object
    Local oStruSC7 As Object

    oStruSC7 := FWFormStruct(1,"SC7")

	oModel := MPFormModel():New("PEDIDO")
	oModel:SetDescription("Pedido de Compras")
	
	oModel:addFields('MASTERSC7',,oStruSC7)
	oModel:getModel('MASTERSC7'):SetDescription('Pedido de Compras')
	 
Return oModel

//-------------------------------------------------------------------
/*{Protheus.doc} ViewDef
Interface do modelo de dados

@return oView , objeto, retorna a view do modelo

@author  Vanessa Ruama
@since   01/12/2022
@version 1.0
*/
//-------------------------------------------------------------------
Static Function ViewDef()
Local oModel := ModelDef()
Local oView
Local oStrSC7:= FWFormStruct(2, 'SC7')
	
	oView := FWFormView():New()
	oView:SetModel(oModel)

	oView:AddField('FORM_PROD' , oStrSC7,'MASTERSC7' ) 
	oView:CreateHorizontalBox( 'BOX_FORM_PROD', 100)
	oView:SetOwnerView('FORM_PROD','BOX_FORM_PROD')	
	
Return oView

//-------------------------------------------------------------------
/*{Protheus.doc} callTRep
Chamada a rotina de agendamento do Schedule

@author  Vanessa Ruama
@since   26/04/2023
@version 1.0
*/
//-------------------------------------------------------------------
Function callRoutine()
    callSchedule("MATR110")
return .T.
  • Sem rótulos