Linha Microsiga Protheus

Árvore de páginas



CONTEÚDO

  1. Visão Geral
  2. Exemplo de utilização
    1. Inclusão
    2. Inclusão com mais de um Lançamento
  3. Tabelas utilizada


01. VISÃO GERAL

Exemplos de execução via rotina automática na rotina de lançamentos contábeis automáticos(CTBA102), mostrando exemplos de utilização e tabelas relacionadas.

02. EXEMPLO DE UTILIZAÇÃO

Abaixo mostraremos exemplos de utilização.


Aviso

A Execução automática está disponível apenas para Inclusão de lançamentos contábeis.

Importante

Na utilização de ExecAuto considerar os seguintes critérios:

 - Passar o campo CT2_CONVER como 15555, demais moedas devem ser feitos pela inclusão de um novo aItens

 - Passar o campo CT2_CRITER, para as demais moedas apenas inclui como conversão, não permitindo a inclusão do CT2_VALOR zerado.

 - Para alteração de registro passe novamente o aCab



Inclusão:


myctba102inc 
#INCLUDE "PROTHEUS.CH"
 
//-------------------------------------------------------------------
/*/{Protheus.doc} MyCTBA102Inc    
 
 Inclusão de Lançamento Automático CTBA102
 
@author Totvs
@since 23/06/2022
@version 2.0
 
/*/
//-------------------------------------------------------------------
 
User Function MyCTBA102Inc()
 
Local aArea  := GetArea()
Local aCab   := {}
Local aItens := {}

Private lMsErroAuto     := .F.
Private lMsHelpAuto     := .T.
Private CTF_LOCK        := 0
Private lSubLote        := .T.
 

    RpcSetType(3)
    RpcSetEnv( 'T1', 'D MG 01 ',,,'CTB')

    aAdd(aCab,  {'DDATALANC'     ,dDataBase        ,NIL} )
    aAdd(aCab,  {'CLOTE'         ,'333333'         ,NIL} )
    aAdd(aCab,  {'CSUBLOTE'      ,'001'            ,NIL} )
    aAdd(aCab,  {'CPADRAO'       ,''               ,NIL} )
    aAdd(aCab,  {'NTOTINF'       ,0                ,NIL} )
    aAdd(aCab,  {'NTOTINFLOT'    ,0                ,NIL} )
 
    aAdd(aItens,{  {'CT2_FILIAL'      ,xFilial('CT2'), NIL},;
                   {'CT2_LINHA'      , '001'         , NIL},;
                   {'CT2_MOEDLC'      ,'01'          , NIL},;
                   {'CT2_DC'           ,'3'          , NIL},;
                   {'CT2_DEBITO'      ,'101010100'   , NIL},;
                   {'CT2_CREDIT'      ,'201010100'   , NIL},;
                   {'CT2_VALOR'      , 3000          , NIL},;
                   {'CT2_ORIGEM'     ,'MSEXECAUT'    , NIL},;
                   {'CT2_HP'           ,''           , NIL},;
                   {'CT2_CONVER'    ,'11'            , NIL},;
                   {'CT2_HIST'       ,'MSEXECCT2'    , NIL} } )         
 
    MSExecAuto({|x, y,z| CTBA102(x,y,z)}, aCab ,aItens, 3)
 
    If lMsErroAuto
        lMsErroAuto := .F.
        MostraErro()
    Endif
    
RestArea(aArea)

 
Return


Inclusão com Mais de um Lançamento :


MyCTBA102Inc() 
#INCLUDE "PROTHEUS.CH"
 
//-------------------------------------------------------------------
/*/{Protheus.doc} MyCTBA102Inc   
  
 Inclusão de Lançamento Automático CTBA102
  
@author Totvs
@since 23/06/2022
@version 2.0
  
/*/
//-------------------------------------------------------------------

User Function MyCTBA102Inc()


Local aArea  := GetArea()
Local aCab   := {}
Local aItens := {}
Local nLinha := 2
Local nX     := 0
 
Private lMsErroAuto := .F.
Private lMsHelpAuto := .T.
Private CTF_LOCK    := 0
Private lSubLote    := .T.
 

    RpcSetType(3)
    RpcSetEnv( 'T1', 'D MG 01 ',,,'CTB')

    aAdd(aCab, {'DDATALANC' ,dDataBase ,NIL} )
    aAdd(aCab, {'CLOTE' ,'333333' ,NIL} )
    aAdd(aCab, {'CSUBLOTE' ,'001' ,NIL} )
    aAdd(aCab, {'CPADRAO' ,'' ,NIL} )
    aAdd(aCab, {'NTOTINF' ,0 ,NIL} )
    aAdd(aCab, {'NTOTINFLOT' ,0 ,NIL} )

    For nX := 1 To nLinha
        aAdd(aItens,  {;
            {'CT2_FILIAL' , xFilial('CT2')                       , NIL},;
            {'CT2_LINHA'  , StrZero(nX,3)                        , NIL},;
            {'CT2_MOEDLC' ,'01'                                  , NIL},;
            {'CT2_DC'     ,'3'                                   , NIL},;
            {'CT2_DEBITO' ,'101010100'                           , NIL},;
            {'CT2_CREDIT' ,'201010100'                           , NIL},;
            {'CT2_VALOR'  , 3000                                 , NIL},;
            {'CT2_ORIGEM' ,'MSEXECAUT'                           , NIL},;
            {'CT2_HP'     ,''                                    , NIL},;
            {'CT2_CONVER' ,'11'                                  , NIL},;
            {'CT2_HIST'   ,'MSEXECCT LANCAMENTO '+cValtoChar(nX) , NIL} })
    Next nX
 
    MSExecAuto({|x, y,z| CTBA102(x,y,z)}, aCab ,aItens, 3)
    
    If lMsErroAuto
        lMsErroAuto := .F.
        MostraErro()
    EndIf


RestArea(aArea)
 
Return



03. TABELAS UTILIZADAS

  • CT2- Lançamentos Contábeis