Histórico da Página

FWFORMMODEL():New([ cID ], [ bPre ], [ bPost ], [ bCommit ], [ bCancel ])-> NIL

Método construtor da classe

 

Static Function ModelDef()
Local oModel := FWFormModel():New('COMP011MODEL', , { |oMdl| COMP011POS( oMdl ) }, {|oModel| commit()},{|oModel| cancel()})
Return

Static Function COMP011POS( oModel )
Local nOperation := oModel:GetOperation()
Local lRet := .T.

If nOperation == MODEL_OPERATION_UPDATE
   If Empty( oModel:GetValue( 'ZA0MASTER', 'ZA0_DTAFAL' ) )
      oModel:SetErrorMessage('ZA0MASTER', 'ZA0_DTAFAL' , 'ZA0MASTER' , 'ZA0_DTAFAL' , "Erro", 'Data incorreta', 'Informe a data')      
      lRet := .F.
   EndIf
EndIf

Return lRet

Static Function commit()
Return

Static Function cancel()
Return

Se a aplicação é uma Function, o identificador (cID) do modelo de dados (Model) pode
ter o mesmo nome da função principal e esta prática é recomendada para facilitar a
codificação. Por exemplo, se estamos escrevendo a função XPTO, o identificador (cID) do
modelo de dados (Model) poderá ser XPTO.
Se a aplicação é uma User Function o identificador (ID) do modelo de dados (Model)
NÃO pode ter o mesmo nome da função principal, isso por causa dos pontos de entrada
que já são criados automaticamente quando desenvolvemos uma aplicação em MVC.

User Function COMP011_MVC
Local oModel := FWFormModel():New("COMP011",,,{|oModel| commit()},{|oModel| cancel()})
Return

Function COMP012_MVC
Local oModel := FWFormModel():New("COMP012_MVC",,,{|oModel| commit()},{|oModel| cancel()})
Return

Método setErrorMessage

FWFORMMODEL():Activate([ lCopy ])-> NIL

Método de ativação da classe. Esse método deve ser usado depois
que o objeto já foi completamente definido, pois após a ativação
não será mais possível realizar definições, tais como addField,
addGrid, setActivate e etc..
Quando a classe é ativada, os dados do submodelo são carregados.

 

Este método realiza algumas validações no preenchimento dos
parametros de operação da classe, gerando uma exceção caso haja
algum problema de configuração.

FWFORMMODEL():DeActivate()-> NIL

Método de desativação da classe. Quando a classe é desativada, os dados
do submodelo são perdidos e o objeto passa a aceitar novamente
os métodos de parametrização, tais como addField, setActivate e etc.
Este método deve ser utilizado para reparametrizar a classe ou para
reinicializar o preenchimento do submodelo.

FWFORMMODEL():Destroy()-> NIL

Destroy o objeto e suas referencias a outros objetos.
O Objeto não pode ter sido desativado.
Importante chamar principalmente quando instanciamos o mesmo em loop.

FWFORMMODEL():ClassName()-> cClassName

Fornece o nome da classe

cClassName Nome da classe

FWFORMMODEL():GetId()-> Id

Fornece o Id do objeto informado no método new.

Id Id do objeto

FWFORMMODEL():SetDescription([ cDescription ])-> NIL

Atribui ao modelo um texto explicativo sobre o objetivo do Modelo.
O objetivo é mostrado em diversos operações, tais como web services,
relatórios e schemas (xsd).

 

Este método somente pode ser utilizado se o objeto estiver desativado

FWFORMMODEL():GetDescription()-> cDescription

Fornece um texto contendo a descrição do modelo, que é informado
no método SetDescription.

cDescription Descrição do objetivo do modelo

SetDescription

FWFORMMODEL():AddFields([ cId ], [ cOwner ], [ oModelStruct ], [ bPre ], [ bPost ], [ bLoad ])-> NIL

Adiciona ao modelo um submodelo de edição por campo (FormField).
Um submodelo do tipo Field permite manipular somente um
registro por vez. Ele tem um relacionamento do tipo 1xN ou 1x1 com outros
SubModelos ou então não tem nenhum relacionamento.

 

Static Function ModelDef()
Local oModel
Local oStruZA1:= FWFormStruct(1,'ZA1')
Local bPre := {|oFieldModel, cAction, cIDField, xValue| validPre(oFieldModel, cAction, cIDField, xValue)}
Local bPos := {|oFieldModel|fieldValidPos(oFieldModel)}
Local bLoad := {|oFieldModel, lCopy| loadField(oFieldModel, lCopy)}


oModel := FWFormModel():New('COMP021',,,{|oModel| commit()},{|oModel| cancel()})
oModel:addFields('ZA1MASTER',,oStruZA1,bPre,bPos,bLoad)

Return oModel

Static Function fieldValidPos(oFieldModel)
Local lRet := .T.
   
   If "MUSICA" $ Upper(oFieldModel:GetValue("ZA1_TITULO"))
      lRet := .F.
      oFieldModel:GetModel():SetErrorMessage('ZA1MASTER', "ZA1_TITULO" , 'ZA1MASTER' , 'ZA1_TITULO' , "Erro", 'Título incorreto', 'O texto "musica" não pode estar contido no título.')      
   EndIf
   
Return lRet

Static Function validPre(oFieldModel, cAction, cIDField, xValue)
Local lRet := .T.

If cAction == "SETVALUE" .And. cIDField == "ZA1_FILIAL"
   lRet := .F.
   oFieldModel:GetModel():SetErrorMessage('ZA1MASTER', "ZA1_FILIAL" , 'ZA1MASTER' , 'ZA1_FILIAL' , "Erro", 'Filial', 'Não possível atribuir valor ao campo Filial.')
Return

Return lRet

Static Function loadField(oFieldModel, lCopy)
Local aLoad := {}

   aAdd(aLoad, {xFilial("ZA1"), "000001", "Musica 1", Date(), "R"}) //dados
   aAdd(aLoad, 1) //recno
      
Return aLoad

Static Function commit()
Return

Static Function cancel()
Return

O primeiro SubModelo do Model deve ser, obrigatoriamente, um FormField.

FWFormModelStruct
FWFormStruct
FWFormFieldModel
Método SetErrorMessage

FWFORMMODEL():AddGrid([ cId ], [ cOwner ], [ oModelStruct ], [ bLinePre ], [ bLinePost ], [ bPre ], [ bPost ], [ bLoad ])-> NIL

Adiciona ao modelo um submodelo de edição por grid (FormGrid).
Um submodelo do tipo Grid permite manipular diversos registros por
vez. Ele tem um relacionamento do tipo Nx1 ou NxM com outros Submodelos.

 

Static Function ModelDef()
Local oModel
Local oStruZA1:= FWFormStruct(1,'ZA1')
Local oStruZA2 := FWFormStruct( 1, 'ZA2')
Local bLinePre := {|oGridModel, nLine, cAction, cIDField, xValue, xCurrentValue| linePreGrid(oGridModel, nLine, cAction, cIDField, xValue, xCurrentValue)}
Local bLoad := {|oGridModel, lCopy| loadGrid(oGridModel, lCopy)}

oModel := FWFormModel():New('COMP021',,,{|oModel| commit()},{|oModel| cancel()})
oModel:AddFields('ZA1MASTER',,oStruZA1)
oModel:AddGrid( 'ZA2DETAIL', 'ZA1MASTER', oStruZA2, bLinePre, , , ,bLoad)
Return oModel

Static Function loadGrid(oGridModel, lCopy)
Local aLoad := {}

   aAdd(aLoad,{0,{xFilial("ZA2"), "000001", "01", "000100","AUTOR1","AUTOR"}})
   aAdd(aLoad,{0,{xFilial("ZA2"), "000001", "02", "000102","AUTOR2","AUTOR"}})
   aAdd(aLoad,{0,{xFilial("ZA2"), "000001", "03", "000104","AUTOR3","AUTOR"}})
   aAdd(aLoad,{0,{xFilial("ZA2"), "000001", "04", "000105","AUTOR4","AUTOR"}})
   aAdd(aLoad,{0,{xFilial("ZA2"), "000001", "05", "000106","AUTOR5","AUTOR"}})

Return aLoad

Static Function linePreGrid(oGridModel, nLine, cAction, cIDField, xValue, xCurrentValue)
Local lRet := .T.   

   If cAction == "SETVALUE"
      If oGridModel:GetValue("ZA2_TIPO") == "AUTOR"
         lRet := .F.
         oGridModel:GetModel():SetErrorMessage('ZA2DETAIL', 'ZA2_TIPO' , 'ZA2DETAIL' , 'ZA2_TIPO' , 'Erro', 'Não é possível alterar linhas do tipo Autor', '')
      EndIf
   EndIf
   
Return lRet

Static Function commit()
Return

Static Function cancel()
Return

O Model deve sempre iniciar com um submodelo do tipo Field

Método SetErrorMessage
FWFormGridModel
FWFormModelStruct

FWFORMMODEL():AddCalc([ cId ], [ cOwner ], [ cIdForm ], [ cIdField ], [ cIdCalc ], [ cOperation ], [ bCond ], [ bInitValue ], [ cTitle ], [ bFormula ], [ nTamanho ], [ nDecimal ])-> NIL

Adiciona ao modelo um submodelo de campos calculados baseado em campos de
um submodelo do tipo grid. Esse submodelo deve ser usado para
fazer calculos, por exemplo, pode-se criar um calc para somar a coluna
valor total do item, tendo assim o total de todos os itens.
Pode-se criar um calc do tipo média e fazer a média das quantidades
de um grid, por exemplo.
O submodelo calc suporta diversos campos de calculo, precisando ter
no minimo 1 e no máximo N. Ou seja, pode-se criar um calc "TOTAIS"
e dentro dele criar dois campos calculado, um para o total e outro para
a média.

 

Static Function ModelDef()
// Cria a estrutura a ser usada no Modelo de Dados
Local oStruZA1 := FWFormStruct( 1, 'ZA1')
Local oStruZA2 := FWFormStruct( 1, 'ZA2')
Local oModel

oModel := FWFormModel():New( 'COMP022M',,,{|oModel| commit()},{|oModel| cancel()})
oModel:AddFields( 'ZA1MASTER', , oStruZA1)
oModel:AddGrid( 'ZA2DETAIL', 'ZA1MASTER', oStruZA2)

oModel:AddCalc( 'COMP022CALC1', 'ZA1MASTER', 'ZA2DETAIL', 'ZA2_AUTOR', 'ZA2__TOT01', 'COUNT', { | oMld | COMP022CAL( oMld, .T. ) },,'Total Pares' )
oModel:AddCalc( 'COMP022CALC1', 'ZA1MASTER', 'ZA2DETAIL', 'ZA2_AUTOR', 'ZA2__TOT02', 'COUNT', { | oMld | COMP022CAL( oMld, .F. ) },,'Total Impares' )

oModel:SetRelation( 'ZA2DETAIL', { { 'ZA2_FILIAL', 'xFilial( "ZA2" ) ' } , { 'ZA2_MUSICA', 'ZA1_MUSICA' } } , ZA2->( IndexKey( 1 ) ) )

oModel:SetDescription( 'Modelo de Musicas' )
oModel:GetModel( 'ZA1MASTER' ):SetDescription( 'Dados da Musica' )
oModel:GetModel( 'ZA2DETAIL' ):SetDescription( 'Dados do Autor' )

Return oModel

Static Function COMP022CAL( oModel, lPar )
Local lRet := .T.

If lPar
   lRet := ( Mod( Val( oModel:GetValue( 'ZA2DETAIL', 'ZA2_AUTOR' ) ) , 2 ) == 0 )
Else
   lRet := ( Mod( Val( oModel:GetValue( 'ZA2DETAIL', 'ZA2_AUTOR' ) ) , 2 ) <> 0 )
EndIf
Return lRet

Static Function commit()
Return

Static Function cancel()
Return

Um submodelo de calc somente pode ser criado abaixo de um submodelo do tipo grid

FWFORMMODEL():AddRules([ cIDSubModel ], [ cIDField ], [ cIDTargetSubModel ], [ cIDFieldTarget ], [ nType ])-> NIL

Adiciona uma relação de dependência entre dois campos, definindo que o
preenchimento de um campo depende do preenchimento de outro.
Por exemplo, podemos definir que o campo Código da Loja só pode ser
preenchido após o preenchimento do campo Código do Cliente.
A regra pode ser criada com campos do mesmo submodelo ou com campos de submodelos diferentes.

 

//campo Loja dependendo do preenchimento do campo Cliente
oModel:AddRules( 'ZA1MASTER', 'A1_LOJA', 'ZA1MASTER', 'A1_CLIENTE', 3)

//Campo autor do submodelo GRID depende do preenchimento do campo data do submodelo FIELD
oModel:AddRules( 'ZA2DETAIL', 'ZA2_AUTOR', 'ZA1MASTER', 'ZA1_DATA', 3)

FWFORMMODEL():GetDependency([ cId ])-> aModels

Fornece a relacao de modelos que são dependentes (filhos) do modelo ou de um submodelo

 

aModels Estrutura
[n][1] Tipo do objeto FIELD ou GRID
[n][2] Id do objeto
[n][3] Objeto do modelo (FWFormFieldModel ou FWFormGridModel)
[n][4] Array com a estrutura dos filhos no mesmo formato

FWFORMMODEL():GetModelStruct([ cId ])-> aModels

Fornece a Estrutura do modelo ou de um submodelo

 

aModels Estrutura
[n][1] Tipo do objeto FIELD ou GRID
[n][2] Id do objeto
[n][3] Objeto do modelo (FWFormFieldModel ou FWFormGridModel)
[n][4] Array com a estrutura dos filhos no mesmo formato

FWFORMMODEL():GetModel([ cId ])-> oRetorno

Localiza o submodelo referente ao ID passado por parametro e retorna,
o objeto do submodelo, podendo ser do tipo FWFormFieldsModel ou
FWFormGridModel

 

oRetorno Objeto do submodelo(FWFormFieldsModel ou
FWFormGridModel). Se o cID for vazio, retorna o próprio model.

FWFORMMODEL():GetXMLData([ lDetail ], [ nOperation ], [ lXSL ], [ lVirtual ], [ lDeleted ], [ lEmpty ], [ lDefinition ], [ cXMLFile ])-> cXML

Fornece uma string com os dados do modelo no formato XML, conforme o modo de operação especificado ( SetOperation ) e
se o objeto esta ativado ( Activate ) ou não (deactivate). Quando o objeto esta desativado ou a operação é de inclusão
uma folha de dados em branco é fornecida.

 

cXML XML com do modelo e os dados

SetOperation,GetXMLSchema

FWFORMMODEL():GetJSONData([ lDetail ], [ nOperation ], [ lVirtual ], [ lDeleted ], [ lEmpty ])-> cJson

Fornece uma string JSON de dados do modelo, conforme o modo de operação especificado ( SetOperation ) e
se o objeto esta ativado ( Activate ) ou não (deactivate). Quando o objeto esta desativado ou a operação é de inclusão
uma folha de dados em branco é fornecida.

 

cJson JSON com o modelo e os dados

SetOperation

FWFORMMODEL():GetXMLSchema([ lVirtual ], [ lTypeDef ], [ lOnlyStruct ])-> cXSD

Fornece uma string com o schema ( XSD ) do modelo de dados. Este método fornece a descrição dos elementos do XML, as
validações em lista, as validações de tamanho e tipo de dados e os campos de preenchimento obrigatório.

 

cXSD Schema ( XSD ) do modelo de dados

GetXMLData

FWFORMMODEL():GetXMLLayout([ cID ])-> cXSL

Fornece uma string com o layout ( XSL ) de apresentação do modelo de dados. Este método fornece o
layout de exibição dos elementos do XML.

 

cXSL Layout de apresentação do modelo de dados

GetXMLData

FWFORMMODEL():LoadXMLPk([ cXML ])-> aResult

Identifica a chave primária do modelo de dados. Este método pode ser utilizado para identificar e extrair os dados da
chave primária contidas no XML fornecido como parametro.

 

aResult Array com a seguinte estrutura:
            [1] ExpN: Codigo da Operacao
            [2] Array com os dados da Primary Key

GetXMLSchema, GetXMLData

FWFORMMODEL():LoadXMLOperation([ cXML ])-> nResult

Identifica a operacao do modelo de dados. Este método pode ser utilizado para identificar e extrair operacao
contida no XML fornecido como parametro.

 

nResult Numero da operacao

GetXMLSchema, GetXMLData

FWFORMMODEL():LoadXMLData([ cXML ], [ lForce ])-> lLoad

Carrega o modelo com base na folha de dados em XML. Este método pode ser utilizado para processar a validação e carga
dos dados contidos no XML fornecido, porém não efetua a gravação dos dados

 

lLoad Indica se o modelo foi carregado com sucesso

            ::MODELXML := oModel:LoadXMLData(::ModelXML)
            If oModel:VldData()
               oModel:CommitData()
               ::lOk := .T.
            Else
               ::lOk := .F.
               aError := oModel:GetErrorMessage()
               SetSoapFault(aError[MODEL_MSGERR_IDFORM]+":"+;
                           aError[MODEL_MSGERR_IDFIELD]+":"+;
                           aError[MODEL_MSGERR_IDFORMERR]+":"+;
                           aError[MODEL_MSGERR_IDFIELDERR]+":"+;
                           aError[MODEL_MSGERR_ID],;
                           aError[MODEL_MSGERR_MESSAGE]+"/"+aError[MODEL_MSGERR_SOLUCTION])
               lRetorno := .F.
            EndIf

FWFORMMODEL():SetLoadXML([ bLoadXML ])-> NIL

Configura o modelo para ser ativado com uma folha de dados em XML.

 

FWFORMMODEL():SetValue([ cIdForm ], [ cIdField ], [ xValue ])-> lRetorno

Atribui um valor a folha de dados do objeto executando sua validação conforme o tipo de operação configurado ( SetOperation ).
Caso o objeto não possa receber dados um erro pode ser gerado ( SetErrorMessage ) ou uma exceção de usuário ( queda do sistema ).

 

lRetorno Indica se o valor foi atribuido

CanSetValue,GetErrorMessage,SetErrorMessage

FWFORMMODEL():LoadValue([ cIdForm ], [ cIdField ], [ xValue ])-> lRetorno

Carrega um valor a folha de dados do objeto. Este metodo somente pode ser utilizado quando há SetValue na pilha de chamadas
de função ( CallStack ). Diferentemente do metodo SetValue, este método não executa a validação do campo, mas fornece
todas as indicações de que ele foi atualizado. Ele é muito utíl quando dentro de uma validação de campo, necessitamos
alterar valores de outros campos, sem que isto implique em valida-los.

 

lRetorno Indica se o valor foi carregado

FWFORMMODEL():VldData([ cIDModel ], [ lVldOwner ])-> lRetorno

Valida toda a folha de dados do objeto modelo, ou um sub-parte dela, assegurando que o mesmo possa ser gravado com toda a integridade de
dados garantida. Este método verifica se todos os elementos da estrutura do modelo estão validos e executa o code-block
de pos-validação de cada um deles, bem como o code-block de validação final do modelo. O objeto é considerado valido
se todas as validações retornarem verdadeiro, caso contrário um erro ( SetErrorMessage ) será gerado.

 

lRetorno Folha de dados valida

SetErrorMessage, GetErrorMessage

FWFORMMODEL():CommitData()-> lRetorno

Grava a folha de dados do objeto modelo. A gravação somente é permitida se o objeto do modelo está valido.
A gravação não é feita diretamente por esta classe, mas sim, pelo code-block informado no método new. Este método
apenas assegura que todos os procedimentos necessários para gravar os dados do objeto modelo foram cumpridos.

lRetorno Folha de dados gravada

new

FWFORMMODEL():CancelData()-> lRetorno

Cancela a folha de dados do objeto modelo. Da mesma forma como o método CommitData, este método apenas assegura que
todos os procedimentos necessários ao cancelamento da gravação do objeto modelo foram cumpridos e invoca o code-block
configurado no método new.

lRetorno Folha de dados cancelada

new

FWFORMMODEL():SetErrorMessage([ cIdForm ], [ cIdField ], [ cIdFormErr ], [ cIdFieldErr ], [ cId ], [ cMessage ], [ cSoluction ], [ xValue ], [ xOldValue ])-> lRetorno

Atribui uma mensagem de erro ao modelo. Quando uma mensagem de erro é atribuida, ela somente pode ser retirada pelo
evento que a provocou.
O controle de mensagens de erro do modelo, permite identificar o Id´s do submodelo e campo de origem do erro e qual
Id do subdmodelo e campo que provocou o erro. Isto significa que caso um erro seja gerado por um gatilho de campo
este possa ser identificado.

 

lRetorno indica que a mensagem de erro foi reinicializada

FWFORMMODEL():GetErrorMessage([ lClear ])-> aErrorMessage

Fornece uma estrutrura com a pilha de erro

 

aErrorMessage Array com a estrutura a seguinte estrutura para tratamento de erro
[1] ExpC: Id do submodelo de origem
[2] ExpC: Id do campo de origem
[3] ExpC: Id do submodelo de erro
[4] ExpC: Id do campo de erro
[5] ExpC: Id do erro
[6] ExpC: mensagem do erro
[7] ExpC: mensagem da solução
[8] ExpX: Valor atribuido
[9] ExpX: Valor anterior

SetErrorMessage

FWFORMMODEL():HasErrorMessage()-> Se

Retorna se o model possui algum erro

Se .T. o Model possui algum erro pendente.

GetErrorMessage

FWFORMMODEL():GetValue([ cIdForm ], [ cIdField ])-> xRetorno

Recupera o valor da folha de dados do objeto.

 

xRetorno Conteudo do campo

SetValue

FWFORMMODEL():CanSetValue([ cIdForm ], [ cIdField ])-> lRetorno

Valida se é possível atribuir um valor a folha de dados do objeto.

 

lRetorno Indica se o valor pode ser atribuido

FWFORMMODEL():SetRelation([ cIdForm ], [ aRelation ], [ cOrderBy ])-> NIL

Atribui o critério de relacionamento entre os submodelos. A especificação do relacionamento
entre os submodelos de dados do objeto modelo, garante a carga dos dados e a correta atualização das chaves estrangeiras
durante a execução do método FWCommit.

 

Static Function ModelDef()
Local oModel
Local oStruZA1:= FWFormStruct(1,'ZA1')
Local oStruZA2 := FWFormStruct( 1, 'ZA2')

oModel := FWFormModel():New('COMP021',,,{|oModel| commit()},{|oModel| cancel()})
oModel:AddFields('ZA1MASTER',,oStruZA1)
oModel:AddGrid( 'ZA2DETAIL', 'ZA1MASTER', oStruZA2)
oModel:SetRelation( 'ZA2DETAIL', { { 'ZA2_FILIAL', 'xFilial( "ZA2" )' }, { 'ZA2_MUSICA', 'ZA1_MUSICA' } }, ZA2->( IndexKey( 1 ) ) )
Return oModel

Static Function commit()
Return

Static Function cancel()
Return

FWFORMMODEL():GetRelation([ cIdForm ])-> aRelation

Fornece o critério de relacionamento entre os submodelos

 

aRelation Estrutura do relacionamento entre as tabelas.
[1][n][1] IdField do submodelo de destino
             [2] IdField ou expressão do submodelo de destino
[2] Ordem de relacionamento no padrão ISAM.

SetRelation

FWFORMMODEL():SetPrimaryKey([ aPK ])-> NIL

Atribui a PrimaryKey da entidade Modelo. A primarykey é imprescindivel para a correta operação
das rotinas automáticas, web-services, relatórios, etc... Não é necessário informar uma para
cada submodelo, a Primary Key é definida somente para o primeiro submodelo do tipo FormField.

 

Se a tabela do submodelo for um metadado e possuir chave primária informada no SX2, não é necessário
fazer uso desse método pois o MVC irá considerar o que está declarado no SX2.

FWFORMMODEL():GetPrimaryKey()-> NIL

Fornece a Primary Key do modelo de dados

SetPrimaryKey

FWFORMMODEL():SetOperation([ nOperation ])-> NIL

Indica ao modelo a operacao de manipulacao de dados que será realizada. A classe utiliza esta informação para
definir como serão inicializadas as informações do modelo.

 

FWFORMMODEL():GetOperation()-> nOperation

Fornece o tipo de operacao de manipulacao de dados que foi configurado.

nOperation Indica a operação que será realizada com o modelo, sendo:
               1 - View
               3 - Insert
               4 - Update
               5 - Delete
               6 - only Update
               

SetOperation

FWFORMMODEL():ReportDef([ cPergunte ], [ bImpress ], [ aFields ])-> oReport

Fornece um objeto de TReport com as definicoes de impressão do modelo.
O TReport tem as seções e células baseado nos submodelos e estrutura
de dados.

 

oReport Objeto do tipo TReport com as definições de impressão

Static Function ModelDef()
Local oStruZA1 := FWFormStruct( 1, 'ZA1')
Local oStruZA2 := FWFormStruct( 1, 'ZA2')
Local oModel

oModel := MPFormModel():New( 'COMP022M')
oModel:AddFields( 'ZA1MASTER', NIL, oStruZA1 )
oModel:AddGrid( 'ZA2DETAIL', 'ZA1MASTER', oStruZA2)
oModel:SetRelation( 'ZA2DETAIL', { { 'ZA2_FILIAL', 'xFilial( "ZA2" ) ' } , { 'ZA2_MUSICA', 'ZA1_MUSICA' } } , ZA2->( IndexKey( 1 ) ) )
Return oModel

Static Function ViewDef()
Local oModel := ModelDef()
Local oView
Local oStr1:= FWFormStruct(2, 'ZA1')
Local oStr2:= FWFormStruct(2, 'ZA2')

oView := FWFormView():New()
oView:SetModel( oModel )
oView:AddField('ZA1MASTER' , oStr1)
oView:AddGrid('ZA2DETAIL' , oStr2)
oView:CreateHorizontalBox( 'BOXFORM2', 50)
oView:CreateHorizontalBox( 'BOXFORM4', 50)
oView:SetOwnerView('ZA1MASTER','BOXFORM2')
oView:SetOwnerView('ZA2DETAIL','BOXFORM4')

oView:AddUserButton("Imprimir TReport","",{|oView| print(oView)})

Return oView

Static Function Print(oView)
Local oModel := oView:GetModel()
Local oReport

   oReport := oModel:ReportDef()
   oReport:PrintDialog()
   
Return

FWFORMMODEL():SetReportTotal([ lTotal ])-> NIL

Configura se o relatório gerado pelo metodo ReportDef deverá totalizar todos os campos numéricos.

 

FWFORMMODEL():GetModelIds()-> aArray

Fornece um Array com os ids de Todos os submodelos do Model

aArray Array unidimensional que contém os Ids do submodelos

FWFORMMODEL():SetActivate([ bBloco ])-> NIL

Seta um bloco que será chamado logo após o Activate do model. Esse bloco recebe como parametro o proprio model(FWFormModel).

 

   bBloco := {|oModel| MinhaFunc(oModel)}
   oModel:SetActivate(bBloco)
   

FWFORMMODEL():SetDeActivate([ bBloco ])-> NIL

Seta um bloco que será chamado logo após o DeActivate do model. Esse bloco recebe como parametro o proprio model.

 

   bBloco := {|oModel| MinhaFunc(oModel)}
   oModel:SetDeActivate(bBloco)

FWFORMMODEL():SetVldActivate([ bBloco ])-> NIL

Seta um bloco que será chamado antes do Activate do model. Ele pode
Ser utilizado para inibir a inicialização do model. Se o retorno for negativo
uma exceção de usuário será gerada. O code-block recebe como parametro
o objeto model.

 

   bBloco := {|oModel| MinhaFunc(oModel)}
   oModel:SetVldActivate(bBloco)

CanActivate

FWFORMMODEL():CanActivate()-> NIL

Verifica se o model pode ser ativado.

SetVldActivate

FWFORMMODEL():SetOptional([ cIdForm ], [ lOp ])-> NIL

Define que um submodelo é opcional. Quando um modelo é opcional ele tem seu preenchimento
não obrigatório, podendo realizar a gravação dos dados sem preenche-lo

 

FWFORMMODEL():IsOptional([ cIdForm ])-> lOp

Retorna se o submodelo é opcional

 

lOp Se verdadeiro o submodelo é opcional

FWFORMMODEL():SetOnlyQuery([ cIdForm ], [ lOp ])-> NIL

Define que o submodelo não será gravado, ele é apenas usado para consulta.
Se um submodelo é onlyquery e possui submodelos abaixo dele, os filhos serão
gravaveis por padrão. Mesmo o pai sendo onlyquery, os filhos irão
fazer a gravação, exceto se o(s) submodelo(s) filho for definido como
setonlyquery verdadeiro.

 

FWFORMMODEL():IsOnlyQuery([ cIdForm ])-> lRet

Retorna se o submodelo é apenas para visualização, ou seja, tem a gravação é inibida.

 

lRet Se verdadeiro o submodelo não é gravado

FWFORMMODEL():ClearField([ cIdForm ], [ cIdField ])-> lRetorno

Limpa o conteudo de um campo de um submodelo

 

lRetorno Indica se a operação foi concluida com sucesso

FWFORMMODEL():IsActive()-> NIL

Retorna se o modelo está ativo

FWFORMMODEL():isEnable([ cIdForm ])-> lRet

Execulta o bloco de bPre do submodelo, retornando se ele está disponivel para edição

 

lRet - Se verdadeiro indica que o submodelo está disponivel

FWFORMMODEL():InitValue([ cIdForm ], [ cIdField ])-> xRetorno

Recupera o valor do inicializador padrao da folha de dados do objeto.

 

xRetorno Conteudo do campo

FWFORMMODEL():Compare(oOtherModel, [ oOtherModel lGetID] )-> NIL

Faz a comparação entre os dados de um objeto do tipo Model passado por referência
com o próprio model. Os dois objetos devem possuir os mesmos submodelos, pois esse
método compara apenas os dados, supondo que a estrutura seja a mesma.

FWFORMMODEL():HasField([ cIdForm ], [ cIdField ])-> NIL

Informa de um determinado campo existe na estrutura

 

FWFORMMODEL():SetCancel([ bBloco ], [ lAcumula ])-> NIL

Seta um bloco que será chamado quando o submodelo é cancelado

 

FWFORMMODEL():SetCommit([ bBloco ], [ lAcumula ])-> NIL

Seta um bloco que será chamado na gravação do submodelo

 

FWFORMMODEL():SetOnDemand([ lOnDemand ])-> NIL

Define se a carga dos dados será por demanda.
Quando o model é por demanda, os dados do submodelo não serão carregados
de uma vez no activate. Conforme eles forem manipulados eles serão
carregados. O método é útil em modelos que contem muitos submodelos
e que podem ficar lentos devido a grande quantidade de dados.

 

FWFORMMODEL():IsCopy()-> lRetorno

Indica se o modelo esta em uma operacao com origem em uma copia de dados

lRetorno Se verdadeiro indica que é uma operação de cópia

FWFORMMODEL():SetProcess([ nProcess ])-> NIL

Define um valor para o processo. Util para se efetuar algum controle alem
da operação.

 

GetProcess

FWFORMMODEL():GetProcess()-> NIL

Obtem o valor do processo que foi definido pelo método SetProcess

SetProcess

FWFORMMODEL():InstallObserver([ cPoint ], [ oObserver ])-> NIL

Faz a instalaçao de um Observador em uma ação

 

FWObserver

FWFORMMODEL():getObservable([ cPoint ])-> oObserable

Retorna um Observable baseado numa ação

 

oObserable Objeto do tipo FWObserable

FWObservable

FWFORMMODEL():SetWKDef([ cWKDef ])-> NIL

Define o Código do processo do Fluig BPM

 

FWFORMMODEL():SetWKVersDef([ cWKVersDef ])-> NIL

Define a versão do processo do Fluig BPM

 

FWFORMMODEL():SetWKNumProces([ cWKNumProces ])-> NIL

Define o Número da solicitação de processo do Fluig BPM

 

FWFORMMODEL():SetWKNumState([ cWKNumState ])-> NIL

Define o Número da atividade do Fluig BPM

 

FWFORMMODEL():SetWKCurrentState([ cWKCurrentState ])-> NIL

Define o Número da atividade atual do processo do Fluig BPM

 

FWFORMMODEL():SetWKCompany([ cWKCompany ])-> NIL

Define o número da empresado Fluig BPM

 

FWFORMMODEL():SetWKUser([ cWKUser ])-> NIL

Define o Código do usuario do Fluig BPM

 

FWFORMMODEL():SetWKUserEmail([ cWKUserEmail ])-> NIL

Define o e-mail do usuario do Fluig BPM

 

FWFORMMODEL():SetWKCompletTask([ cWKCompletTask ])-> NIL

Indica se tarefa foi completada (true/false) do Fluig BPM

 

FWFORMMODEL():SetWKNextState([ cWKNextState ])-> NIL

Define o Número da próxima atividade (destino) do Fluig BPM

 

FWFORMMODEL():SetWKCardId([ cWKCardId ])-> NIL

Define o código do formulário do processo do Fluig BPM

 

FWFORMMODEL():SetWKFormId([ cWKFormId ])-> NIL

Define o Código da definição de formulário do processo do Fluig BPM

 

FWFORMMODEL():GetWKDef()-> cWKDef

Retorna o Código do processo do Fluig BPM

cWKDef Código do processo

FWFORMMODEL():GetWKVersDef()-> cWKVersDef

Retorna o Versão do processo do Fluig BPM

cWKVersDef Versão do processo

FWFORMMODEL():GetWKNumProces()-> cWKNumProces

Retorna o Número da solicitação de processo do Fluig BPM

cWKNumProces Número da solicitação de processo

FWFORMMODEL():GetWKNumState()-> cWKNumState

Retorna o Número da atividade do Fluig BPM

cWKNumState Número da atividade

FWFORMMODEL():GetWKCurrentState()-> cWKCurrentState

Retorna o Número da atividade atual do processo do Fluig BPM

cWKCurrentState Número da atividade

FWFORMMODEL():GetWKCompany()-> cWKCompany

Retorna o Número da empresa do processo do Fluig BPM

cWKCompany Número empresa

FWFORMMODEL():GetWKUser()-> cWKUser

Retorna o Código do usuario do Fluig BPM

cWKUser Código do usuario

FWFORMMODEL():GetWKUserEmail()-> cWKUserEmail

Retorna o e-mail do usuario do Fluig BPM

cWKUserEmail E-mail do usuario

FWFORMMODEL():GetWKCompletTask()-> cWKCompletTask

Retorna se tarefa foi concluída do Fluig BPM

cWKCompletTask true/false

FWFORMMODEL():GetWKNextState()-> cWKNextState

Retorna o Número da próxima atividade (destino) do processo do Fluig BPM

cWKNextState Número da atividade

FWFORMMODEL():GetWKCardId()-> cWKCardId

Retorna o código do formulário do processo do Fluig BPM

cWKCardId Código do formulário

FWFORMMODEL():GetWKFormId()-> cWKFormId

Retorna o Código da definição de formulário do processo do Fluig BPM

cWKFormId Código da definição de formulário

FWFORMMODEL():SetPKIndexOrder([ nIndexOrder ])-> NIL

Define a ordem de indice utilizada pela PK do model