AF060VLAU - Valida pantalla de selección de ítems en la transferencia automática

Descripción

El punto de entrada AF060VLAU valida la pantalla de selección de ítems en la transferencia en modo automático en el momento de la confirmación.

Observaciones

El punto de entrada AF060VLAU activa la opción de confirmación de la pantalla, después de la selección de los ítems para la transferencia y antes de la grabación. Este recibe como parámetros los datos necesarios para la validación de los ítems marcados.

Ejemplos

#Include "Protheus.ch"
User Function AF060VLAU()
Local aArea := GetArea()
Local lRet := .T. 
Local cMarca := PARAMIXB[1]
Local aDados := PARAMIXB[2]
Local dDataBase := PARAMIXB[3]
Local cFilDest := PARAMIXB[4] 
Local cFilOrig := PARAMIXB[5]
Local cFiltro := PARAMIXB[6]
If cFilDest <> cFilOrig
Alert("No se permite transferir a esta sucursal.")
lRet := .F.
EndIf  
If lRet  
DbSelectArea("SN3")
SN3->(DbSetOrder(1))
SN3->(MsSeek(xFilial("SN3")+aDados[1]+aDados[2],.T.))
While SN3->(!Eof()) .And. xFilial("SN3") == SN3->N3_FILIAL .And. SN3->N3_CBASE <= aDados[3] .And. SN3->N3_ITEM <= aDados[4]  
If Empty(cFiltro) .Or. &(cFiltro)
If SN3->N3_OK == cMarca .And. SN3->N3_TIPO == "01"
Alert("No se permite transferir ítem del Tipo 01.")
lRet := .F.  
Exit  
Endif
Endif  
SN3->(DbSkip()) 
EndDo 
EndIf 
RestArea(aArea)
Return lRet

Idioma

Portugués(Brasil)

Versiones

Microsiga_Protheus10

Sistemas operativos compatibles

Todos

Compatible con las bases de datos

Todas

Parámetros

cMarca,{cBaseI,cItemI,cBaseF,cItemF},dDataBAse,cFilDest,cFilOrig,cExpFiltro

Devolución

.F. (No válido) o .T. (Válido)

Eventos de activación del punto de entrada

EnchoiceBar(oDlg1,IIF(AF060VLAUTO(cExpFiltro),(nOpca := 1,oDlg1:End()),)
Static Function AF060VLAUTO(cExpFiltro)
Local lAF060VLAU := ExistBlock("AF060VLAU")
If lAF060VLAU
lRet := ExecBlock("AF060VLAU",.F.,.F.,cMarca {cBaseI,cItemI,cBaseF,cItemF},dDataBAse,cFilDest,cFilOrig,cExpFiltro)
EndIf  
Return lRet

Programa fuente

ATFA060.PRW