• O nome do arquivo fonte .prw no qual o ponto de entrada será salvo e compilado , deve ter um nome genérico . Assim não utilizando o mesmo nome e com nome diferente da função "MNTA400A", ou seja, não pode se chamar "MNTA400A" pois este nome já consta existe no banco de fontes da TotvsTOTVS.

 #INCLUDE "PROTHEUS.CH"
  
User Function MNTA400A()
        
    Local aArea := GetArea()
    Local cObs  := ""
    Local nOpcc := 0
    Local oDlg  := Nil
    Local oObs  := Nil
    Local oMenu := Nil
    Local nRec  := ParamIXB[1]
        
    dbSelectArea("STJ")
    dbGoTo(nRec)
        
    cObs := STJ->TJ_MTCANC
        
    Define Msdialog oDlg Title "Cancelamento da O.S."+STJ->TJ_ORDEM From 18,20 To 35,75 Of oMainWnd
        @ 38,8 Say "Motivo do Cancelamento" Of oDlg Pixel
        @ 45,8 Get oObs Var cObs Of oDlg Multiline Size 200,40 Pixel
               
        If ValType(aSMenu) == "A"
            NGPOPUP(aSMenu,@oMenu)
            oDlg:bRClicked:= { |o,x,y| oMenu:Activate(x,y,oDlg)}
        EndIf
               
    Activate Msdialog oDlg On Init EnchoiceBar(oDlg,{||nOpcc:=1,oDlg:End()},{||oDlg:End()})
        
    If nOpcc == 1
        dbSelectArea("STJ")
        RecLock('STJ',.F.)
        STJ->TJ_MTCANC := cObs
        MsUnLock()
    EndIf
        
    RestArea(aArea)
        
Return (nOpcc == 1)