Histórico da Página
CONTEÚDO
- Visão Geral
- Exemplo de utilização
- Parâmetros
- Variáveis
- Tabelas utilizadas
01. VISÃO GERAL
Este Ponto de Entrada pertence à rotina de Export XLS Ele deve ser utilizado para customização desta rotina.
Programa Fonte:NFEEXCEL.PRW
02. EXEMPLO DE UTILIZAÇÃO
Bloco de código | ||||||||||
---|---|---|---|---|---|---|---|---|---|---|
| ||||||||||
User function NFEEXCEL()
Local xRet := nil
Local cParam := iif( type("paramixb") == "A" .and. len(paramixb) > 0 , paramixb[1] , paramixb )
Do case
Case cParam == "EXPDADOS"
WKEXCEL->WK_NEWCPO := "NEW CAMPO"//Permite atribuir valores para os campos da Work que será gerada no Excel
Case cParam == "SET_ESTRUTURA"
aAdd(aEstru,{"WK_NEWCPO","C",10,0})//Permite adicionar novos campo na Work que será gerada para a gravação dos dados
Case cParam == "IMPDADOS_WORK"
WKDADOSXLS->WK_NEWCPO := "NEW CAMPO"//Permite atribuir valores para os campos da Work que será gerada no Excel
Case cParam == "TELA_RETORNO"
aAdd(aCampos,{"NOVO_CAMPO" ,"","Meu Campo Novo","" })
Case cParam == "SET_ESTRUTURA_MACRO"
//A estrura criada terá os sequinte forma
//Nome do campo + tipo + tamanho
//Tipo: Char ou Decimal
//Tamanho se tipo Char (x) se Decimal (x,x)
//Ex. WK_NOME Char(30), WK_DEC DECIMAL (10,2)
cStru += "WK_COD_I Char(20),WK_QTDE Decimal(13,3)"
Case cParam == "IMPDADOS_BASE"
SW9->W9_INCOTER := "FOB"//Permite personalizar a importação de dados na base
Case cParam == "EXP_DADOS_DUIMP"
// a posição 2 do paramixb são os campos padrões que serão exportados.
// Deverá retornar um vetor da seguindo estrutura:
// { 1 - Campo da tabela ,
// 2 - Se será editável ("true" - editável / "false" - não editável) ,
// 3 - Cor da coluna em hexadecimal sem # }
xRet := aClone(paramixb[2])
aAdd( xRet, { "W6_DT_EMB", "false", "3065ee" })
Case cParam == "EXECNFE"
lArqNFE := .T.
End Case
Return xRet |
03. PARÂMETROS
Nome | Tipo | Descrição |
---|---|---|
EXPDADOS | Caractere | Permite personalizar os dados exportados na Work |
SET_ESTRUTURA | Caractere | Permite alterar a estrutura do campo da Work |
IMPDADOS_WORK | Caractere | Permite retornar os dados da Work do Excel (DBFXLS) para a Work que será usada na importação na base de dados (WKDADOSXLS) |
TELA_RETORNO | Caractere | Permite personalizar a estrutura da tela de retorno (aCampos) |
SET_ESTRUTURA_MACRO | Caractere | Permite personalizar a estrutura da Work a ser gerada pelo Excel |
IMPDADOS_BASE | Caractere | Permite personalizar a importação de dados na base |
EXP_DADOS_DUIMP | Caractere | Permite adicionar ou excluir colunas na exportação do processo de Desembaraço do tipo DUIMP MANUAL. Somente é permite exportar os campos das tabelas: SW6 - Capa Declaração de Importação SWV - Lotes / Preparação Licença Imp SW8 - Itens de Invoices SW9 - Capa de Invoices EIJ - Tabela Adições Declaração Imp SWZ - Operação SWX - Classificação Fiscal Operação SB1 - Descrição Genérica do Produto |
EXECNFE | Caractere | Permite exportar a planilha com base no padrão dos arquivos NFE do cliente |
04. VARIÁVEIS
Parâmetro | Nome | Tipo | Permite alterar | Descrição |
---|---|---|---|---|
SET_ESTRUTURA | aEstru | Array | Sim | Array para definir a estrutura no formato {"CAMPO","TIPO",TAMANHO,DECIMAL} |
TELA_RETORNO | aCampos | Array | Sim | Array para permitir alterar a estrutura de retorno. |
SET_ESTRUTURA_MACRO | cStru | Caractere | Sim | Variável contendo a estrutrura para a macro criar o arquivo |
EXECNFE | lArqNFE | Lógico | Sim | Variável lógica que, se True, permite desviar da rotina padrão e montar a planilha com base nos arquivos NFE.xls e NFE.xla customizados pelo cliente. |
05. TABELAS UTILIZADAS
- Não há.
Visão Geral
Import HTML Content
Conteúdo das Ferramentas
Tarefas