ATF060GRV PE Transferência ATFA060 - Gravação de dados adicionais

01. DADOS GERAIS

Produto:	TOTVS Backoffice
Linha de Produto:	Linha Protheus
Segmento:	Serviços
Módulo:	TOTVS Backoffice (Linha Protheus) - Ativo Fixo (SIGAATF)
Função:	ATFA060 - Transferências / PE - ATF060GRV
País:	Brasil
Ticket:	Interno
Requisito/Story/Issue :	DSERCTR1-42088

02. SITUAÇÃO/REQUISITO

Essa documentação visa esclarecer e exemplificar sobre o ponto de entrada ATF060GRV.

03. SOLUÇÃO

O ponto de entrada ATF060GRV tem como objetivo realizar gravações adicionais após as gravações comuns da rotina de transferência e sendo possível realizar gravações adicionais nas tabelas posicionadas SN3 e SN4, também levando como parâmetro para referencia o modelo de dados da rotina para checagens e possíveis pontos de critério com base no bem posicionado da movimentação.

Importante

As alterações realizadas no ponto de entrada são de total responsabilidade do cliente que o implementa.

Codigo e exemplos

Exemplo do ponto de Entrada

#include 'totvs.ch'
#include "rwmake.ch"     

User Function ATF060GRV()

    Local Modelo060  := PARAMIXB[1] 
    Local aArea 	 := GetArea()
    Local cBase      := Modelo060:GetValue("GridFNR",'FNR_CBAORI')
    Local cItem      := Modelo060:GetValue("GridFNR",'FNR_ITEORI')
    Local cFilMovi   := Modelo060:GetValue("FieldFN9",'FN9_FILIAL')
    Local cChave     := cFilMovi + cBase + cItem

    dbSelectArea("SN4")
    dbSetOrder(1)

    If dbSeek(cChave)
        While SN4->(!EOF()) .And. cChave==SN4->(N4_FILIAL+N4_CBASE+N4_ITEM)

       		If rtrim(SN4->N4_CONTA) == '1110205' //CONTA NA ORIGEM
            	Reclock("SN4", .F.)
                	N4_CONTA := 'TX003' // CONTA NO DESTINO
            	MsUnlock()
        	Endif

        SN4->(dbSkip())
        EndDo
    Endif

    RestArea(aArea)

Return

Chamada do PE no Sistema

If lCont .And. ExistBlock ("ATF060GRV")
	ExecBlock("ATF060GRV",.F.,.F.,{oModel})
EndIf

Importante Ressaltar que o ponto de entrada somente é acionado caso todas as validações padrões da rotina estejam corretas.

Importante !!

Os exemplos utilizados nessa documentação são meramente ilustrativos.

04. DEMAIS INFORMAÇÕES

Parâmetros

Parâmetros	Tipo	Descrição
PARAIXB[1]	Object	Modelo de dados da rotina de transferência.

Retorno

Nome	Tipo	Descrição
Não se aplica	Não se aplica	Não se aplica

05. ASSUNTOS RELACIONADOS

Não se aplica.

Árvore de páginas