DT_PE_CT192POS_Reprocessamento_CTBA192

Características do Requisito

Descrição

O ponto de entrada CT192POS possibilita outros processamentos após o término dos jobs de reprocessamento da rotina CTBA192.

Ponto de Entrada

Exemplo:

#Include 'Protheus.ch'

User Function CT192POS()

Local aArea     := GetArea()

Local aCtbMoeda := {}

Local cFilDe    := PARAMIXB[1]

Local cFilAte   := PARAMIXB[2]

Local dDataIni  := PARAMIXB[3]

Local dDataFim  := PARAMIXB[4]

Local lMoedaEsp := PARAMIXB[5]

Local cMoeda    := PARAMIXB[6]

Local cTpSald   := PARAMIXB[7]

SAVEINTER()

// Tratamento da moeda especifica

If lMoedaEsp                    

    aCtbMoeda := CtbMoeda( cMoeda )

    If Empty( aCtbMoeda[1] )

        Help(" ",1,"NOMOEDA")

        Return Nil

    EndIf

    nMoedaIni := Val( cMoeda )

    nMoedaFim := Val( cMoeda )

Else

    nMoedaIni    := 1

    nMoedaFim    := __nQuantas

EndIf

Conout( "CT192POS: Iniciando processo de atualização do LOTE" )

//Reprocessa totais por lote  => atualiza CT6

Ctb190Lote(nMoedaIni,nMoedaFim,cFilDe,cFilAte,cTpSald,dDataIni,dDataFim)

Conout( "CT192POS: Iniciando processo de atualização do DOCUMENTO" )

//Reprocessa totais por documento => atualiza CTC

Ctb190Doc(nMoedaIni,nMoedaFim,cFilDe,cFilAte,cTpSald,dDataIni,dDataFim)

Conout( "CT192POS: Iniciando processo de atualização do FLAG DE CONTA PONTE" )

//Atualiza os flags de conta ponte.

CtbFlgPon(nMoedaIni,nMoedaFim,cFilDe,cFilAte,cTpSald,dDataIni,dDataFim)

Conout( "CT192POS: PROCESSO CONCLUIDO!" )

RESTINTER()

RestArea( aArea )

Return Nil