#INCLUDE "PROTHEUS.CH"
#INCLUDE 'FWMVCDEF.CH'


User Function MNTA735() //Função responsável pela chamada dos pontos de entrada da rotina MNTA735 - Retorno Check List

Local aParam    := PARAMIXB //Parâmetros passados pelo ponto de entrada.
Local aAreaTTF  := '' //Variável para gravação da área posicionada.
Local xRet      := .T. //Retorno da função.
Local oObj      := '' //Objeto que receberá o modelo.
Local oGrid1    := '' //Variável de grid.
Local cIdPonto  := '' //Identificador da chamada do ponto de entrada.
Local cIdModel  := '' //Identificador do modelo utilizado.
Local cModel    := '' //Identifica o modelo utilizado e receberá o seu identificador.
Local cEtapa    := '' //Código da etapa.
Local nLinhas   := 0 //Numero de linhas.
Local nLenGrid  := 0 //Numero total de linhas.
Local nInd      := 0 //Variável de controle de linhas.

If aParam <> NIL //Identifica que foram enviado os parâmetros.
    oObj     := aParam[1] //Modelo ativado.
    cIdPonto := aParam[2] //Determina o ponto de chamada.
    cIdModel := aParam[3] //Identificador do modelo.

    If cIdPonto == 'FORMCOMMITTTSPRE' //Substituição do ponto de entrada MNTA7352. 

        If cIdModel == 'MNTA735'

            oGrid1  := PARAMIXB[4] //Retorna a Grid que contêm os valores da TTG.
            nLinhas := 0

            oGrid1:AddLine() //Adiciona uma nova linha.
            nLinhas := oGrid1:Length() // Quantidade Total de linhas do oGrid1.
            oGrid1:GoLine( nLinhas ) //Posiciona na nova linha incluída.

            //Adiciona valores na Grid.
            oGrid1:LoadValue('TTD_TIPMOD',"X")
            oGrid1:LoadValue('TTG_CHECK',oObj:GetValue('TTFMASTER','TTF_CHECK'))
            oGrid1:LoadValue('TTG_ETAPA',"01")
            oGrid1:LoadValue('TTG_NOMETA',"Nome etaga 1")
            oGrid1:LoadValue('TTG_CRITIC','A')

        EndIf

    ElseIf cIdPonto == 'FORMCOMMITTTSPOS' //Substituição dos ponto de entrada MNTA7351 e MNTA7358. 

        If cIdModel == 'MNTA735'

            aAreaTTF := TTF->(GetArea()) //Salva área posicionada.

            dbSelectArea("TTF")
            dbSetOrder(1) //TTF_FILIAL+TTF_CHECK+TTF_CODFAM+TTF_TIPMOD+TTF_SEQFAM
            If dbSeek(xFilial("TTF")+oObj:GetValue('TTFMASTER','TTF_CHECK')) //Posiciona no registro adicionado.
                RecLock("TTF",.F.)
                TTF->TTF_POSCON := 100  // Realiza alteração de contador.
                MsUnLock("TTF")
            EndIf

            dbSelectArea("ST9")
            dbSetOrder(1)
            If dbSeek(xFilial("ST9")+oObj:GetValue('TTFMASTER','TTF_CODBEM'))
                RecLock("ST9",.F.)
                ST9->T9_PADRAO  := '2'
                MsUnlock("ST9")
            EndIF

            RestArea(aAreaTTF) //Retorna área posicionada.

        EndIf

    ElseIf cIdPonto == 'MODELPOS' //Substituição do ponto de entrada MNTA7356. 

        If cIdModel == 'MNTA735'

            oGrid1   := oObj:GetModel('TTGDETAIL') // Posiciona no Model da Grid
            nLenGrid := oGrid1:Length() // Pega tamanho total da grid.
            nInd     := 0
            cEtapa   := ""

            If Empty(oObj:GetValue('TTFMASTER','TTF_RAMAL')) //Verifica se o campo Ramal foi preenchido.
                Help(Nil, Nil, "Atenção", Nil, "O campo de Ramal não foi preenchido. Favor realizar o seu preenchimento.", 1, 0)
                xRet := .F.
            EndIf

            If xRet
                For nInd := 1 To nLenGrid

                    oGrid1:GoLine(nInd) // Posiciona na linha desejada.
                    If !oGrid1:IsDeleted() // Veririfica se o registro não está delatado

                        cEtapa := AllTrim(oGrid1:GetValue("TTG_ETAPA"))
                        If cEtapa == "0001"
                            Help(Nil, Nil, "Atenção", Nil, "Essa etapa não pode ser utilizada", 1, 0)
                            xRet := .F.
                        EndIf

                    EndIf
                Next nInd
            EndIf

        EndIf

    ElseIf cIdPonto == 'FORMLINEPOS' //Substituição do ponto de entrada MNTA7355. 

        If cIdModel == 'MNTA735'
            oGrid1  := oObj:GetModel('TTGDETAIL') // Posiciona no Model da Grid

            If Empty(oGrid1:GetValue('TTG_CRITIC')) //Verifica se o campo foi preenchido.
                Help(Nil, Nil, "Atenção", Nil, "O campo de criticidade não foi preenchido. Favor realizar o seu preenchimento.", 1, 0)
                xRet := .F.
            EndIf
        EndIf

    EndIf

EndIf

Return xRet