Histórico da Página
...
Bloco de código | ||||||||||
---|---|---|---|---|---|---|---|---|---|---|
| ||||||||||
User Function EECAF200()
Local cParam := if(Type("ParamIxb") = "A", ParamIxb[1], if(Type("ParamIxb") = "C", ParamIxb, ""))
If cParam == "PE_STATUS"
MsgInfo("Entrou no ponto de entrada", 'PE_STATUS')
If EEC->(RecLock("EEC",.f.))
M->EEC_STATUS := "A"
M->EEC_STTDES := "STATUS TESTE"
EndIf
ElseIf cParam == "INICIALIZA_EVENTOS"
MsgInfo("Entrou no ponto de entrada", 'INICIALIZA_EVENTOS')
lGrvCamCon := .F.
ElseIf cParam == "PE_ALT_PARC"
Msginfo("Entrou no ponto de entrada", 'PE_ALT_PARC')
ElseIf cParam == "EVENTOS_NAO_GERADOS"
//disponível para alteração a variável cEventosNaoGerados
ElseIf cParam == "AF200DPARC_PARCELA_CAMBIO"
/* Exemplo de uso do ponto de entrada no momento da exclusão da parcela de câmbio, quando retirada a data do embarque.
A variável lDLoopEEQ indica se o programa deverá esquivar da exclusão do registro. */
If EEQ->EEQ_EVENT == "120"
lDLoopEEQ:= .T.
EndIf
ElseIf cParam == "AF200VALID_VALCAMPO"
If nTipoDet == 6 //exclusão
//não permite excluir
lSair:= .T.
lRet:= .F.
EndIf
ElseIf cParam == "PE_VALIDA"
nTipo:= ParamIXB[2] //é o mesmo conteúdo da variável nTipoDet
If nTipo == 6 //ou nTipoDet == 6; exclusão
//não permite excluir
//Return .F. //pode retornar .F. ou alterar a variável lRet
lRet:= .F.
EndIf
Elseif cParam == "ANTES_GRV_TMP"
nTipo:= ParamIXB[2]
If nTipo == 5
MsgInfo("Alteração da parcela de câmbio", "ANTES_GRV_TMP")
Endif
Elseif cParam == "GRV_ITEM_CAMBIO"
/*
If Empty(EEQ->EEQ_DTCE) .And. !Empty(TMP->EEQ_DTCE)
//processamento customizado
EndIf */
MsgInfo("Ponto de entrada EECAF200 GRV_ITEM_CAMBIO", "GRV_ITEM_CAMBIO")
ElseIf cParam == "INC_CAMBIO"
MsgInfo("Ponto de Entrada EECAF200 INC_CAMBIO", "INC_CAMBIO")
ElseIf cParam == "PE_GERPARC"
MsgInfo("Ponto de Entrada EECAF200 PE_GERPARC", "PE_GERPARC")
//customização após a gravação das parcelas de câmbio (EEQ)
//EEQ->(DBSeek(xFilial() + M->EEC_PREEMB))
//Looping na tabela EEQ para customização das parcelas de câmbio geradas para o processo de embarque
Elseif cParam == "VALIDA_PARCELA"
cMsg := "Variáveis com dados da parcela a ser gerada " + ENTER
cMsg += "nValParPE = " + Alltrim(str(nValParPE)) + ENTER
cMsg += "cCondPagtoPE = " + cCondPagtoPE + ENTER
cMsg += "dDtBasePE = " + dtoc(dDtBasePE) + ENTER
cMsg += "cEventoPE = " + cEventoPE + ENTER
cMsg += "cFornecedorPE = " + cFornecedorPE + ENTER
cMsg += "cLojaPE = " + cLojaPE + ENTER
cMsg += "cEmpresaPE = " + cEmpresaPE + ENTER
cMsg += "cNrInvoPE = " + cNrInvoPE + ENTER
cMsg += "cNatPE = " + cNatPE + ENTER
MsgInfo(cMsg,"VALIDA_PARCELA")
Elseif cParam == "PE_ENCHOICE_EEQ"
If ParamIXB[2] == 5
MsgInfo("Entrou no Ponto de Entrada PE_ENCHOICE_EEQ", "Alteração")
ElseIf ParamIXB[2] == 3
MsgInfo("Entrou no Ponto de Entrada PE_ENCHOICE_EEQ", "Visualização")
ElseIf ParamIXB[2] == 4
MsgInfo( "Entrou no Ponto de Entrada PE_ENCHOICE_EEQ", "Inclusão")
ElseIf ParamIXB[2] == 98
MsgInfo( "Entrou no Ponto de Entrada PE_ENCHOICE_EEQ", "Estorno da Liquidação")
ElseIf ParamIXB[2] == 99
MsgInfo( "Entrou no Ponto de Entrada PE_ENCHOICE_EEQ","Liquidação")
ElseIf ParamIXB[2] == 97
MsgInfo("Entrou no Ponto de Entrada PE_ENCHOICE_EEQ","Baixa Gerencial")
EndIf
aDel(aMostra, AScan(aMostra, "EEQ_FOLOJA"))
aDel(aMostra, AScan(aMostra, "EEQ_CORR"))
aDel(aMostra, AScan(aMostra, "EEQ_OBS"))
aSize(aMOSTRA, Len(aMostra)-3)
ADel(aALTERA, AScan(aALTERA, "EEQ_BANC"))
ADel(aALTERA, AScan(aALTERA, "EEQ_AGEN"))
ADel(aALTERA, AScan(aALTERA, "EEQ_NCON"))
aSize(aAltera, Len(aAltera)-3)
ElseIf cParam == "AF200GPARC_ALTDTEMBA"
dDTEMBA := M->EEC_DUEAVR
EndIf
Return Nil |
03. PARÂMETROS
Nome | Tipo | Descrição |
---|---|---|
PE_STATUS | Caracter | Permite a customização do status do pedido após a liquidação do controle do câmbio |
INICIALIZA_EVENTOS | Caracter | Permite a customização da validação que não permite gerar parcela de câmbio, caso a parcela já esteja liquidado. Também possibilita reiniciar a definição dos eventos para os quais devem ser geradas parcelas de câmbio, através da variável lInicializa. |
PE_ALT_PARC | Caracter | Permite alteração da parcela de câmbio (aParc) |
AF200DPARC_PARCELA_CAMBIO | Caracter | Ao remover a Dt.Embarque do processo e clicar em Salvar, este ponto de entrada será executado. Também estará disponível a variável cDespIntFin, com a lista dos eventos que serão integrados ao módulo SIGAFIN. |
AF200GPARC_DEF_PARC | Caracter | Possibilitar a alteração das parcelas que serão criadas no EEQ com base no array aParc. Também estará disponível a variável cDespIntFin, com a lista dos eventos que serão integrados ao módulo SIGAFIN. |
AF200GPARC_DEF_COMI | Caracter | Possibilitar a alteração do rateio das comissões no array aParcAux caso o array aParc tenha sido customizado. |
EVENTOS_NAO_GERADOS | Caracter | Permite manipular a variável cEventosNaoGerados, determinando os eventos para os quais não devem ser geradas parcelas de câmbio. Este ponto é executado quando ocorre a reinicialização das variáveis de controle, que pode ser provocada pelo uso do ponto de entrada com o parâmetro INICIALIZA_EVENTOS. |
AF200VALID_VALCAMPO | Caracter | Executado a partir da validação dos campos da parcela de câmbio e na confirmação da gravação da parcela de câmbio. Permite implementar validações adicionais e/ou aborar, através da manipulação das variáveis lSair e lRet. Os campos que estão sendo validados podem ser identificados pela função ReadVar(). |
{"PE_VALIDA", nTipoDet} | Array | Executado na confirmação da gravação da parcela de câmbio - botão Salvar (BT_OK). Permite implementar validações adicionais e/ou aborar, através da manipulação da variável lRet. Este ponto de entrada também pode retornar dados lógicos, sendo atribuído ao lRet da função de validação. Como array, possui duas posições:
3: Visulização da parcela de câmbio |
{"ANTES_GRV_TMP", nTipo} | Array | Executado na confirmação da manutenção da parcela de câmbio, logo após as validações, para gravação dos dados da memória (da parcela) para a tabela temporária:
3: Visulização da parcela de câmbio |
GRV_ITEM_CAMBIO | Caracter | Executado na confirmação final do câmbio, parcela a parcela, na gravação dos dados da tabela temporária (TMP) para a tabela de câmbio (EEQ). |
INC_CAMBIO | Caracter | Executado após a gravação de todas as parcelas de câmbio (looping), da tabela temporária (TMP) para a tabela de câmbio (EEQ). |
PE_GERPARC | Caracter | Indica o final da gravação de todas as parcelas de câmbio para o processo de embarque, após o preenchimento da data do embarque e gravação do processo. Este ponto permite a implementação de um looping na tabela das parcelas de câmbio (EEQ) para customização e gravação adicional de informações, dentre outras necessidades. Os dados da tabela podem ser posicionados usando as variáveis de memória da capa do processo de embarque (EEC). |
VALIDA_PARCELA | Caracter | Valida as parcelas que serão geradas para o câmbio como comissão de agentes e despesas internacionais |
DTNEGO_VALID | Caracter | Permite a substituição dos tratamentos padrões de validação do campo data de negociação, EEQ_DTNEGO. |
AF200STATUS_ALTSTATUS | Array | Permite a alteração do status do PO, mesmo quando o mesmo possuir algum câmbio gerado. |
ALTERA_PARCELA | Array | Permite customizar a informação do campo Parcela, utilizado na chave para baixa dos títulos no módulo Financeiro. |
ACERTA_TMP | Array | Parâmetro permitirá alteração dos valores do campos de parcela na rotina de Câmbio. |
DESVIA_AJUSTE | Array | Parâmetro que permitirá desviar o ajuste das parcelas de câmbio. |
AF200VALID_VALCAMPO | Caracter | Ponto de entrada para criação ou alteração de uma validação |
ALTERA_CSEEK_1 | Caracter | Parâmetro que possibilitará alterar a variável cSeek |
ALTERA_CSEEK_2 | Caracter | Parâmetro que possibilitará alterar a variável cSeek |
AF200GPARC_ALTDTEMBA | Caracter | Ponto de entrada para alteração da variável dDtEmba que guarda a data do campo EEC_DTEMBA, este campo será usado em diversas validações |
04. VARIÁVEIS
PE_ENCHOICE_EEQ | Caracter | Ponto de entrada que permite retirar campos mostrados na tela, modificar a relação dos campos passíveis de alteração e identificar a operação realizada. |
AF200GPARC_ALTDTEMBA | Caracter | Ponto de entrada que pemite alterar a variável dTEMBA para alterar o vencimento das parcelas de câmbio. |
04. VARIÁVEIS
Parâmetro | Nome | Tipo | Permite alterar | Parâmetro | Nome | Tipo | Permite alterar | Descrição |
---|---|---|---|---|---|---|---|---|
INICIALIZA_EVENTOS | lGrvCamCon | Lógica | Sim | Variável que permite pular a validação que não gera/regerar o titulo no financeiro | ||||
PE_ALT_PARC | aParc | Array | Sim | Array que contém as parcelas de câmbio | ||||
AF200DPARC_PARCELA_CAMBIO | lDLoopEEQ | Lógica | Sim | Se estiver atribuído como .T., a parcela de câmbio da iteração atual não será excluída. Caso estiver como .F., a parcela de câmbio será excluída. Essa variável é referente ao ponto de entrada AF200DPARC_PARCELA_CAMBIO. Valor padrão = .F. | ||||
AF200DPARC_PARCELA_CAMBIO | cDespIntFin | Caracter | Não | Variável com a lista dos eventos que serão integrados ao módulo SIGAFIN. | ||||
AF200GPARC_DEF_COMI | aParcAux | Array | Sim | Guarda os percentuais de comissão em conta gráfica nas parcelas de saldo a receber quando há adiantamento com Mov. Exterior | ||||
INICIALIZA_EVENTOS | lInicializa | Lógica | Sim | Determina se reinicializa as variáveis de controle dos eventos para os quais devem ser geradas parcelas de câmbio | ||||
EVENTOS_NAO_GERADOS | cEventosNaoGerados | Caracter | Sim | Eventos para os quais devem ser geradas as parcelas de câmbio | ||||
AF200GPARC_DEF_PARC AF200DPARC_PARCELA_CAMBIO | cDespIntFin | Caracter | Não | Eventos para os quais serão gerados os títulos no módulo SIGAFIN/ contas a pagar. | ||||
AF200VALID_VALCAMPO | lSair | Lógica | Sim | Disponível no ponto de entrada com o parâmetro AF200VALID_VALCAMPO, permite a intervenção nas validações dos campos da parcela de câmbio, forçando a saída das validações (True) sem as execuções padrões. | ||||
PE_VALIDA | nTipoDet | Numérico | Sim | Variável que permite identificar a operação que está sendo executada na manutenção da parcela de câmbio (Af200DetMan()). Pode assumir os valores: 3: Visulização da parcela de câmbio | ||||
ANTES_GRV_TMP | nTipo | Caracter | Sim | Variável que indicará a operação realizada, podendo assumir os valores: 3: Visulização da parcela de câmbio | ||||
AF200VALID_VALCAMPO | lRet | Lógica | Sim | Disponível no ponto de entrada com os parâmetros AF200VALID_VALCAMPO e {"PE_VALIDA", nTipoDet} da validação da parcela de câmbio, permite definir se a validação está correta (True) ou incorreta (False). | ||||
VALIDA_PARCELA | nValParPE | Numérico | Não | Valor da parcela a ser gerada | ||||
VALIDA_PARCELA | cCondPagtoPE | Caracter | Não | Condição de pagamento aplicado no processo | ||||
VALIDA_PARCELA | dDtBasePE | Data | Não | Data de criação da parcela | ||||
VALIDA_PARCELA | cEventoPE | Caracter | Não | Evento do qual será criado a parcela | ||||
VALIDA_PARCELA | cFornecedorPE | Caracter | Não | Fornecedor referente a parcela | ||||
VALIDA_PARCELA | cLojaPE | Caracter | Não | Loja referente a parcela | ||||
VALIDA_PARCELA | cEmpresaPE | Caracter | Não | Empresa no qual será criada a parcela | ||||
VALIDA_PARCELA | cNrInvoPE | Caracter | Não | Número da Invoice do processo | ||||
VALIDA_PARCELA | cNatPE | Caracter | Não | Natureza da parcela | ||||
VALIDA_PARCELA | lRetPE | Lógica | Sim | Variável que valida a geração da parcela e caso verdadeiro aborta o processo de gerar a parcela | ||||
VALIDA_PARCELA | nValorPE | Numérico | Sim | Variável que permite alterar o valor da parcela a ser gerada, não podendo o valor ser igual a zero | ||||
AF200GPARC_ALTDTEMBA | dDTEMBA | Data | Sim | |||||
ALTERA_CSEEK_1 ALTERA_CSEEK_2 | cSeek | Caracter | Sim | |||||
PE_ENCHOICE_EEQ | nTipoOpc | Numérico | Não | Variável que permite visualizar qual a operação acessada no sistema. Valores da variável nTipoOpc 3 -Visualizar | ||||
PE_ENCHOICE_EEQ | aMostra | Array | Sim | Array que contém os campos que serão exibidos na tela. | ||||
PE_ENCHOICE_EEQ | aAltera | Array | Sim | Array contendo os campos que permitem alteração. | ||||
AF200GPARC_ALTDTEMBA | dTEMBA | Data | Sim | Permite alterar esta variável que serve como referência para gerar os vencimentos das parcelas de câmbio. |
05. TABELAS UTILIZADAS
- Não há.
...